Memory HubNet

;; We represent each card using two turtles, one for the front and one for the
;; back.  The card-back turtles are on top of the card-front turtles, covering
;; them up.  To reveal a card-front, we hide the card-back turtle on top of it.
breed [card-backs card-back]
breed [cards card]

;; Players are invisible turtles that we use to store information about
;; the participants in the game.
breed [players player]
players-own [
  user-name   ;; a string
  matches     ;; a number, how many successful matches so far
  attempts    ;; a number, how may total tries so far
]

globals [
  current-player  ;; holds a player turtle
]

;;
;; Setup Procedures
;;

to startup
  clear-all
  setup
  hubnet-reset
end 

to setup
  ask patches [ set pcolor gray + 3 ]  ;; light gray
  deal
end 

to deal
  ask cards [ die ]
  ask card-backs [ die ]
  ask players
  [
    set attempts 0
    set matches 0
  ]
  set current-player 0

  let card-shapes remove "default" shapes
  let y-max floor (pairs-in-deck * 2 / world-width)
  let x-max pairs-in-deck * 2 mod world-width
  let bounded-patches (patch-set patches with [pycor < y-max]
                                 patches with [pycor = y-max and pxcor < x-max])
  ask n-of pairs-in-deck bounded-patches
  [
    sprout-cards 1
    [
      set shape one-of card-shapes
      set card-shapes remove shape card-shapes
      set size 0.5
    ]
  ]
  ask cards
  [ hatch 1 [ move-to one-of bounded-patches with [not any? cards-here] ] ]
  ask cards
  [
    hatch-card-backs 1
    [
      set color white
      set size 0.8
    ]
    hide-turtle
  ]
  if any? players
  [ hubnet-broadcast "Whose turn?" [user-name] of item current-player sort players ]
  hubnet-broadcast "Your matches" 0
  hubnet-broadcast "Your turns" 0
  hubnet-broadcast "Success %" 0
  hubnet-broadcast "Cards remaining" 0
  hubnet-broadcast "Leader" ""
  hubnet-broadcast "Leader's matches" 0
end 

;;
;; Runtime Procedures
;;

to go
  if not any? cards [
    __hubnet-broadcast-user-message winner-message
    user-message winner-message
    stop
  ]
  listen-clients
end 

to-report winner-message
  let winners players with-max [matches]
  ifelse count winners > 1
  [ report (word "It's a " count winners "-way tie." ) ]
  [ report (word [user-name] of one-of winners " wins!") ]
end 

;;
;; HubNet Procedures
;;

to listen-clients
  while [hubnet-message-waiting?]
  [
    hubnet-fetch-message
    ifelse hubnet-enter-message?
    [ add-player hubnet-message-source ][
      ifelse hubnet-exit-message?
      [ remove-player hubnet-message-source ]
      [
        let p item current-player sort players
        if hubnet-message-tag = "View" and [user-name] of p = hubnet-message-source
        [ ask p [ select-card first hubnet-message last hubnet-message ] ]
      ]
    ]
  ]
end 

to add-player [name]
  create-players 1
  [
    hide-turtle
    set user-name name
    set matches 0
    set attempts 0
    hubnet-send user-name "Your name" user-name
    hubnet-send user-name "Whose turn?" [user-name] of item current-player sort players
    hubnet-send user-name "Your matches" matches
    hubnet-send user-name "Your turns" attempts
    hubnet-send user-name "Success %" 0
  ]
end 

to remove-player [name]
  let p one-of players with [user-name = name]
  if p != nobody
  [
    ifelse position p sort players <= current-player
    [
      ask p [ die ]
      increment-current-player
    ]
    [ ask p [ die ] ]
  ]
end 

to select-card [x y]
  if count cards with [not hidden?] < 2
  [
    let my-card one-of [cards-here] of patch x y
    if my-card != nobody
    [
      ask my-card [ show-turtle ]
      display
      let selected-cards cards with [not hidden?]
      if count selected-cards = 2
      [
        set attempts attempts + 1
        hubnet-send user-name "Your turns" attempts
        wait pair-up-delay
        ifelse 1 = length (remove-duplicates [shape] of selected-cards)
        [
          ask selected-cards [ ask card-backs-here [ die ] die ]
          set matches matches + 1
          hubnet-send user-name "Your matches" matches
          hubnet-broadcast "Cards remaining" count cards
          hubnet-broadcast "Leader" leader
          hubnet-broadcast "Leader's matches" max [matches] of players
        ]
        [
          ask selected-cards [ hide-turtle ]
          increment-current-player
        ]
        hubnet-send user-name "Success %" precision (matches / attempts) 3
        display
      ]
    ]
  ]
end 

to increment-current-player
  ifelse count players = 0
  [ set current-player 0
    hubnet-broadcast "Whose turn?" "" ]
  [ set current-player (current-player + 1) mod count players
    hubnet-broadcast "Whose turn?" [user-name] of item current-player sort players ]
end 

to-report leader
  let leaders players with-max [matches]
  ifelse any? leaders
  [
    ifelse count leaders = 1
    [ report [user-name] of one-of leaders ]
    [ report (word count leaders "-way tie") ]
  ]
  [ report "nobody" ]
end 


; Copyright 2009 Uri Wilensky.
; See Info tab for full copyright and license.