Wall Following Example

turtles-own [direction]  ;;  1 follows right-hand wall,
                         ;; -1 follows left-hand wall

to setup
  clear-all
  ;; make some random walls for the turtles to follow.
  ;; the details aren't important.
  ask patches [ if random-float 1.0 < 0.04 [ set pcolor brown ] ]
  ask patches with [pcolor = brown] [ ask patches in-radius random-float 3 [ set pcolor brown ] ]
  ask patches with [count neighbors4 with [pcolor = brown] = 4] [ set pcolor brown ]
  ;; now make some turtles. SPROUT puts
  ;; the turtles on patch centers
  ask n-of 40 patches with [pcolor = black] [
    sprout 1 [
      if count neighbors4 with [pcolor = brown] = 4 [ die ]  ;; trapped!
      set size 2              ;; bigger turtles are easier to see
      set pen-size 2          ;; thicker lines are easier to see
      face one-of neighbors4  ;; face north, south, east, or west
      ifelse random 2 = 0
        [ set direction 1     ;; follow right hand wall
          set color blue ]
        [ set direction -1    ;; follow left hand wall
          set color green ]
    ]
  ]
  reset-ticks
end 

to go
  ask turtles [ walk ]
  tick
end 

to walk  ;; turtle procedure
  ;; turn right if necessary
  if not wall? (90 * direction) and wall? (135 * direction) [ rt 90 * direction ]
  ;; turn left if necessary (sometimes more than once)
  while [wall? 0] [ lt 90 * direction ]
  ;; move forward
  fd 1
end 

to-report wall? [angle]  ;; turtle procedure
  ;; note that angle may be positive or negative.  if angle is
  ;; positive, the turtle looks right.  if angle is negative,
  ;; the turtle looks left.
  report brown = [pcolor] of patch-right-and-ahead angle 1
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.