Case Conversion Example

to try-it
  let input user-input "Type any string."
  user-message word "In all caps, that's: "
                    upper-case-string input
  user-message word "And in all lower case, it's: "
                    lower-case-string input
end 

;;;
;;; Here are the procedures, suitable for copying and pasting into
;;; your own models.
;;;
;;;
;;; upper-case-string and lower-case-string are recursive procedures
;;; that operate on the input string one character at a time.
;;; upper-case-char and lower-case-char are used for converting
;;; the individual characters.
;;;

to-report upper-case-string [s]
  ifelse empty? s
    [ report "" ]
    [ report word (upper-case-char first s)
                  (upper-case-string butfirst s) ]
end 

to-report upper-case-char [c]
   let pos position c "abcdefghijklmnopqrstuvwxyz"
   ifelse pos = false
     [ report c ]
     [ report item pos "ABCDEFGHIJKLMNOPQRSTUVWXYZ" ]
end 

to-report lower-case-string [s]
  ifelse empty? s
    [ report "" ]
    [ report word (lower-case-char first s)
                  (lower-case-string butfirst s) ]
end 

to-report lower-case-char [c]
   let pos position c "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
   ifelse pos = false
     [ report c ]
     [ report item pos "abcdefghijklmnopqrstuvwxyz" ]
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.