Ant sorting

turtles-own[
  memory
  drop_rate
  interest
]

to setup
  clear-all
  set-default-shape turtles "bug"
  ;; randomly distribute food
  ask patches
  [ if random-float 100 < density
    [ set pcolor one-of [yellow red blue]] ]
  ;; randomly distribute ants
  create-turtles number [
    set color white
    show memsize
    set memory n-values memsize [black]
    setxy random-xcor random-ycor
    set size 5  ;; easier to see
  ]
  reset-ticks
end 

to go  ;; turtle procedure
  ask turtles[
    update_memory
    ifelse color = white [
      ;; turtle is not carrying anything - look for food
      try-pick-up
    ] [
      ;; turtle is carrying food - look for place to drop it
      try-drop
    ]
    move
  ]
  tick
  if ticks >= max_steps[
    stop
  ]
end 

to try-pick-up
  if pcolor = yellow or pcolor = blue or pcolor = red[
    ; count how many objects I have seen of this color
    let f 0
    foreach memory [ x ->
      if x = pcolor [set f f + 1]
    ]
    set interest greed / (greed + f) ;; prob of being interested
    ;; if I am interested and I have no object, I pick up
    if random-float 1 < interest[
      ifelse color = white
      [
        set color pcolor
        set pcolor black
      ]
      ;; swap current hold item with item on ground otherwise.
      [
        let temp color
        set color pcolor
        set pcolor temp
      ]
      fd escape
    ]
  ]
end 

to try-drop  ;; turtle procedure -- finds empty spot & drops chip
  if pcolor = black
  [
    let f 0
    foreach memory [ x ->
      if x = color [set f f + 1]
    ]
    set drop_rate f / (cons + f)
    if random-float 1 < drop_rate[
      set pcolor color
      set color white
    ]
  ]
end 

to move ; turtle procedure
  fd 1
  rt random 50
  lt random 50
end 

to update_memory ; ant procedure to update memory
  if pcolor != black[
    let index random memsize
    set memory replace-item index memory pcolor
  ]
end 
; Copyright 1997 Uri Wilensky.
; See Info tab for full copyright and license.