Sylvatic Yellow Fever model

This model is seeking new collaborators — would you please help?

1 collaborator

Antônio Ralph Medeiros de Sousa (Author)

WHAT IS IT?

This model simulates the transmission and dispersal dynamics of sylvatic yellow fever in a closed population of humans, monkeys, and mosquitoes. The user will be able to simulate and identify in which situations the virus is more (or less) likely to spread among the human population living close a forest where monkeys and mosquitoes are infected.

Briefly, yellow fever is an infectious disease whose etiological agent is the yellow fever virus (YFV), which is transmitted to humans and non-human primates through the bite of infected mosquitoes. Illness ranges from a fever and body aches to severe liver disease with bleeding and jaundice (yellowing skin). In tropical and subtropical areas of Africa and South and Central America, the jungle (sylvatic) cycle of the disease has been observed, with the virus circulating in forested areas where wild mosquitoes transmit YFV to monkeys and sometimes to humans that visit, work or live close the forest. Outbreaks of yellow fever occurred regularly in urban areas of the Americas until the first half of the twentieth century, transmitted to humans by the Aedes aegypti mosquito. With the development of the YFV vaccine and the control programs to eliminate the Aedes aegypti, the urban circulation of yellow fever was disrupted. However, the occurrence of YFV outbreaks in forest areas in the vicinity of cities, with the onset of human cases, raises great concern about the possibility of the virus circulating again in urban areas. This concern is reinforced by the fact that the urban vector Aedes aegypti is a widespread and abundant mosquito in most cities of the South and Central America, and in many regions the human population has low vaccination coverage.

By manipulating the model parameters related to human, monkey, and mosquito populations the user can simulate scenarios of higher risk for the virus to spread through the human population.

Overall, this model helps the user to understand: 1) the transmission dynamics of a vector-borne disease involving multiple host and vector species. 2) the importance of high vaccine coverage in human populations living in YF risk areas 3) how differences in vector competence of urban and wild mosquitoes can influence the spread of the virus on the different environments 4) how outbreaks in the human population can be influenced by mobility and the presence of people into forest areas where YFV circulates 5) the effect of the abundance of human, monkey, and mosquito populations on the spread of the virus 6) how the mortality rate and daily biting rate of mosquitoes (which may be natural or affected by control and prevention actions) affect the spread of the virus.

HOW IT WORKS

The world is divided into three environments: forest (green patches), border (pink patches), and urban (gray patches).

There are four types of agents: humans (person shape), non-human primates (circle shape), urban-mosquitoes (triangle shape), and forest-mosquitoes (square shape). Humans and urban-mosquitoes move randomly, interact, and 'live' in the urban patches, while monkeys and forest-mosquitoes move randomly, interact, and 'live' in the forest. All different types of agents can move and interact on the border (patches between urban and forest). A choose proportion of humans can enter and move inside the forest.

All agents can become infected and transmit the virus at rates that will depend on the selected parameters.

Mosquitoes follow an SEI (Susceptible - Exposed - Infected) transmission model. Susceptible individuals are exposed to the virus and may enter a latent period (14 days) in which the virus has already infected the individual but cannot yet be transmitted. After this, the infectious period begins and the mosquito can transmit the virus to susceptible monkeys and humans. The mosquito will remain infectious for the rest of its life. For simplicity, we chose to keep the mosquito population constant. Thus, when a particular mosquito dies, another one is born in the susceptible state.

Humans and monkeys follow an SEIR (Susceptible - Exposed - Infected - Recovery) model. Susceptible humans can become infected by urban or forest mosquito bites. The exposed or latent phase will last 4 days and after this, an infectious period lasting 6 days will begin. During the infectious period, infected humans can transmit the virus to urban and forest mosquitoes. After the infectious period, humans have an 85% chance of recovering and becoming immune to the virus. If they do not recover, they will enter the toxic phase (the severe form of the disease), which lasts 7 days. At this stage, individuals remain ill but there is no further transmission of the virus to mosquitoes. At the end of the toxic phase, individuals will have a 50% chance of recovering and becoming immune; otherwise, they will die. For monkeys, the only difference from humans is that after the infectious period everyone will enter the toxic phase of the disease that will last 10 days. After this, only 20% of monkeys will survive and become immune (this high lethality is similar to what is observed for howler monkeys in forests of South America).

The presence of the virus in the populations is represented by the colors of individuals. Five colors are used: susceptible = white; exposed = red; infected = black; immune = blue; toxic-phase = yellow.

The graph YELLOW FEVER PREVALENCE shows the cumulative percentage of the population of unvaccinated humans and monkeys that were infected with YFV. The graph MOSQUITO INFECTION RATE shows the percentage of infected individuals per day in the populations of forest and urban mosquitoes. The three monitors above the graphs show the total humans that were infected, the infected humans that died, and the total monkeys that died during the outbreak.

When there are only susceptible or immune individuals in the world the simulation stops.

HOW TO USE IT

The SETUP button creates individuals according to the parameter values chosen by the user. The outbreak will start from a certain percentage of infected forest-mosquitoes that will depend on the INITIAL-INFECTED-MOSQUITOES parameter.

Once the simulation has been setup, push the GO button to run the model. GO starts the simulation and runs it continuously until GO is pushed again or the virus is no longer circulating between individuals.

Each time-step can be considered to be a day.

The following is a summary explanation of the sliders in the model.

INITIAL-MONKEYS (initialized to vary between 5 - 50): The total number of monkeys the simulation begins with.

MONKEY-MOBILITY (0.1 - 2): This indicates how mobile the monkey is. The higher the value, the greater the mobility of the individual in each time step. Individuals move randomly by this assigned value.

VACCINE-COVERAGE (0 - 100%): The proportion of human individuals vaccinated against YFV. Vaccinated individuals will already start the simulation as immune.

FREE-WALKERS (0 - 100%): The proportion of human individuals free to entering and walking through the forest. This parameter takes into account that some individuals in the human population will have greater contact with the forest than others and, in this case, will be more exposed to the virus infection if they are not immune.

INITIAL-PEOPLE (30 - 300): The total number of humans the simulation begins with.

HUMAN-MOBILITY (0.1 - 2): This indicates how mobile the person is. The higher the value, the greater the mobility of the individual in each time step. Individuals move randomly by this assigned value.

INITIAL-INFECTED-MOSQUITOES (0.5 - 10%): The probability that each individual of the forest-mosquitoes population has to start the simulation in the infectious state.

MOSQUITO-MORTALITY-RATE (0.01 - 0.5): The probability of a mosquito dying in each time-step after 15 time-steps (minimum life span considered in the model). To simplify the model, the mortality rate is considered equal for urban and forest mosquitoes.

MOSQUITO-DAILY-BITING-RATE (0.2 - 1): The daily rate at which mosquitoes seek for a blood meal. For example, a value of 0.25 means that in a potentially infectious contact there is a 25% chance the mosquito will bite the host.

INITIAL-URBAN-MOSQUITOES (100 - 1000): The total number of urban mosquitoes the simulation begins with. For each individual who dies a new individual is born, so the final number of mosquitoes will be equal to the initial number.

INITIAL-FOREST-MOSQUITOES (100 - 1000): The total number of forest mosquitoes the simulation begins with. For each individual who dies a new individual is born, so the final number of mosquitoes will be equal to the initial number.

U-MOSQ-INFECTION-COMPETENCE (0 - 1): The probability that a susceptible individual from the urban-mosquitoes population has to become infected by biting an infectious human or monkey.

F-MOSQ- INFECTION-COMPETENCE (0 - 1): The probability that a susceptible individual from the forest-mosquitoes population has to become infected by biting an infectious monkey or human.

U-MOSQ-TRANSMISSION-COMPETENCE (0 - 1): The probability that an infectious individual from the urban-mosquitoes population has to transmit the virus to a susceptible human or monkey by biting them.

F-MOSQ-TRANSMISSION-COMPETENCE (0 - 1): The probability that an infectious individual from the forest-mosquitoes population has to transmit the virus to a susceptible monkey or human by biting them.

THINGS TO NOTICE

Note that the outbreak begins with a rapid increase in the number of infected monkeys, which is called epizootics. This event is followed by an increase in the number of infected forest mosquitoes as monkeys are currently serving as virus amplifiers. As monkeys die or survive and become immune, the rate of infection in wild mosquitoes tends to shrink to zero, while the prevalence curve of infected monkeys tends to stabilize.

There are two possibilities of starting an outbreak in humans. A first possibility is that susceptible urban mosquitoes become infected by biting infectious monkeys on the border and transmitting the virus to susceptible humans. The second possibility is that susceptible humans become infected by being bitten by infectious forest mosquitoes and transmit the virus to susceptible urban mosquitoes. In both cases, there is a possibility that an outbreak will start among the human population, and the spread of the virus will depend on the selected parameters (mainly vaccine coverage).

During outbreaks the number of humans who die is less than the total number of infected because around 85% of infected humans tend to recover and become immune, the others 15% enter the toxic phase and around 50% survive. However, these proportions present some variations in outbreaks observed in different places and times, which usually depends on the genetic lineage of the virus, among other factors.

There are many species of non-human primates that can become infected with YFV. This model considers some known infection parameters for howler monkeys, which are primates quite susceptible to YFV and have high mortality rates during outbreaks. Therefore, the number of monkeys killed during simulations will tend to be proportionally higher compared to humans.

THINGS TO TRY

Try to identify which situations may favor an outbreak in the human population by changing one parameter at a time and then using different combinations of these parameters. Which parameters can be considered the most important?

Define a set of parameters and try to identify the minimum proportion of immunization coverage needed to prevent a YFV outbreak from spreading to the human population.

In addition to vaccination coverage, what other parameters (or set of parameters) can prevent the virus from leaving the forest and spreading in urban areas?

EXTENDING THE MODEL

This model assumes that there is no seasonal variation in mosquito abundance. However, this is a very important factor in the dynamics of YFV outbreaks. Try to include seasonal variations in mosquito populations to see how virus transmission behaves over time.

Some of the fixed parameters of the model (such as latency and infectious period in monkeys and humans) can be changed to become means of a statistical distribution.

Different mortality and bite rates could be included for urban and wild mosquitoes.

The inclusion of other mosquito species that act as intermediate vectors and a virus reservoir animal could add complexity to the model and perhaps come a little closer to reality.

NETLOGO FEATURES

In this model, the potential infectious contact between mosquitoes and primates occurs based on a Moore Neighborhood pattern. This means that the infectious individual will select a susceptible individual (if any) from the eight patches adjacent to his.

RELATED MODELS

epiDEM Basic, epiDEM trave and control, HIV, Virus and Virus on a Network are related models.

CREDITS AND REFERENCES

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

Medeiros-Sousa, Antônio Ralph (2019). Sylvatic YF model. School of Public Health, University of São Paulo.

Contact: aralphms@usp.br

Please cite the NetLogo software as:

Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
  forest                  ;; The patches representing the forest
  urban                   ;; The patches representing the urban area
  border                  ;; The patches representing the border between urban and forest
  angle                   ;; Heading for individuals
  vaccinated-humans       ;; The initial number of immune (vaccinated) people
]

breed [u-mosquitoes u-mosquito]      ;; To create a urban mosquito species
breed [f-mosquitoes f-mosquito]      ;; To create a forest mosquito species
breed [humans human]                 ;; To create humans
breed [monkeys monkey]               ;; To create monkeys

u-mosquitoes-own
[susceptible?             ;; If true, the urban mosquito is susceptible
 exposed?                 ;; If true, the urban mosquito is infected but in latent period
 infected?                ;; If true, the urban mosquito is infected and infectious
 min-lifespan             ;; The minimum life span before die
 virus-incubation         ;; The incubation period of the virus in mosquitoes
]
f-mosquitoes-own
[susceptible?             ;; If true, the forest mosquito is susceptible
 exposed?                 ;; If true, the forest mosquito is infected but in latent period
 infected?                ;; If true, the forest mosquito is infected and infectious
 min-lifespan             ;; The minimum life span before die
 virus-incubation         ;; The incubation period of the virus in mosquitoes
]
humans-own
[susceptible?             ;; If true, the human is susceptible.
 exposed?                 ;; If true, the human is infected but in latent period
 infected?                ;; If true, the human is infected and infectious
 immune?                  ;; If true, the human is immune
 toxic-phase?             ;; If true, the human is in toxic-phase (severe disease)
 latent-period            ;; The latent period of the virus
 viremic-time             ;; The time in days that individuals will be infectious and can transmit the virus to mosquitoes
 toxic-phase-time         ;; The time in days that individuals will be in the toxic-phase
 walk-free?               ;; If true, the individual can walk through the forest
]
monkeys-own
[susceptible?             ;; If true, the monkey is susceptible.
 exposed?                 ;; If true, the monkey is infected but in latent period
 infected?                ;; If true, the monkey is infected and infectious
 immune?                  ;; If true, the monkey is immune
 toxic-phase?             ;; If true, the monkey is in toxic-phase
 latent-period            ;; The latent period of the virus
 viremic-time             ;; The time in days that individuals will be infectious and can transmit the virus to mosquitoes
 toxic-phase-time         ;; The time in days that individuals will be in the toxic-phase
]

;;;;
;;;SETUP PROCEDURES
;;;;

to setup
  clear-all
  setup-globals
  setup-host
  reset-ticks
end 

;; creating and assigning colors to patches

to setup-globals
  set border patches with [(pxcor =  0 and abs (pycor) >= 0)]
  ask border [ set pcolor pink ]
  set urban patches with [(pxcor < 0 and abs (pycor) >= 0)]
  ask urban [set pcolor gray ]
  set forest patches with [(pxcor > 0 and abs (pycor) >= 0)]
  ask forest [set pcolor green ]
end 

;; creating initial humans, monkeys, and mosquitoes

to setup-host
  create-humans initial-people
  [ask humans [move-to one-of urban]
   set shape "person"
   set size 1
   set infected? false
   set immune? false
   set susceptible? true
   set exposed? false
   set toxic-phase? false
   set walk-free? false
   if random-float 100 < vaccine-coverage [      ;;; assigning immunity to vaccinated people
    set susceptible? false
    set immune? true
    ]
   if random-float 100 < free-walkers     ;;; defining the people who can walk through the forest.
    [
      set walk-free? true
    ]
   assign-color
  ]
  set vaccinated-humans count humans with [immune?]

  create-u-mosquitoes initial-urban-mosquitoes
  [ask u-mosquitoes [move-to one-of urban]
   set shape "triangle"
   set size 0.3
   set infected? false
   set susceptible? true
   set exposed? false
   assign-color
  ]

  create-f-mosquitoes initial-forest-mosquitoes
  [ask f-mosquitoes [move-to one-of forest]
   set shape "square"
   set size 0.3
   set infected? false
   set susceptible? true
   set exposed? false
   if (random-float 100 < initial-infected-mosquitoes)  ;; defining initial number of infected forest-mosquitoes
    [
      set susceptible? false
      set infected? true
    ]
  assign-color
  ]

  create-monkeys initial-monkeys
   [ask monkeys [move-to one-of forest]
   set shape "circle"
   set size 0.5
   set infected? false
   set susceptible? true
   set immune? false
   set exposed? false
   set toxic-phase? false
   assign-color
   ]
end 

to assign-color  ;; The colors for represent the virus circulation and individual status
    if susceptible? [ set color white ]
    if exposed? [ set color red ]
    if infected? [ set color black ]
    if breed = humans or breed = monkeys [
      if immune? [ set color blue ]
      if toxic-phase? [ set color yellow ] ]
end 

;;;
;;; GO PROCEDURES
;;;

to go
  move-f-mosquitoes
  move-u-mosquitoes
  move-monkeys
  move-humans
  if all? turtles [ not exposed? and not infected? ] and all? humans [ not toxic-phase? ] and all? monkeys [ not toxic-phase? ] [stop]  ;; stopping the simulation
  ask f-mosquitoes with [infected?] [infect-primates]
  ask u-mosquitoes with [infected?] [infect-primates]
  ask monkeys with [infected?] [infect-mosquitoes stop-infect]
  ask humans with [infected?] [infect-mosquitoes stop-infect]
  ask f-mosquitoes with [exposed?] [extrinsic-incubation-period]
  ask u-mosquitoes with [exposed?] [extrinsic-incubation-period]
  ask monkeys with [exposed?] [become-viremic]
  ask humans with [exposed?] [become-viremic]
  ask f-mosquitoes [maybe-die]
  ask u-mosquitoes [maybe-die]
  ask monkeys with [toxic-phase?] [recovery-or-die]
  ask humans with [toxic-phase?] [recovery-or-die]
  tick
end 

to move-monkeys   ;; turtle procedure
  ask monkeys [
    rt random-float 360.0
    forward random-float monkey-mobility
    if xcor < 0 ;; outside forest
    [
      set angle random-float 180
      let new-patch patch-at-heading-and-distance angle (1)
      if new-patch != nobody
      [
        move-to new-patch
      ] ]
    if xcor > (max-pxcor - 0.1)  ;; at the edge of world
      [
        set angle random-float 180
        let new-patch2 patch-at-heading-and-distance angle (-1)
        if new-patch2 != nobody
      [
        move-to new-patch2
      ] ]
    assign-color
  ]
end 

to move-humans  ;; turtle procedure
  ask humans [
    rt random-float 360.0
    forward random-float human-mobility
    if xcor > 0 and not walk-free? ;; outside urban area
    [
      set angle random-float 180
      let new-patch patch-at-heading-and-distance angle (-1)
      if new-patch != nobody
      [
        move-to new-patch
      ] ]
     if xcor > (max-pxcor / 2) and walk-free?  ;; Don't go too far in the woods
    [
      set angle random-float 180
      let new-patch patch-at-heading-and-distance angle (-1)
      if new-patch != nobody
      [
        move-to new-patch
      ] ]
    if xcor < (min-pxcor + 0.1)  ;; at the edge of world
      [
      set angle random-float 180
      let new-patch patch-at-heading-and-distance angle (1)
      if new-patch != nobody
      [
        move-to new-patch
      ] ]
    assign-color
  ]
end 

to move-u-mosquitoes  ;; turtle procedure
 ask u-mosquitoes [
    rt random-float 360.0
    forward random-float 0.2
    if xcor > 0  ;; outside urban area
    [
      set angle random-float 180
      let new-patch patch-at-heading-and-distance angle (-1)
      if new-patch != nobody
      [
        move-to new-patch
      ] ]
    if xcor < (min-pxcor + 0.1)  ;; at the edge of world
      [
        set angle random-float 180
        let new-patch2 patch-at-heading-and-distance angle (1)
      if new-patch2 != nobody
      [
        move-to new-patch2
      ] ]
    assign-color
  ]
end 

to move-f-mosquitoes  ;; turtle procedure
 ask f-mosquitoes [
    rt random-float 360.0
    forward random-float 0.2
    if xcor < 0  ;; outside forest
    [
      set angle random-float 180
      let new-patch patch-at-heading-and-distance angle (1)
      if new-patch != nobody
      [
        move-to new-patch
      ] ]
    if xcor > (max-pxcor - 0.1)  ;; at the edge of world
      [
        set angle random-float 180
        let new-patch2 patch-at-heading-and-distance angle (-1)
        if new-patch2 != nobody
      [
        move-to new-patch2
      ] ]
    assign-color
  ]
end 

to infect-mosquitoes  ;; turtle procedure
 let target-p (u-mosquitoes-on neighbors)
 let hostm one-of (target-p with [susceptible?])
 let target-p2 (f-mosquitoes-on neighbors)
 let hostm2 one-of (target-p2 with [susceptible?])
 if hostm != nobody [
  if  random-float 1 < mosquito-daily-biting-rate [
   if random-float 1 < u-mosq-transmission-competence [
    ask hostm [
      set susceptible? false
      set exposed? true
  ] ] ] ]
 if hostm2 != nobody [
  if  random-float 1 < mosquito-daily-biting-rate [
   if random-float 1 < f-mosq-transmission-competence [
    ask hostm2 [
      set susceptible? false
      set exposed? true
  ] ] ] ]
end 

to infect-primates  ;; turtle procedure
let target-m (humans-on neighbors)
 let hostp one-of (target-m with [susceptible?])
 let target-m2 (monkeys-on neighbors)
 let hostp2 one-of (target-m2 with [susceptible?])
 if breed = u-mosquitoes [
  if hostp != nobody [
    if  random-float 1 < mosquito-daily-biting-rate [
     if random-float 1 < u-mosq-infection-competence [
     ask hostp [
      set susceptible? false
      set exposed? true
    ] ] ] ]
 if hostp2 != nobody [
   if  random-float 1 < mosquito-daily-biting-rate [
    if random-float 1 < u-mosq-infection-competence [
    ask hostp2 [
      set susceptible? false
      set exposed? true
    ] ] ] ] ]
 if breed = f-mosquitoes [
  if hostp != nobody [
    if  random-float 1 < mosquito-daily-biting-rate [
     if random-float 1 < f-mosq-infection-competence [
     ask hostp [
      set susceptible? false
      set exposed? true
    ] ] ] ]
 if hostp2 != nobody [
   if  random-float 1 < mosquito-daily-biting-rate [
    if random-float 1 < f-mosq-infection-competence [
    ask hostp2 [
      set susceptible? false
      set exposed? true
    ] ] ] ] ]
end 

;; the incubation period in mosquitoes

to extrinsic-incubation-period  ;; turtle procedure
  set virus-incubation virus-incubation + 1
  if virus-incubation > 14 [
    if breed = u-mosquitoes [
      set exposed? false
      set infected? true
      ]
    if breed = f-mosquitoes [
      set exposed? false
      set infected? true
      ] ]
end 

;; the start of infectious period

to become-viremic  ;; turtle procedure
  set latent-period latent-period + 1
  if latent-period > 4 [
     set infected? true
     set exposed? false
     ]
end 

;; The end of infectious period

to stop-infect  ;; turtle procedure
  set viremic-time viremic-time + 1
  if breed = humans [
  if viremic-time > 6 [
    ifelse random 100 < 85 [
     set infected? false
     set immune? true
     ] [
      set infected? false
      set toxic-phase? true
      ] ] ]
  if breed = monkeys [
    if viremic-time > 6 [
      set infected? false
      set toxic-phase? true
      ] ]
end 

;; defining the individuals who will survive or die

to recovery-or-die  ;; turtle procedure
  set toxic-phase-time toxic-phase-time + 1
  if breed = humans [
  if toxic-phase-time > 7 [
    ifelse random 100 < 50 [
    set toxic-phase? false
    set immune? true
     ] [
        die ] ] ]
  if breed = monkeys [
  if toxic-phase-time > 10 [
    ifelse random 100 < 20 [
    set toxic-phase? false
    set immune? true
     ] [
        die ] ] ]
end 

;; defining a lifespan to mosquitoes

to maybe-die  ;; turtle procedure
  set min-lifespan min-lifespan + 1
  if min-lifespan > 15 [
  if random-float 1 < mosquito-mortality-rate [
   if breed = u-mosquitoes [
     hatch-u-mosquitoes 1 [
     set infected? false
     set susceptible? true
     set exposed? false
     move-to one-of urban
    ] ]
   if breed = f-mosquitoes [
     hatch-f-mosquitoes 1 [
     set infected? false
     set susceptible? true
     set exposed? false
     move-to one-of forest
    ] ]
    die ] ]
end

There is only one version of this model, created over 5 years ago by Antônio Ralph Medeiros de Sousa.

Attached files

File	Type	Description	Last updated
Sylvatic Yellow Fever model.png	preview	Preview for 'Sylvatic Yellow Fever model'	over 5 years ago, by Antônio Ralph Medeiros de Sousa	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo