GenDrift T reproduce

1 collaborator

Uri Wilensky (Author)

WHAT IS IT?

This model is an example of genetic drift. It shows that competing breeds of turtles, each reproducing with equal likelihood on each turn, will ultimately converge on one breed without any selection pressure forcing this convergence. The idea, explained in more detail in Dennett's "Darwin's Dangerous Idea", is that trait drifts can occur without any particular purpose or 'selecting pressure'.

HOW IT WORKS

The model starts with a random distribution of colored turtles. They move by wiggling randomly across the world. Each turn, a turtle produces between 0 and 4 offspring. If the total number of turtles is greater than the original number, then turtles are randomly killed until the original number is restored. After enough turns, a color will gain a slight dominance. By statistical advantage, a dominant color becomes more likely to win the entire grid. However, because the process is random, there will usually be a series of dominant colors before one color finally wins. Equally important is the fact that a color can never come back once it dies out.

HOW TO USE IT

The "setup" button initializes the model.
The "go" button runs the model.
Use the "colors" slider to select the number of competing colors.
The "number" slider sets the initial number of turtles.

THINGS TO NOTICE

Notice that often colors can get to quite a high population but still fail to win the race.

EXTENDING THE MODEL

The grim reaper in the procedure death does a random harvesting of the population to keep it roughly constant. This might be somewhat like a natural environment with a limited food supply. Can you think of other ways to write this procedure? Are the results affected?

RELATED MODELS

GenDrift P global
GenDrift P local
GenDrift T interact

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

Wilensky, U. (1997). NetLogo GenDrift T reproduce model. http://ccl.northwestern.edu/netlogo/models/GenDriftTreproduce. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

to setup
  clear-all
  crt number [
    set color 5 + (random colors) * 10
    if color = turquoise     ;; turquoise (75) is too similar to another color
      [ set color magenta ]  ;; so use magenta (125) instead
    setxy random-xcor random-ycor
  ]
  reset-ticks
end 

to go
  if variance [color] of turtles = 0
    [ stop ]
  ask turtles [
    rt random 50
    lt random 50
    fd 1
  ]
  birth
  death
  tick
end 

;; turtles hatch between 0 and 4 babies

to birth
  ask turtles
    [ hatch random 5 [ fd 1 ] ]
end 

;; if the overall population is greater than the original number,
;; randomly kill turtles to keep population roughly constant

to death
  let total-turtles count turtles
  ask turtles [
    if random total-turtles > number
      [ die ]
  ]
end 


; Copyright 1997 Uri Wilensky.
; See Info tab for full copyright and license.

There are 10 versions of this model.

Uploaded by	When	Description	Download
Uri Wilensky	almost 11 years ago	Updated to NetLogo 5.0.4	Download this version
Uri Wilensky	over 11 years ago	Updated version tag	Download this version
Uri Wilensky	over 11 years ago	Updated to version from NetLogo 5.0.3 distribution	Download this version
Uri Wilensky	over 12 years ago	Updated to NetLogo 5.0	Download this version
Uri Wilensky	almost 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	almost 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	almost 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	almost 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	almost 14 years ago	Model from NetLogo distribution	Download this version
Uri Wilensky	almost 14 years ago	GenDrift T reproduce	Download this version

Attached files

File	Type	Description	Last updated
GenDrift T reproduce.png	preview	Preview for 'GenDrift T reproduce'	about 11 years ago, by Uri Wilensky	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo