Penalty Kicks in Soccer

breed [ keepers keeper ]
breed [ takers taker ]

keepers-own [ 
  dive ;;how fast he dives (the taker doesn't move)
  choices 
  choice 
  results
  result
  strategies
  best-strategy 
  tendency
  cheat-sheet1
  cheat-sheet2
  ]

takers-own [ choices choice results best-strategy strategies tendency cheat-sheet1 cheat-sheet2 ] ;;same stuff

turtles-own [ power ] ;;how fast the ball's moving

globals [ 
  ;;for statistics
  goals 
  misses 
  saves 
  
  ;;for functions
  over? ;;true when we know the result of the kick 
  gk ;;the keeper whose turn it is 
  tk ;;the taker whose turn it is
  ball ;;the ball turtle
  
  ;;for plotting
  allresults
  gk-allchoices 
  tk-allchoices 
  gk-tendencies ;;list of each player's tendencies noted after his turn
  tk-tendencies 
  ]


;SETUP FUNCTIONS

to setup
  clear-all-plots
  reset-ticks
  setup-plots
  clr
  ask patches with [ pzcor = -4 and pycor = 1 ] [ 
    if pcolor != green [ line-field set-goal ] 
    ] ;;set up field only if it isn't already set
  setup-turtles
end 

to clr
  ask turtles with [ color != white ] [ die ] ;;clear keepers, takers, and the ball, but not the goal
  set over? false
  set goals 0
  set misses 0
  set saves 0
  set gk-allchoices []
  set tk-tendencies []
  set gk-tendencies []
  set tk-allchoices []
  set allresults []
end 

to line-field
  ask patches with [ pzcor = -4 ] [ set pcolor green ]
  ask patches with [ pycor = 36 or pycor = -18 or (pycor = 18 and abs pxcor <= 30) or (abs pxcor = 30 and 18 <= pycor and pycor <= 36) and pzcor = -4 ] [ set pcolor white ]
  ask patches with [ pycor = 0 and pxcor = 0 and pzcor = -4 ] [ set pcolor white ]
  ask patches with [ precision (distance patch 0 0 0) 0 = 30 and pycor <= -18 and pzcor = -4 ] [ set pcolor white ]
end 

to set-goal
  ask patches with [ (pycor = 38  and abs pxcor <= 12) or (abs pxcor = 12 and 38 >= pycor and pycor >= 36) and pzcor > -4 and pzcor <= 4 ] [ sprout 1 [ set shape "box" set color white set size .5 ] ]
  ask patches with [ pzcor = 4 and pycor < 38 and pycor >= 36 and abs pxcor <= 12 ] [ sprout 1 [ set shape "box" set color white set size .5 ] ]
end 

to setup-turtles
  crt 1 [ ;;create ball
    set size .75 set color orange set shape "circle" setxyz 0 0 -3.125 set ball self 
    ]
  foreach n-values num-takers [ ? * 2 ] [ ;;create num-takers penalty takers
    create-takers 1 [ set size 6 set color red set shape "person" setxyz 36 (35 - ?) -1 set heading 0 ]
    ]
  foreach n-values (num-takers + 1) [ ? * 2 ] [ ;;create num-takers + 1 goalkeepers
    create-keepers 1 [ set size 6 set color yellow set shape "person" setxyz -36 (35 - ?) -1 set heading 0 ]
    ]
  if not Manual [
    ask (turtle-set keepers takers) [ 
      set choices n-values (memory-size * 2) [ one-of (list -1 1) ] ;;randomize previous choices
      set results n-values (memory-size * 2) [ one-of (list 0 0 1 1 1 1 1 1 1 1) ] ;;randomize previous results to success rate of 80%
      learning-setup ;;setup strategies
    ]
  ]
  get-ready
end 

to learning-setup
  set strategies n-values num-strategies [random-strategy]
  set best-strategy first strategies
end 

to get-ready
  ask (turtle-set keepers takers) [ fd 2 ] ;;dequeue
  ask keepers with [ patch-here = patch -36 37 -1 ] [ ;;(head of the keepers queue)
    set gk self move-to patch 0 36 -1 
    ]
  ask takers with [ patch-here = patch 36 37 -1 ] [ ;;(head of the takers queue)
    set tk self move-to patch -6 -10 -1 
    ]
  if not Manual [
    ask (turtle-set gk tk) [ scout ] ;;obtain scouting data
  ]
  ask gk [ save-decision ] ;;both players decide before shot
  ask tk [ shot-decision ] 
end 


;STRATEGY FUNCTIONS
; (Adapted from El Farol Bar)

to-report random-strategy
  report n-values (memory-size + 1) [ 1.0 - random-float 2.0 ]
end 

to-report predict [strategy subhistory]
  report first strategy + sum (map [?1 * ?2] butfirst strategy subhistory)
end 

to update-strategies [ sheet1 sheet2 ]
  let best-score (memory-size ^ 3) + 1
  foreach strategies [
    let score 0
    let kick 1
    repeat memory-size [
      let pred predict ? sublist sheet1 kick (kick + memory-size)
      set choice pred / (abs pred)
      set score score + abs (item (kick - 1) sheet2 - choice)
      set kick kick + 1
    ]
    if (score <= best-score) [
      set best-score score
      set best-strategy ?
    ]
  ]
end 


;DECISION FUNCTIONS

to scout
  ifelse breed = keepers 
  [ set cheat-sheet1 translate [ choices ] of tk [ results ] of tk set cheat-sheet2 [ choices ] of tk ] 
  [ set cheat-sheet1 translate [ choices ] of gk [ results ] of gk set cheat-sheet2 [ choices ] of gk ]
end 

to-report translate [ l1 l2 ]
  report ( map [ ?1 * ?2 ] l1 l2 )
end 

to save-decision
  ifelse not Manual 
  [
    update-strategies cheat-sheet1 cheat-sheet2
    let raw-choice (predict best-strategy sublist cheat-sheet1 0 memory-size) + .000001 ;;to avoid division by zero
    ifelse students = "Goalkeepers"
      [ set choice (raw-choice / abs raw-choice) ] 
      [ ifelse random 100 < teach-nat-tendency [ set choice 1 ] [ set choice -1 ] ] ;;positive = 1 = natural, negative = -1 = non-natural
    set choices fput choice butlast choices ;;choices are limited to memory-size * 2
    set gk-allchoices fput choice gk-allchoices ;;allchoices are unlimited
    set dive (random 20) * .0005 ;;how far he stretches to get the ball is random, since direction of ball is random except left or right
    ifelse choice = 1 ;;1 is natural
      [ set heading -90 ] 
      [ set heading 90 ]
  ]
  [
    set dive (random 20) * .0005
    ifelse random 100 < gk-tendency [ set heading -90 set choice 1 ] [ set heading 90 set choice -1 ]
  ]
end 

to shot-decision
  ifelse not Manual 
  [
    let raw-choice (sum cheat-sheet1) + one-of (list .000001 (-1 * .000001))
    ifelse students = "Penalty Takers"
      [ set choice (raw-choice / abs raw-choice) ] 
      [ ifelse random 100 < teach-nat-tendency [ set choice 1 ] [ set choice -1 ] ]
    set choices fput choice butlast choices
    set tk-allchoices fput choice tk-allchoices
    ask ball [
      ifelse [ choice ] of myself = 1
        [ set heading random-float -1 * (atan 12.2 36) set pitch random-float (atan 8.1 36) set power .04 ]
        [ set heading random-float (atan 12.55 36) set pitch random-float (atan 8.3 36) set power .03 ]
    ]
  ]
  [
    ask ball [
      ifelse random 100 < tk-tendency
        [ set heading random-float -1 * (atan 12.2 36) set pitch random-float (atan 8.1 36) set power natural-power ask myself [ set choice 1 ] ]
        [ set heading random-float (atan 12.55 36) set pitch random-float (atan 8.3 36) set power non-natural-power ask myself [ set choice -1 ] ]
    ]
  ]
end 


;GO FUNCTIONS

to go
  if over? [ 
;     if ticks mod (num-takers + 1) = 0 [ 
;        ask (turtle-set keepers takers) [
;          let Z ind-sequence-Z-score choices count-runs choices 
;          if (abs Z > 2) [ 
;            set rejections rejections + 1 
;          ]
;        ]
;      ]
    if not Manual [
      ask (turtle-set gk tk) [ ;;update tendencies
        set tendency length filter [ ? = 1 ] sublist choices 0 memory-size / memory-size
        ifelse breed = keepers [ set gk-tendencies fput tendency gk-tendencies ] [ set tk-tendencies fput tendency tk-tendencies ] ]
    ]
    move-queue 
    get-ready 
    ask ball [ setxyz 0 0 -3.125 ] 
    set over? false 
    if not Manual [ tick ]
    ]
  ;;if not over, proceed:
  ask ball [ fd power ]
  ask gk [ 
    if [ distance patch 0 0 -10 ] of ball >= 26 and choice * [ choice ] of tk = 1 [ 
      face ball set dive .01 
      ] 
    ] ;;the keeper stretches for the ball if he is near enough
  ask gk [ fd dive ]
  save?
  score?
end 

to move-queue
  ask min-one-of keepers [ distance patch 12 36 -4 ] [ move-to patch -36 (35 - num-takers * 2) -1 set heading 0 set pitch 0 ]
  ask min-one-of takers [ distance patch 0 0 0 ] [ move-to patch 36 (37 - num-takers * 2) -1 set heading 0 ]
end 

to save?
  ask gk [ 
    if distance ball <= 2 and (abs ([ heading ] of ball - 180)) > ((atan -12 36) - 180) and [ pitch ] of ball < (atan 8 36) [ 
      ;;if the ball is between the posts and the distance between it and the keeper is less than or equal to 2
      set misses misses + 1 
      set saves saves + 1 
      set over? true 
      set allresults fput 0 allresults
      if not Manual [
        set results fput 0 butlast results
        ask tk [ set results fput 0 butlast results ]
      ]
      ask ball [
        set heading 270 - heading fd 1 ;;make sure the ball is parried away
      ]
    ]
  ] 
end 

to score?
  ask ball [ if [ pycor ] of patch-here > 36 and (abs (heading - 180) > (atan -12 36) - 180) and pitch < (atan 8 36) [ 
      ;;if the ball passes the goal-line between the posts
      set goals goals + 1 
      set over? true 
      if not Manual [
        ask (turtle-set gk tk) [ set results fput 1 butlast results ]
      ]
      set allresults fput 1 allresults 
      ] 
      ] 
  ask ball [ if [ pycor ] of patch-here > 36 and ((abs (heading - 180) <= (atan -12 36) - 180) or pitch >= (atan 8 36)) [ 
      ;;air-ball
      set misses misses + 1 
      set over? true
      if not Manual [
        ask (turtle-set gk tk) [ set results fput 0 butlast results ]
      ]
      set allresults fput 0 allresults
      ] 
  ]
end 


;;Non-functioning probability functions

;to-report ind-sequence-Z-score [ s r ] ;;reports Z-score of a sequence s with r runs
;  let tot length s
;  let lc 0
;  foreach s [ if ? = -1 [ set lc lc + 1 ] ]
;  let rc tot - lc
;  report (r - (2 * lc * rc / tot) - 1) / sqrt ( (2 * lc * rc * (2 * lc * rc - tot) ) / ((tot ^ 2) * (tot - 1)))
;end

;to-report count-runs [ s ]
;  let runs 0
;  let run? false
;  let prev first s
;  let cnt (length s) - 1
;  foreach (but-first s) [ set cnt cnt - 1
;                          if (run? = false and ? = prev) [ set run? true ]
;                          if (run? = true and (? != prev or cnt = 0)) [ set run? false set runs runs + 1 ]
;                          set prev ? ]
;  report runs
;end