Myself Example

to setup
  ca
  crt 50                               ; make  50 turtles
  [
    setxy random-xcor random-ycor      ; scatter them around the world
  ]
end 

; turtle procedure -- find closest turtle and move towards it

to cluster
  ; figure out what turtle, other than ourselves, is closest
  let closest-turtle min-one-of other turtles [distance myself]

  ; now move ourselves towards that turtle
  face closest-turtle
  ; but first "wiggle" a little
  rt random-float 20
  lt random-float 20
  fd 1
end 


; turtle procedure -- make a colored splotch around myself, the same color as me

to splotch
  ask patches in-radius 2 [ set pcolor [color] of myself ]
end 


; turtle procedure -- turn any turtle I encounter the same color as me

to infect
  ask turtles-here [ set color [color] of myself ]
  rt random-float 20
  lt random-float 20
  fd 1
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.