Evolution and forest resource use GERMAN

breed [trees tree]
breed [farmers farmer]

farmers-own [
  harvest-type
  amount
  harvest
  wealth
]

trees-own [height]


;;;;;;;;;;;;;;;;;;;;;;
;;;Setup Procedures;;;
;;;;;;;;;;;;;;;;;;;;;;

to setup
  clear-all

  setup-pastures
  setup-trees
  setup-farmers

  reset-ticks
end 

to setup-pastures
  ask patches [set pcolor brown + 2]
end 

to setup-trees
  ask patches [
    sprout-trees 1 [
    set shape "tree"
    set color green - 2
    set height Max-Baumhoehe
    set size ( height / 100 )
  ]]
end 

to setup-farmers
  ask n-of Anzahl-Agenten patches
    [sprout-farmers  1 [
      set shape "person logger"

      set size 0.9 ] ]

  ask n-of Gemaessigte farmers [ set harvest-type "sustainable"]

  update-color
end 


;;;;;;;;;;;;;;;;;;;;;;;;
;;;Runtime Procedures;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to go

  ask farmers with [harvest-type = "sustainable"] [set amount Anteil-gemaessigt]
  ask farmers with [harvest-type = "greedy"] [set amount Anteil-gierig]

  cut-trees

  livingcosts

  if Fortpflanzung?
  [reproduce]
  death

  ask trees [ regrow]

  tick
end 

to cut-trees

  harvest-commons

  ask farmers [set wealth wealth + harvest]
end 

to harvest-commons
  ask farmers [
     let harvest-tree max-one-of (trees in-radius 1) [height]
   ;; let neighborhood (patch-set neighbors with [not any? farmers-on self ])
  ;;  ifelse (any? neighborhood)
 ;;   [
     ;; let harvest-tree max-one-of (trees-on neighborhood) [height]
       move-to harvest-tree
        set harvest (  [height] of harvest-tree  * ( amount / 100))
        ask  harvest-tree [set height (height - (height * [amount ] of myself / 100))]
    ]
   ;; [set harvest 0]
  ;;]
end 

to livingcosts
  ask farmers [set wealth wealth - Lebenshaltungskosten]
end 

to reproduce

 ask farmers
  [ let neighborhood  (patch-set neighbors with [not any? farmers-on self ])
      if (any? neighborhood)  and random-float 1 < ( 0.0005 * wealth );;/ 100)
        [hatch 1 [

         set wealth ([wealth] of myself / 2)
         move-to one-of neighborhood
          ]
        set wealth (wealth / 2)
        ]
     ]
end 

to death
  ask farmers
  [if wealth <= 0 [die]]
end 

to update-color
   ask farmers [
    ifelse harvest-type = "sustainable"
      [set color green ]
      [set harvest-type "greedy"
       set color red]
  ]
end 

to regrow ;; tree
  ifelse height > 0
   [ set height  (height + ((Wachstumsrate * height) * (1 - (height / ( Max-Baumhoehe)  ))))
   ]
   [set height 0.1]
  set size height / 100
end 

;;;;;;;;;;;;;;
;;;;;;;;;;;;;

;;; Farmers1 variables

to-report average-wealth-greedys
  report sum [wealth] of farmers with [harvest-type = "greedy"] / count farmers with [harvest-type = "greedy"]
end 

to-report average-wealth-sustainables
  report sum [wealth] of farmers with [harvest-type = "sustainable"] / count farmers with [harvest-type = "sustainable"]
end