Fish & Plankton for Challenge

breed [planktons plankton]
breed [fishes fish]

fishes-own [ energy ]   ;; gives fish the trait of "energy" which can be set & changed in the code

to setup
  clear-all
  ask patches                            ;; color background cyan
    [  set pcolor cyan  ]

  create-planktons 500   ;; this might be a good place to add a slider later
    [
       set heading random 360                ;; random heading
       setxy random-xcor random-ycor         ;; random starting location
       set color green
       set shape "circle"
       set size .75
    ]

  create-fishes number-of-fishes        ;; create the initial number of fishes
    [
      set heading random 360             ;; random heading
      setxy random-xcor random-ycor      ;; random starting location
      set shape "fish"
      set size 2
      set energy 50                      ;; set the initial energy of each fish to 50
    ]
 reset-ticks
end 

to go                             ;; go procedure calls all other procedures
  if not any? fishes [ stop ]     ;; if all the fish are dead, stop the run

  ask planktons
    [ wiggle ]

  ask fishes
   [
     wiggle
     move-cost
     eat
     more-fishes
     check-death
   ]

  more-planktons
  tick
end 

to wiggle                    ;; turn right, then left by a random 0-9, then forward 1
  right random 10
  left random 10
  forward 1
end 

to move-cost
  set energy energy - 1       ;; reduce the fish energy each step
end 

to eat
  if any? planktons-here       ;; if there are plankton on this patch then eat one, plankton dies
  [
    let target one-of planktons-here
    ask target
      [ die ]
    set energy energy + 10    ;; increase fish energy by eating a plankton, this could be a place to add a slider
  ]
end 

to more-fishes  ;; fish can reproduce if they have enough energy, but it will cost them half of their own energy
  if energy > 100
    [
      set energy energy - 50    ;; energy cost of reproduction
      hatch 1 [ set energy 40 ] ;; creates a new agent just like parent with energy set to 40
    ]
end 

to check-death        ;; if energy level is zero or less, the fish dies
 if energy <= 0
  [  die  ]
end 

to more-planktons
  if (random 1 < 10)    ;; there is a 1/10 chance of getting a new plankton at each tick
    [
      create-planktons 1
        [
             setxy random-xcor random-ycor
             set heading random 360
             set color green
             set size 0.75
             set shape "circle"
        ]
    ]
end 

; Copyright 2007 Uri Wilensky.
; See Info tab for full copyright and license.