Game Of Life

globals[
 backgroundColor
 cellColor 
]

patches-own[
  futurColor
  
]

to start
  clean
  ask n-of population_start patches [ set pcolor cellColor]
  ask patches [ set futurColor pcolor ]
end 

to clean
  clear-all
  set cellColor blue
  set backgroundColor black
  ask patches [ set pcolor backgroundColor ]
  ask patches [ set futurColor pcolor ]
  reset-ticks 
end 

to populate
  ask n-of population_start patches with [pcolor = backgroundColor]  [ 
    set pcolor cellColor
    set futurColor pcolor
    ]
end 

to draw
   if(mouse-down?)[
   ask patch mouse-xcor mouse-ycor [set pcolor cellColor]
 ]
   
   tick
end 

to go
 ask patches [ gameOfLife ]
 
 ask patches [ applyChange]
 
 if(count patches with [pcolor = cellColor] = 0) [stop]
 
 set-plot-x-range (ticks - graph_window) ticks
 tick
end 

to gameOfLife
  
  let cells neighbors with [pcolor = cellColor]
  
  ifelse(pcolor = backgroundColor and count cells = 3)[
    set futurColor cellColor
  ]
  [
    ifelse(pcolor = cellColor and (count cells = 2 or count cells = 3))[
      set futurColor cellColor
    ]
    [
      set futurColor backgroundColor
    ]
  ]
end 

to applyChange
  set pcolor futurColor
end