Percussion Workbench

extensions [ sound ]

globals [ drum-index memory ]

;; initializes the drum-index and the memory bank

to startup
  set drum-index 0
  set memory (list "" "" "" "")
end 

;; plays the current note and prints it to the output area

to play
  run generate-command
  output-print generate-command
end 

;; generates a NetLogo command to play the current drum
;; at the current pitch with the current velocity

to-report generate-command
  report (word "sound:play-drum "
               "\"" ( item drum-index sound:drums ) "\" "
               velocity)
end 

;; saves the current command in the nth memory slot

to save [ n ]
  set memory replace-item n memory generate-command
end 

;; arrow keys to scroll through the drum list

to first-drum
  set drum-index 0
  play
end 

to last-drum
  set drum-index length sound:drums - 1
  play
end 

to next-drum
  if drum-index < length sound:drums - 1 [
    set drum-index drum-index + 1
    play
  ]
end 

to prev-drum
  if drum-index > 0 [
    set drum-index drum-index - 1
    play
  ]
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.