Equilíbrio Químico

No preview image

1 collaborator

Marcos Taira (Author)

O QUE É O MODELO?

Esse modelo com fim didático, baseado no modelo "Wilensky, U. (1998). NetLogo Chemical Equilibrium model. http://ccl.northwestern.edu/netlogo/models/ChemicalEquilibrium. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL", adaptado e traduzido para português mostra como um simples sistema químico chega em diferentes estados de equilíbrio de acordo com os níveis de concentração dos reagentes iniciais. Equilíbrio é o termo que se usa para descrever um sistema no qual não há mudanças macroscópicas. Isso significa que o sistema aparenta como se não estivesse nada acontecendo. Na verdade, em todos os sistemas químicos, os processos em nível atômico continuam mas em um equiílibrio que não provoca mudanças macroscópicas. Esse modelo simula duas simples reação entre quatro moléculas. As reações podem ser escritas dessa forma:

        A + B =======> C + D

        C + D =======> A + B

Também pode ser escrita como uma simples e reversível reação.

        A + B <=======> C + D

Um simples exemplo de tal reação na vida real é a reação que ocorre quando monóxido de carbono reage com dióxido de nitrogênio para produzir dióxido de carbono e monóxido de nitrogênio (ou óxido de nitrogênio). A reação reversa (quando dióxido de carbono e monóxido de nitrogênio reagem para formar monóxido de carbono e dióxido de nitrogênio) também é possível. Embora todas as substâncias da reação forem gases, poderíamos observar como um sistema atinge equilíbrio, visto que dióxido de nitrogênio (NO₂) é um gás de cor avermelhada visível. Quando o dióxido de nitrogênio (NO₂) se combina com o monóxido de carbono (CO), os produtos resultantes -- monóxido de nitrogênio(NO) e dióxido de carbono (CO₂) -- são incolores, fazendo com que o sistema perca um pouco de sua cor avermelhada. Por fim, o sistema chega a um estado de equilíbrio com alguns dos "reagentes e alguns dos "produtos" presentes.

Embora o quanto de reagente e produto um sistema termina depende de um número de fatores (incluindo, por exemplo, o quanto de energia é liberada quando uma substância reage ou a temperatura do sistema), esse modelo focaliza nas concentrações dos reagentes.

COMO FUNCIONA

No modelo, moléculas azuis e amarelas podem reagir com outras como verdes e rosas. A cada tick, cada molécula se move randomicamente dentro da simulação encontrando outras molécuals. Se encontra uma molécula com a qual ela pode reagir (como por exemplo, uma amarela encontrando uma azul, ou uma rosa encontrando uma verde, a reação acontece. Porque moléculas azuis e amarelas reagem para produzir moléculas verdes e rosas, moléculas verdes e rosas reagem para produzir azuis e amarelas, e eventualmente, um equilíbrio químico é alcançado.)

Para impedir que as moléculas reagem duas vezes ao mesmo tempo, cada molécula possui um cronômetro que é zerado a cada dois tiques. permitindo que a molécula reaja novamente.

COMO USAR

Os deslizadores das "moléculas-amarelas" e das "moléculas azuis" determinam a quantidade inicial de moléculas amarelas e azuis. Uma vez que esse deslizador é ajustado, o usuário deve clicar em configurar, onde as moléculas serão criadas e distribuídas na simulação.

O botão "Iniciar" começa a simulação. As moléculas se movem randomicamente e reagem com as outras, mudando de cor para representar o rearranjamento dos átomos em diferentes estruturas moléculares. O sistema logo entra em equilíbrio.

Quatro monitores mostram o quanto de cada molécula está presente no sistema. O gráfico "montante de moléculas" mostra o quanto cada molécula esteve presente durante o tempo.

COISAS NOTÁVEIS

Você pode perceber que o número de moléculas do produto é limitado pela menor quantidade de reagentes inicias. Perceba que sempre há o mesmo número de moléculas de produto, pois elas são formadas em uma correspondência de um para um com o outro.

COISAS PARA O PROFESSOR TESTAR EM CLASSE

Como dois montantes diferentes de reagentes afetam no equilíbrio final? As quantidades absolutas são importantes, é a diferença entre as quantidades ou o que importa é a proporção entre os dois reagentes?

Tente setar as moléculas amarelas em 400 e as azuis em 20, 40, 100, 200, 400 em 5 simulações seguidas. Qual tipo de equilíbrio você previu em cada caso? Algumas taxas são previsíveis?

O que acontece quando você inicia com o mesmo número de moléculas amarelas e moléculas azuis? Depois de iniciar o modelo, qual a relação entre a contagem dessas duas moléculas?

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

turtles-own [
  ready-timer  ;; Cronômetro que tem com função impedir que as moléculas entrem
  ;;imediatamente em uma reação reversa.
]

;;Configurações iniciais

to setup
  clear-all
  set-default-shape turtles "circle"
  create-turtles moleculas-azuis [
    setup-molecules blue
  ]
  create-turtles moleculas-amarelas [
    setup-molecules yellow
  ]
  reset-ticks
end 

to setup-molecules [c] ;; turtle procedure
  set ready-timer 0 ;;Cronômetro que indica se a molécula está pronta ou não para reagar
  set color c ;;para zero, a cor da molécula, e a posição aleatória da molécula em x e y.
  setxy random-xcor random-ycor ;;
end 


;;  Procedimentos de tempo de execução

;;  As turtles se mexem e verificam se há uma reação. As turtles que têm um temporizador também o reduzem em um tique.

to go
  ask turtles [
    if ready-timer > 0 [
      set ready-timer ready-timer - 1
    ]
    wiggle

    ;;Se uma molécula azul se encontra com uma amarela, elas se tornam verde e rosas, respectivamente.
    check-for-reaction blue yellow green pink

    ;;Se uma molécula verde se encontra com uma rosa, elas se tornam azul e amarelas, respectivamente.

    check-for-reaction green pink blue yellow

  ]
  tick
end 

;; As turtles recebem um leve giro aleatório em sua direção.

to wiggle ;; Procedimento da turtle
  fd 1
  rt random-float 2
  lt random-float 2
end 

;; Uma reação é definida por quatro cores: As cores das duas moléculas que podem potencialmente
;; reagir entre si(molécula-cor1 e molécula-cor2) e a cor das duas moléculas
;; que serão produzidas se uma tal reação acontecer(produto de cor1 e produto de cor2).

to check-for-reaction [ reactant-1-color reactant-2-color product-1-color product-2-color ]
  ;; Primeiramente, verifica-se se a reação está pronta para ser executada
  ;; E se as cores estão corretas para ocorrer as reações.
  if ready-timer = 0 and color = reactant-1-color [
    ;; Tentativa de achar parceiro apropriado para reação

    if any? turtles-here with [ color = reactant-2-color ] [
      ;; condicional para identificar se há uma reação e executá-la
      react product-1-color
      ask one-of turtles-here with [ color = reactant-2-color ] [ react product-2-color ]
    ]
  ]
end 

;; Quando uma molécula reage, muda sua cor e seta uma nova direção,
;; e um temporizador que lhe dará tempo o suficiente se movimentar
;; antes de reagir novamente

to react [ new-color ]
  set color new-color
  rt random-float 360
  set ready-timer 2
end

There are 4 versions of this model.

Uploaded by	When	Description	Download
Marcos Taira	over 4 years ago	Reverted to older version	Download this version
Marcos Taira	over 4 years ago	Reverted to older version	Download this version
Marcos Taira	over 4 years ago	Pequena mudança no código e na info	Download this version
Marcos Taira	almost 5 years ago	Initial upload	Download this version

Attached files

No files

This model does not have any ancestors.

This model does not have any descendants.

NetLogo