Conway’s Game of Life

patches-own [
  next-pcolor ;; the next state is calculated using current pcolor
]

;; clear the board and create some life

to setup
  clear-all
  reset-ticks

  ;; make the world with custom size
  resize-world 0 (world-size - 1) 0 (world-size - 1)
  set-patch-size floor ( 50 / (sqrt world-size) )

  ;; use next-pcolor to initialize pcolor
  ask patches [
    ifelse random 100 < init-life [
      set next-pcolor green
    ][
      set next-pcolor white
    ]
    set pcolor next-pcolor
  ]
end 

;;
;; main function
;;

to go
  ifelse synchronous [
    ask patches [
      simulate-life
    ]
    ask patches [
      update-color
    ]
  ][
    ask patches [
      simulate-life
      update-color
    ]
  ]

  tick
end 

;;
;; calculate the updating rule
;; and save it the next state
;;

to  simulate-life
  let x (count neighbors with [ pcolor = green] )

  ;; set plabel x ;; [debug]

  ifelse pcolor = green [
    ifelse x < 2 or x >= 4 [ ;; x>=4 (weak inequality) - standard rule
      set next-pcolor white ;; ie. die
    ][
      set next-pcolor green ;; ie. stay alive
    ]
  ][ ;; pcolor = white
    if x = 3 [
      set next-pcolor green ;; ie. live
    ]
  ]
end 

;;
;; update the state
;;

to update-color
  set pcolor next-pcolor
end