Simple Birth Rates

Simple Birth Rates preview image

1 collaborator

Uri_dolphin3 Uri Wilensky (Author)

Tags

biology 

Tagged by Reuven M. Lerner over 10 years ago

social science 

Tagged by Reuven M. Lerner over 10 years ago

Parent of 1 model: Child of Simple Birth Rates
Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 1079 times • Downloaded 91 times • Run 1 time
Download the 'Simple Birth Rates' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This is a simple model of population genetics. There are two populations, the REDS and the BLUES. Each has settable birth rates. The reds and blues move around and reproduce according to their birth rates. When the carrying capacity of the terrain is exceeded, some agents die (each agent has the same chance of being selected for death) to maintain a relatively constant population. The model allows you to explore how differential birth rates affect the ratio of reds to blues.

HOW TO USE IT

Each pass through the GO function represents a generation in the time scale of this model.

The CARRYING-CAPACITY slider sets the carrying capacity of the terrain. The model is initialized to have a total population of CARRYING-CAPACITY with half the population reds and half blues.

The RED-FERTILITY and BLUE-FERTILITY sliders sets the average number of children the reds and blues have in a generation. For example, a fertility of 3.4 means that each parent will have three children minimum, with a 40% chance of having a fourth child.

The # BLUES and # REDS monitors display the number of reds and blues respectively.

The GO button runs the model. A running plot is also displayed of the number of reds, blues and total population (in green).

The RUN-EXPERIMENT button lets you experiment with many trials at the same settings. This button outputs the number of ticks it takes for either the reds or the blues to die out given a particular set of values for the sliders. After each extinction occurs, the world is cleared and another run begins with the same settings. This way you can see the variance of the number of generations until extinction.

THINGS TO NOTICE

How does differential birth rates affect the population dynamics?

Does the population with a higher birth rate always start off growing faster?

Does the population with a lower birth rate always end up extinct?

THINGS TO TRY

Try running an experiment with the same settings many times. Does one population always go extinct? How does the number of generations until extinction vary?

EXTENDING THE MODEL

In this model, once the carrying capacity has been exceeded, every member of the population has an equal chance of dying. Try extending the model so that reds and blues have different saturation rates. How does the saturation rate compare with the birthrate in determining the population dynamics?

In this model, the original population is set to the carrying capacity (both set to CARRYING-CAPACITY). Would population dynamics be different if these were allowed to vary independently?

In this model, reds are red and blues blue and progeny of reds are always red, progeny of blues are always blue. What if you allowed reds to sometimes have blue progeny and vice versa? How would the model dynamics be different?

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

COPYRIGHT AND LICENSE

Copyright 1997 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals
[
  red-count            ; population of red turtles
  blue-count           ; population of blue turtles
]

turtles-own
[
  fertility            ; the whole number part of fertility
  fertility-remainder  ; the fractional part (after the decimal point)
]

to setup
  clear-output
  setup-experiment
end 

to setup-experiment
  cp ct
  clear-all-plots
  reset-ticks
  crt carrying-capacity
  [
    setxy random-xcor random-ycor         ; randomize turtle locations
    ifelse who < (carrying-capacity / 2)  ; start out with equal numbers of reds and blues
      [ set color blue ]
      [ set color red ]
    set size 2                            ; easier to see
  ]
  reset-ticks
end 

to go
  reproduce
  grim-reaper
  tick
end 

;; to enable many repetitions with same settings

to go-experiment
  go
  if red-count = 0
  [
    output-print (word "red extinct after " ticks " generations")
    setup-experiment
  ]
  if blue-count = 0
  [
    output-print (word "blue extinct after " ticks " generations")
    setup-experiment
  ]
end 

to wander  ;; turtle procedure
  rt random-float 30 - random-float 30
  fd 1
end 

to reproduce
  ask turtles
  [
    ifelse color = red
    [
      set fertility floor red-fertility
      set fertility-remainder red-fertility - (floor red-fertility)
    ]
    [
      set fertility floor blue-fertility
      set fertility-remainder blue-fertility - (floor blue-fertility)
    ]
    ifelse (random-float 100) < (100 * fertility-remainder)
      [ hatch fertility + 1 [ wander ]]
      [ hatch fertility     [ wander ]]
  ]
end 

;; kill turtles in excess of carrying capacity
;; note that reds and blues have equal probability of dying

to grim-reaper
  let num-turtles count turtles
  if num-turtles <= carrying-capacity
    [ stop ]
  let chance-to-die (num-turtles - carrying-capacity) / num-turtles
  ask turtles
  [
    if random-float 1.0 < chance-to-die
      [ die ]
  ]
end 


; Copyright 1997 Uri Wilensky.
; See Info tab for full copyright and license.

There are 15 versions of this model.

Uploaded by When Description Download
Uri Wilensky almost 11 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky over 11 years ago Updated version tag Download this version
Uri Wilensky over 11 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky about 12 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Model from NetLogo distribution Download this version
Uri Wilensky almost 14 years ago Model from NetLogo distribution Download this version
Uri Wilensky almost 14 years ago Simple Birth Rates Download this version

Attached files

File Type Description Last updated
Simple Birth Rates.png preview Preview for 'Simple Birth Rates' almost 11 years ago, by Uri Wilensky Download

This model does not have any ancestors.

Children:

Graph of models related to 'Simple Birth Rates'