Simple Kinetics 1

Simple Kinetics 1 preview image

2 collaborators

Uri_dolphin3 Uri Wilensky (Author)
Mike Stieff (Author)

Tags

chemical reactions 

Tagged by Reuven M. Lerner over 10 years ago

chemistry and physics 

Tagged by Reuven M. Lerner over 10 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 414 times • Downloaded 65 times • Run 1 time
Download the 'Simple Kinetics 1' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model demonstrates the kinetics of a simple reversible reaction. It demonstrates numerically that the application of the Principle of Stationary Concentrations is valid in this case.

In this model there are two kinds of molecules, green and red. Green turtles turn into red turtles bimolecularly whereas red turtles turn back into pairs of green turtles monomolecularly. You can control the rate at which this changes occur with sliders Kb and Ku.

The reaction here is a reversible reaction of the type:

                         Kb
        A + A <=======> B
                         Ku

An example of such a reaction would be dimerization of acetic acid:

                                  Kb
        2 H C-COOH <=======> H C-COOH~...~HOOC-C H
       3           Ku     3                 3

This reaction is an example of a complex reaction which consists of two elementary reactions. The forward bimolecular reaction

                        Kb
        A + A --------> B

is characterized by the constant Kb and the reverse unimolecular reaction

             Ku
        B ---------> A + A

is characterized by the constant Ku.

The system of ordinary differential equations (ODE) that describes the concentrations of A and B is given below:

        dA           2
        -- = -2Kb * A  + 2Ku * B        (1)
        dt


        dB         2
        -- = Kb * A  - Ku * B           (2)
        dt

The usual initial conditions are A(0) = Ao and B(0) = 0. While it is possible to solve this system of ODE analytically, chemists usually apply the Principle of Stationary Concentrations when they investigate the kinetics of reactions of this type. The Principle says that one can assume that the concentrations of the species stop changing from some point on after the system reaches equilibrium. If concentrations are stationary, the derivatives

        dA               dB
        --  and  --
        dt               dt

are zero. Hence one can replace the system of ODE above with the system of algebraic equations below:

                    2
        0 = -2Kb * A*   + 2Ku * B*              (1')

                  2
        0 = Kb * A*  - Ku * B*                  (2')

where concentrations marked with * are stationary concentrations. The second equation (2') is linearly dependent on the first equation (1'). Luckily we also have another equation coming from the law of the conservation of mass:

        A* + 2 * B* = Ao                        (3)

From equation (2') we can express B* in terms of A* :

                  Kb    2
        B*  = --  A*                    (4)
                  Ku

We can now plug in expression (4) into (3) and then we will have a quadratic equation in terms of A*:

                  Kb   2
        A*  + -- A*  = Ao               (5)
          Ku

whose solution is:

             _____________
             |
             |             Kb
             |  1 + 4 * --  - 1
            \|          Ku
           --------------------         (6)
                  Kb
                         2 * --
                                 Ku

One can now find the stationary concentration of B using equation (4).

HOW TO USE IT

Choose the values of Ku and Kb with appropriate sliders:

  • Kb controls the rate of the forward reaction by which two green turtles turn bimolecularly into a single red turtle.
  • Ku controls the rate of the reverse reaction, by which a red turtle turns unimolecularly into two green turtles.

Having chosen appropriate values of the constants, press SETUP to clear the world and create an initial number of green turtles. Note: we do not create red turtles initially, although this could be done in principle.

Press GO to start the simulation.

THINGS TO NOTICE

You will see turtles wandering around the world and changing color. Pay more attention to the plot of the concentrations. Do the plots soon reach stationary concentrations?

THINGS TO TRY

How do the stationary concentrations depend on the values of Kb and Ku? You can change Ku and Kb while the model is running. See if you can predict what the stationary concentrations will be with various combinations of Kb and Ku.

EXTENDING THE MODEL

Try to implement the following reaction:

                 Kb         K2
        A + A <======> B -------> C
                 Ku

This reaction underlines a vast number of microbiological processes (e.g. fermentation). You can read about its kinetics in any book on Biochemistry. Look up the so-called Michaeles-Menten equation. Does it check numerically?

Try to implement the following reaction:

                 Kb         K2
        A + B <======> C -------> D
                 Ku

RELATED MODELS

Enzyme Kinetics Chemical Equilbrium Simple Kinetics 2 Simple Kinetics 3

CREDITS AND REFERENCES

Thanks to Mike Stieff for his work on this model.

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

  • Wilensky, U. (1998). NetLogo Simple Kinetics 1 model. http://ccl.northwestern.edu/netlogo/models/SimpleKinetics1. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
  • Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

Copyright 1998 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [reactants reactant]    ;; reactants are green, products are red
breed [products product]

to setup
  clear-all
  set-default-shape reactants "molecule1"
  set-default-shape products "molecule2"
  create-reactants number
    [ set color green
      setxy random-xcor random-ycor ]
  reset-ticks
end 

to go
  ask turtles
    [ rt random-float 10 - random-float 10  ;; wander around randomly
      fd 1 ]
  ask turtles
    [ ifelse (breed = reactants)
        [ react-forward ]  ; reactants
        [ react-backward ] ; products
    ]
  tick
end 

to react-forward
  if (any? other reactants-here) and
     ;; multiply Kb by 2 because 2 molecules are involved
     random-float 1000 < (Kb * 2)
    [ ask one-of other reactants-here
        [ die ]
      set breed products
      set color red ]
end 

to react-backward
  if (random-float 1000) < Ku
    [ set breed reactants    ;; change back to reactant
      set color green
      hatch 1 ]         ;; then split into two reactants
end 


; Copyright 1998 Uri Wilensky.
; See Info tab for full copyright and license.

There are 10 versions of this model.

Uploaded by When Description Download
Uri Wilensky almost 11 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky over 11 years ago Updated version tag Download this version
Uri Wilensky over 11 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky about 12 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Model from NetLogo distribution Download this version
Uri Wilensky almost 14 years ago Simple Kinetics 1 Download this version

Attached files

File Type Description Last updated
Simple Kinetics 1.png preview Preview for 'Simple Kinetics 1' almost 11 years ago, by Uri Wilensky Download

This model does not have any ancestors.

This model does not have any descendants.