Perspective Example

;; this code is from Bounce Example. The perspective code is all in the buttons.

to setup
  clear-all
  set-default-shape turtles "circle"
  draw-walls
  crt 20                                ;; create some turtles
    [ randomize ]                       ;; set random coordinates and random direction
  reset-ticks
end 

; draws the boundaries of the billiard table

to draw-walls
  ask patches with [abs pxcor = max-pxcor]
    [ set pcolor blue ]
  ask patches with [abs pycor = max-pycor]
    [ set pcolor blue ]
end 

; set random coordinates

to randomize
  setxy random-xcor random-ycor
  if pcolor = blue       ; if it's on the wall...
    [ randomize ]        ; ...try again
end 

to go
  ask turtles [
    ifelse leave-trace?             ;; the turtle puts its pen up or down depending on the
      [ pd ]                        ;; value of the LEAVE-TRACE? switch
      [ pu ]
    bounce
    fd 0.1
  ]
  tick
end 

;; check the turtles coordinates and bounce it if needed

to bounce  ;; turtle procedure
  if abs [pxcor] of patch-ahead 0.1 = max-pxcor
    [ set heading (- heading) ]
  if abs [pycor] of patch-ahead 0.1 = max-pycor
    [ set heading (180 - heading) ]
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.