view2.5extension

extensions [ view2.5d ]

globals [
  observer-distance ; the observer's distance from its "focus point"
  observer-heading  ; the heading of the observer's angular perspective
  observer-pitch    ; the pitch of the the observer's angular perspective
  observer-x-focus  ; the x coordinate the observer is "looking at" in the patch plane
  observer-y-focus  ; the y coordinate the observer is "looking at" in the patch plane
  z-scale           ; factor for scaling the computed turtle height value
]
patches-own [ my-var ]

to setup

  ca
  random-seed 271828
  init-globals
  ask patches [ set pcolor random-float 2 + 2  ]
  ask patches [ set my-var pcolor - 2]

  crt num-turtles [ move-to one-of patches ]

  reset-ticks
  create-patch-view
end 

to create-patch-view
  view2.5d:patch-view window-name [ the-patch -> [my-var] of the-patch ]
  wait 1
  set-z-scale
  set-observer-distance
  set-observer-xy-focus
  set-observer-angles
  view2.5d:decorate-patch-view window-name
end 

to go-turtles
  ask patches [
    set my-var min list 5 max list 0  my-var + count turtles-here - 1
  ]
  ask turtles [
    rt (random 90) - 45
    fd random-float .2
  ]
  wait .2
  view2.5d:update-all-patch-views
  tick
end 

; One source for the window name

to-report window-name
  report "My View"
end 

; One could explore the effect of these variables by giving them each a slider

to init-globals
  set observer-distance 32
  set observer-x-focus 3
  set observer-y-focus 2
  set observer-heading 28
  set observer-pitch 56
  set z-scale 1.5
end 

to set-observer-distance
  view2.5d:set-observer-distance window-name observer-distance
end 

to set-observer-xy-focus
  view2.5d:set-observer-xy-focus window-name observer-x-focus observer-y-focus
end 

to set-observer-angles
  view2.5d:set-observer-angles window-name observer-heading  observer-pitch
end 

to set-z-scale
  view2.5d:set-z-scale window-name z-scale
end