Contact Hypothesis Model

Contact Hypothesis Model preview image

1 collaborator

Charis_psaltis_photo Charis Psaltis (Author)

Tags

(This model has yet to be categorized with any tags)
Visible to everyone | Changeable by the author
Model was written in NetLogo 6.3.0 • Viewed 1233 times • Downloaded 20 times • Run 0 times
Download the 'Contact Hypothesis Model' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

It is a simulation of two groups with a history of conflict interacting under various constraints (geographical,legal and social psychological) under the assumption on the basis of Gordon Allport's contact hypothesis that contact can lead to the reduction of prejudice. This simulation was inspired by the situation in Cyprus which is completely geographically divided in two parts where Greek Cypriots and Turkish Cypriot live in complete separation after 1974. From 1974 to 2003 no crossing of the UN patrolled Buffer Zone (called green line) was allowed. However, after 2003 crossing between the two sides is allowed.

HOW IT WORKS

There is a general rule about the initial condition of setup where members of the two groups live in complete separation and interact only in one side of the divide. However, the percentage of people from each community that are allowed (for legal reasons) or willing for social psychological reasons to cross the line can be controlled by sliders. The actors are randomly assigned a level of prejudice from 1-10 with 10 being the highest possible level of prejudice. Another rule in the simulation is that actors that have prejudice level over a certain threashhold would not be willing to interact with outgroup members. This threashold can be varied with a slider. Their prejudice level can be reduced by a prejuce reduction factor that can be varied by a slider every time they interact with an outgroup member. There are also two monitors in the setting that measure on every tick the mean prejudice level of the actors of each community (group). The number of members of each community (group) can also be varied with a slider.

HOW TO USE IT

By pressing the setup button the initial position of the members of the two communities in complete separation depending on their numbers is set in place. Once the go button is pressed then the actors start moving in the one side or both sides of the divide depending on the rules set by the sliders.

Two liders control the number of actors in each group varying from 0-100.

Two sliders control the percentage of actors frome each community that are allowed or willing to cross varyng from 0-1.

Another slider controls the prejudice reduction factor that can vary from 0-1.

The monitors are updated on every tick and report the mean prejudice level of each group. Similarly the mean prejudice level for each group is plotted on the graph with two pens corresponding to the colours of the groups.

THINGS TO NOTICE

Notice how resilient as a process prejudice reduction is even with the application of heavy constraints on crossings and interaction. In the smaller community, all other being equal prejudice reduction shows a sharper decrease. This is probably due to the higher density of population of outgroupers that they meet when they cross.

THINGS TO TRY

Try to move the sliders the set the simulation according to the characteristics of the situation you are exploring. For example for Cyprus the suggested sliders would be as follows:

group-a-size=80 group-b-size=20 prejudice-reduction-factor=0.36 percentage-a-cross=0.70 percentage-b-cross=0.70 interaction-threashold=8

EXTENDING THE MODEL

The model could be extended to simulate the four conditions of Allport that were found by Pettigrew and Tropp (2006) to maximise the beneficial prejudice reduction effects of contact: equal status, common goal, aquaintance potential, support by authorities. It can also incoporate social networks of interaction of ingroup or outgroup networks as social influence sources that effect the prejudice levels of individuals depending on the ideology of these networks.

NETLOGO FEATURES

NA

RELATED MODELS

segregation, party

CREDITS AND REFERENCES

This model can be cited as Psaltis, C. (2023). An ABM model simulating intergroup contact between Greek Cypriots and Turkish Cypriots in divided Cyprus

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
]

breed [ group-a-members group-a-member ]
breed [ group-b-members group-b-member ]

group-a-members-own [ crossing-allowed? prejudice ]
group-b-members-own [ crossing-allowed? prejudice ]

to setup
  clear-all

  ; Draw the horizontal line
  ask patches with [pycor = 0] [ set pcolor green ]

  create-group-a-members group-a-size [
    set color gray
    set shape "person"
    set size 1.5
    set crossing-allowed? (random-float 1 <= percentage-a-cross)
    set prejudice 1 + random 10
    setxy random-xcor (min-pycor + 1 + random (abs 0 - min-pycor - 1))
  ]
  create-group-b-members group-b-size [
    set color orange
    set shape "person"
    set size 1.5
    set crossing-allowed? (random-float 1 <= percentage-b-cross)
    set prejudice 1 + random 10
    setxy random-xcor (1 + random (abs max-pycor - 1))
  ]
  reset-ticks
end 

to update-plot [mean-prejudice-a mean-prejudice-b]
  set-current-plot "Mean Prejudice Levels"
  set-current-plot-pen "group-a"
  plot mean-prejudice-a

  set-current-plot-pen "group-b"
  plot mean-prejudice-b
end 

to go
  ask turtles [
    move
    interact
  ]

  let mean-prejudice-a mean [prejudice] of group-a-members
  let mean-prejudice-b mean [prejudice] of group-b-members

  update-plot mean-prejudice-a mean-prejudice-b

  tick
end 

to move
  let old-xcor xcor
  let old-ycor ycor

  rt random 50 - 25
  if can-move? 1 [
    fd 1
  ]

  ifelse breed = group-a-members [
    if ycor >= 0 and not crossing-allowed? [
      setxy old-xcor old-ycor
    ]
  ] [
    if ycor <= 0 and not crossing-allowed? [
      setxy old-xcor old-ycor
    ]
  ]
end 

to interact
  let other-turtle one-of other turtles-here
  if other-turtle != nobody [
    ifelse breed = group-a-members [
      if [breed] of other-turtle = group-b-members [
        if prejudice < interaction-threshold [
          set prejudice prejudice - (prejudice * prejudice-reduction-factor)
          ask other-turtle [ set prejudice prejudice - (prejudice * prejudice-reduction-factor) ]
        ]
      ]
    ] [
      if [breed] of other-turtle = group-a-members [
        if prejudice < interaction-threshold [
          set prejudice prejudice - (prejudice * prejudice-reduction-factor)
          ask other-turtle [ set prejudice prejudice - (prejudice * prejudice-reduction-factor) ]
        ]
      ]
    ]
  ]
end 




There is only one version of this model, created over 2 years ago by Charis Psaltis.

Attached files

File Type Description Last updated
Contact Hypothesis Model.png preview Preview of Interface over 2 years ago, by Charis Psaltis Download

This model does not have any ancestors.

This model does not have any descendants.