Sand 3D

1 collaborator

Uri Wilensky (Author)

WHAT IS IT?

This is a model of how sand particles interact with each other. The sand particles move according to the following rules:

1.) If the cell directly below is empty, move there.

2.) If the cell directly below is not empty, randomly move to one of the empty neighbors of the cell below.

HOW TO USE IT

GO: Starts and stops the simulation.

SETUP: Sets up the model.

SPACING: Determines how long the spout waits before releasing the next particle of sand.

THINGS TO NOTICE

Observe how sand rolls down a "mountain" of sand particles. Consider how this phenomenon is supported by the rules.

THINGS TO TRY

Observe how the spout will form a uniform pyramid of sand. Try DUMP SAND at a low density once you have a relatively large pyramid shape. How does this effect the shape of the pyramid? Does the pyramid ever return to its original shape?

Set the SPACING to 1. (You'll have to edit the slider, since the normal minimum is 2.) What happens? Is this just a limitation of the model rules, or does it have some plausible physical interpretation?

EXTENDING THE MODEL

Does this model accurately reflect how sand behaves? If not what rules could you devise to more accurately model sand's behavior? How could they be incorporated into the model?

What effect does weight have on sand particles? Should particles with lots of particles above them behave differently? If so, how would this change the rules?

Try simulating erosion with this model. How could you simulate wind? What effect would this have on the shape of the piles? How could you simulate rain? What effect would this have on the shape of the piles?

HOW TO CITE

If you mention this model in an academic publication, we ask that you include these citations for the model itself and for the NetLogo software:

- Wilensky, U. (1996). NetLogo Sand 3D model. http://ccl.northwestern.edu/netlogo/models/Sand3D. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

- Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use:

COPYRIGHT NOTICE

Permission to use, modify or redistribute this model is hereby granted, provided that both of the following requirements are followed:

a) this copyright notice is included.

b) this model will not be redistributed for profit without permission from Uri Wilensky. Contact Uri Wilensky for appropriate licenses for redistribution for profit.

This is a 3D version of the 2D model Sand.

This model was created as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

patches-own [
  next-color       ;; patches first all decide what color to change to, then all change
]

to setup
  ca
  setxyz 45 -45 0
  let surface-zcor -0.8 * max-pzcor
  ask patches with [pzcor < surface-zcor]
    [ set pcolor gray ]
end 

to go
  spout
  move-all-sand
  tick
end 

;; spouts sand particles depending on spacing (how often sand is released)

to spout
  if ticks mod spacing = 0
  [
     ask patch 0 0 max-pzcor
       [ set pcolor yellow - 1 ]
  ]
end 

;; implements the rules given in the info tab
;; to all the beige sand particles

to move-all-sand
  ask patches
    [ set next-color pcolor ]
  ask patches with [pcolor = yellow - 1]
    [ ifelse ([pcolor] of patch-at 0 0 -1 = black)
        [ shift-color patch-at 0 0 -1 ]
      [ let empty-patches-below
          ([ neighbors with [ pzcor = [pzcor] of myself ] ] of patch-at 0 0 -1  )
            with [ pcolor = black ]
        if any? empty-patches-below
          [ shift-color one-of empty-patches-below ] ] ]
  ;; we do this in a separate "ask" so that all the patches decide
  ;; on their new colors before any of them actually change color
  ask patches
    [ set pcolor next-color ]
end 

to shift-color [ p ]
  set next-color black
  ask p [ set next-color yellow - 1 ]
end 


; Copyright 1996 Uri Wilensky. All rights reserved.
; The full copyright notice is in the Information tab.

There are 3 versions of this model.

Uploaded by	When	Description	Download
Uri Wilensky	almost 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	almost 14 years ago	Model from NetLogo distribution	Download this version
Uri Wilensky	almost 14 years ago	Sand 3D	Download this version

Attached files

File	Type	Description	Last updated
Sand 3D.png	preview	Preview for 'Sand 3D'	about 11 years ago, by Uri Wilensky	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo