Infectious Disease Outbreak-daily cases and daily new cases

;;
;; This model is developed by Dr. Lin Xiang at the University of Kentucky. Contact: lin.xiang@uky.edu
;;
;; If you see this page rather than a "download" button when downloading the model, click the "download" icon
;; in your browser to download this model file.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


turtles-own [ days-after-exposure  days-of-sick labeled]
Patches-own [ ]
Globals [ watching  max-daily-cases daily-new-cases max-daily-new-cases]

to setup
  ca
  setup-turtles

   set watching false

  reset-ticks
end 

to setup-turtles
  create-turtles population-size
  [set color 68
    set size 1.25
    set labeled 0
    set shape "person"
    setxy random-xcor random-ycor
  ]
end 

to go

if ticks > incubation-period and count turtles with [color = red] = 0 [stop]

  set daily-new-cases 0
  move
  transmission
  incubation
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask turtles with [shape = "person"]
  [right random 360 forward mobility]
end 

to add-a-carrier
  ask one-of turtles                     ;choose a random person
  [set color orange                      ;set the color as orange (carrier color)
  ]
end 

to transmission
  ask turtles with [color = orange]                                              ;Hi, carriers
  [let susceptible-person one-of other turtles in-radius 1.5 with [color = 68]   ;Are there any susceptible people near you (within a radius of 1.5)?
    if susceptible-person != nobody                                              ;If there is at least one
    [ask susceptible-person                                                      ;ask the suscetiple person
      [ if random 100 < transmission-rate                                        ;at the defined transmission rate
        [set color orange]                                                       ;to become a carrier (orange color)
      ]
    ]
  ]
end 

to incubation
  ask turtles with [color = orange]                    ;Hi carriers
   [ifelse days-after-exposure < incubation-period     ;If the number of days after you get infected is smaller than the defined incubation period
    [set days-after-exposure days-after-exposure + 1]  ;increase the number of days after exposure by 1
    [set color red set shape "house"                   ;otherwise, become infectious (red color)
           set daily-new-cases daily-new-cases + 1     ;count daily neew cases
           if daily-new-cases > max-daily-new-cases    ;find the max daily new cases
            [set max-daily-new-cases daily-new-cases]  ]
   ]
end 

to sickness
  ask turtles with [color = red]          ;Hi sick people,
  [ifelse days-of-sick <= illness-period             ;if you have not been sick for 15 days
    [set days-of-sick days-of-sick + 1]   ;remain sick and increase the number of sick days by 1
    [ifelse random 100 < mortality        ;otherwise, at the define mortality rate
      [die]                               ;die
      [set color blue set shape "person"] ;or recover
    ]
   ]
end 

to vaccination
  let num-of-susceptible (count turtles with [color = 68])              ;find the number of susceptible people
  let num-of-vaccinated  (num-of-susceptible * vaccination-rate * 0.01) ;calculate number of susceptubel people to be vaccinated
  ask n-of num-of-vaccinated turtles with [color = 68]                  ;find these many susceptible people
     [set color blue]                                                   ;set as immune (blue)
end 

to find-max-daily-cases
  if count turtles with [color = red ] > max-daily-cases        ;Count the infectious.If it is greater than the current record of max daily cases
  [set max-daily-cases count turtles with [color = red ]]       ;update the max daily case
end 

to watch-an-infected-person
  watch one-of turtles with [color = red]
end 

to label-a-person

  if any? turtles = false [user-message "Nobody is here." stop]


  if mouse-inside? [
    if mouse-down? [
      let labeled-person min-one-of turtles [distancexy mouse-xcor mouse-ycor]
      if labeled-person != nobody [
        ask labeled-person [set label "me" set labeled 1]      ;label the 1st selected person as me
        watch labeled-person]
  ]]


 if count turtles with [labeled = 1] >= 1 [stop]   ;disable the button when one person is labelled.
end 

to unselect

  ask turtles
  [set labeled 0
    set label ""]
  rp
end