guanacos_vs_ovejas

1 collaborator

Ulises Balza (Author)

SOBRE EL MODELO

Este modelo explora la dinamica de competencia interespecIfica para el caso de dos herbIvoros, el guanaco y la oveja. Esta inspirado en recientes discusiones sobre la coexistencia de estas dos especies en paisajes naturales de Patagonia (Oliva et al. 2019, Marino et al. 2020, Oliva et al. 2020) y en un modelo clasico de herbivoria en NetLogo (Wilensky 2001).

COMO USARLO

SETUP para generar las condiciones iniciales GO para comenzar la simulacion

La unica diferencia global es que los guanacos se mueven mas y son mas eficientes energeticamente (i.e., gastan menos energia en relacion a la distancia que recorren). Eso genera que en condiciones iguales de competencia excluyan (a largo plazo) a las ovejas, pero que al mismo tiempo su capacidad de carga sea menor.

Por defecto, los dos tipos de vegetacion (verde y amarillo) ofrecen la misma energia y se regeneran a la misma tasa. Los individuos nacen con un valor de energia de entre 0 y 10. Cuando ese valor disminuye por debajo de 0 mueren, y cuando aumenta por encima de 20, producen una cria a la vez que disminuyen su energia a la mitad. Cada vez que encuentran un parche de vegetacion (verde o amarillo) lo transforman en un parche vacio (negro), incorporando la energia correspondiente (energia-pasto-amarillo o energia-pasto-verde).

INTERRUPTORES DE OTROS PROCESOS

Es posible activar otros procesos para estudiar como puede generarse coexistencia en este sistema

Heterogeneidad: se genera un gradiente ambiental O-E en el que el pasto amarillo es mas abundante hacia el oeste y el pasto verde mas abundante hacia el este.

Territorialidad guanacos: los guanacos tienen un factor de competencia intraespecifica adicional. Evitan estar cerca entre si a un radio de 10 parches, y el movimiento de evitar otros conespecificos les genera un gasto energetico extra

Segregacion de nicho: los guanacos son mas eficaces en consumir el pasto amarillo, mientras que las ovejas son mas eficaces en consumir el pasto verde.

COSAS PARA PROBAR

La idea es probar y discutir diferentes combinaciones de procesos que puedan generar coexistencia estable en este sistema.

MODELOS RELACIONADOS

El modelo "vicunias pasto" (http://modelingcommons.org/browse/onemodel/6808#modeltabsbrowseinfo) explora dinamicas densodependientes para un sistema con una sola especie

CITA

El modelo:

Balza, U (2021). Modelo guanacos vs ovejas espaniol. http://modelingcommons.org/browse/one_model/6811

NetLogo Software:

Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

AGRADECIMIENTOS

Probaron el modelo y sugirieron cambios fundamentales para su funcionamiento y utilidad: Lucia Rodriguez Planes y Nicolas Lois.

REFERENCIAS

Marino, A., Rodriguez, V., & Schroeder, N. M. (2020). Wild guanacos as scapegoat for continued overgrazing by livestock across southern Patagonia. Journal of Applied Ecology, 57(12), 2393-2398. https://doi.org/10.1111/1365-2664.13536
Oliva, G., Paredes, P., Ferrante, D., Cepeda, C., & Rabinovich, J. (2019). Remotely sensed primary productivity shows that domestic and native herbivores combined are overgrazing Patagonia. Journal of Applied Ecology, 56(7), 1575-1584. https://doi.org/10.1111/1365-2664.13408
Oliva, G., Paredes, P., Ferrante, D., Cepeda, C., & Rabinovich, J. (2020). Are Patagonia grasslands being overgrazed? A response to Marino et al.(2020). Journal of Applied Ecology, 57(12), 2399-2405. https://doi.org/10.1111/1365-2664.13753
Wilensky, U. (2001). NetLogo Rabbits Grass Weeds model. http://ccl.northwestern.edu/netlogo/models/RabbitsGrassWeeds. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [guanaco guanacos]
breed [oveja ovejas]
guanaco-own [ energy ]
oveja-own [ energy ]

to setup
  clear-all
  setup-vegetacion
  set-default-shape guanaco "guanaco"
  set-default-shape oveja "oveja"
  create-guanaco guanacos-inicial [
    set size 6
    setxy random-xcor random-ycor
    set energy random 10  ;start with a random amt. of energy
  ]
  create-oveja ovejas-inicial [
    set size 6
    setxy random-xcor random-ycor
    set energy random 10  ;start with a random amt. of energy
  ]
  reset-ticks
end 

to go
   grow-vegetacion

  ask guanaco
  [ move-guanaco
    eat-grass-guanaco
    reproduce-guanaco
    death-guanaco
 if territorialidad-guanacos [exclusion-vecinos] ]

   ask oveja
  [ move-oveja
    eat-grass-oveja
    reproduce-oveja
    death-oveja ]
  tick
end 

to setup-vegetacion
  ask n-of 7000 patches [set pcolor green]
   ask n-of 7000 patches [set pcolor yellow]
  if heterogeneidad [
    ask n-of 2000 patches with [(pxcor >= -60) and (pxcor <= -10)]
    [set pcolor yellow]
    ask n-of 2000 patches with [(pxcor >= 20)]
    [set pcolor green] ]
end 

to grow-vegetacion ;gradiente de vegetacion
  ask patches [
    if pcolor = black [
      if random-float 1000 < crecimiento-amarillo [ set pcolor yellow ]
      if heterogeneidad [if random-float 1000 < crecimiento-amarillo * 3
        and pxcor <= 10 [ set pcolor yellow ]
      if random-float 1000 < crecimiento-amarillo * 5
        and pxcor <= -40 [ set pcolor yellow ]]
      ;mucha más chance de crecer hacia el W

      if random-float 1000 < crecimiento-verde [ set pcolor green ]
      if heterogeneidad [if random-float 1000 < crecimiento-verde * 2
      and pxcor >= 10 [ set pcolor green ] ; más chance de crecer hacia el E
          ] ]]
end 

to move-guanaco
  rt random 90
  lt random 90
  fd 1
  set energy energy - 0.5 ;guanaco más eficiente para moverse
end 

to exclusion-vecinos
   if count guanaco in-radius 10  > 2
  [rt 180
  fd 0.5
  set energy energy - 0.5 ]
end 

to move-oveja
  rt random 90
  lt random 90
  fd 0.5
  set energy energy - 0.3
end 

to eat-grass-guanaco
  if pcolor = green
  [ set pcolor black
    set energy energy + energia-pasto-verde
    if segregacion-de-nicho [ set energy energy - energia-pasto-verde / 5]
  ]
  if pcolor = yellow
  [ set pcolor black
    set energy energy + energia-pasto-amarillo ]
end 

to eat-grass-oveja
  if pcolor = green
  [ set pcolor black
    set energy energy + energia-pasto-verde ]
    if pcolor = yellow
  [ set pcolor black
    set energy energy + energia-pasto-amarillo
    if segregacion-de-nicho [ set energy energy - energia-pasto-amarillo / 5] ]
end 

to reproduce-guanaco
  if energy > 20
    [ set energy energy / 2
      hatch 1 [ fd 1 ] ]
end 

to reproduce-oveja
  if energy > 20
    [ set energy energy / 2
      hatch 1 [ fd 1 ] ]
end 

to death-guanaco
  if energy < 0 [ die ]
end 

to death-oveja
  if energy < 0 [ die ]
end

There are 6 versions of this model.

Uploaded by	When	Description	Download
Ulises Balza	over 2 years ago	actualizado	Download this version
Ulises Balza	over 2 years ago	actualizado	Download this version
Ulises Balza	over 2 years ago	actualizado	Download this version
Ulises Balza	over 2 years ago	actualizado	Download this version
Ulises Balza	over 2 years ago	actualizado	Download this version
Ulises Balza	over 2 years ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
guanacos_vs_ovejas.png	preview	Preview for 'guanacos_vs_ovejas'	over 2 years ago, by Ulises Balza	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo