Movilidad y propagacion de virus

1 collaborator

¿DE QUÉ TRATA?

Este es un modelo que muestra cómo se modifica la velocidad de propagación de un virus de acuerdo a la cantidad de población inmóvil y cómo contribuye a lo que coloquialmente se le ha llamado "aplanar la curva".

CÓMO FUNCIONA

Existe una población sana (círculos verdes), la cual un porcentaje se mantiene fija emulando la restricción "quédate en casa" y el resto se desplaza de manera aleatoria en el espacio de la pantalla. Una persona de la población móvil está enferma (círculo rojo) de un virus que, al entrar en contacto con gente sana la infecta. Esta nueva gente infectada a su vez infecta a más gente sana. La gente infectada es removida de la pantalla, ingresa al hospital y ocupa una cama. El tiempo que deja pasar cada persona entre estar infectada y decidir hospitalizarse es aleatorio. Después de cierto tiempo de estar en cama se vuelve inmune, deja libre la cama y reaparece en pantalla de manera móvil (círculo gris). Esta dinámica se da en un contexto de cantidad limitada de camas de hospital disponibles. La simulación se detiene cuando ya no hay gente enferma o cuando ya no hay más camas disponibles.

CÓMO USAR EL MODELO

1) Asignar una cantidad de población total con el deslizador "poblacion". 2) Determinar el porcentaje de población que se mantendrá fija en el campo "%poblacion-fija". 3) Determinar el número total de camas de hospital en el campo "camas". 4) Presionar el botón "preparar" para generar la población asignada. 5) Presionar el botón "iniciar" para iniciar o pausar el modelo.

COSAS QUÉ NOTAR

Observar en la gráfica si en algún momento la cantidad de población enferma supera a la cantidad de camas disponibles, lo cual es un escenario no deseado.

Observar cómo se "aplana la curva" al aumentar el porcentaje de personas fijas.

COSAS A PROBAR

Probar con diferentes porcentajes de personas fijas y comparar los resultados de cantidad de población enferma. Probar con estos porcentajes hasta que la cantidad de población enferma no supere la cantidad de camas disponibles, lo cual es un escenario deseado.

CRÉDITOS Y REFERENCIAS

La elaboración de este modelo se inspiró en el artículo del Washington Post titulado "Por qué brotes como el del coronavirus crecen exponencialmente y cómo ‘aplanar la curva’" de Harry Stevens (https://www.washingtonpost.com/graphics/2020/world/corona-simulator-spanish/)

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

;:::::::::::::::::::::::::::::::::::::::::::::::: P R O P A G A C I Ó N   D E   V I R U S :::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::Código y diseño: Dr. Javier Sadoval Félix:::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::Contacto: jarquisol@gmail.com:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
globals [camas-disponibles]
turtles-own
  [ enferma?
    inmune?
    movil?
    tiempo-enfermo
    tiempo-restante-para-internarse]

to setup
  clear-all
  preparar-tortugas
  actualizar-visualizacion
  set camas-disponibles camas
  reset-ticks
end 

to go
  ask turtles [
    if movil? [fd .3]
    if enferma? [
      infectar
      set tiempo-enfermo tiempo-enfermo + 1
      set tiempo-restante-para-internarse tiempo-restante-para-internarse - 1

    if tiempo-restante-para-internarse = 0 [
      set camas-disponibles camas-disponibles - 1
      set hidden? true]
    ]

    if enferma? and tiempo-enfermo = 300 [
      set enferma? false set inmune? true
      if hidden? [set camas-disponibles camas-disponibles + 1]
      set hidden? false
      if movil? = false [set movil? true]
  ]]

  actualizar-visualizacion
  if count turtles with [enferma?] = 0 [
    user-message "Ya no hay población enferma"
    stop]
  if camas-disponibles = 0 [
    user-message "Ya no hay camas disponibles"
    stop]
  tick
end 

to preparar-tortugas
  create-turtles poblacion
    [ setxy random-xcor random-ycor
      set movil? true
      set size 1
      set shape "circle"
      set color green
      set inmune? false
      saludable ]
  ask n-of (poblacion * (%poblacion-fija / 100))  turtles [set movil? false]
  ask n-of 1 turtles with [movil? = true]
    [ enfermarse
      set tiempo-restante-para-internarse random 300]
end 

to actualizar-visualizacion
  ask turtles [
    ifelse enferma?
    [set color red ]
    [ifelse inmune? [set color grey ] [set color green]]
  ]
end 

to saludable
  set enferma? false
end 

to enfermarse
  set enferma? true
  set tiempo-enfermo tiempo-enfermo + 1
end 

to infectar
  if hidden? = false [
  ask other turtles-here with [ not enferma? and not inmune? ] [
    enfermarse
    set tiempo-restante-para-internarse random 150
  ]]
end

There is only one version of this model, created about 4 years ago by Javier Sandoval.

Attached files

File	Type	Description	Last updated
Movilidad y propagacion de virus.png	preview	Preview for 'Movilidad y propagacion de virus'	about 4 years ago, by Javier Sandoval	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo