UBoats in the Bay of Biscay

; Developed by Ken Comer to evaluate kinematic activity in the Bay of Biscay
breed [uboats uboat] ; There is only one kind of U-boat
uboats-own [dest speed submerged? status dived? battery transittime lastescape]
breed [s25s s25]
s25s-own [fuel speed nearest patrol? outbound? pathrs contacts]
globals [Brest LOrient SaintNazere Plymouth LaRochelle Bordeaux
  deployed encounters totalpatrolhrs opportunities escapes ttimes s25-arrate
  ports ocean]
patches-own [
  region ; the number of the region that the patch is in, patches outside all regions have region = 0
]



To Setup
  __clear-all-and-reset-ticks
  import-pcolors "Bay_of_Biscay_Short.bmp"
  set Brest patch 418 316
  set LOrient patch 434 280
  set SaintNazere patch 471 256
  set LaRochelle patch 546 201
  set Bordeaux patch 560 171
  set Plymouth patch 435 440
  set-default-shape uboats "suboat"
  set-default-shape s25s "airplane 2"
  set ports (list Brest lorient saintnazere larochelle bordeaux)
  set ocean patches with [pcolor = 9.9]
  set deployed 0
  set encounters 0 ; The number of minute-turns in which a surfaced U-boat is in cone of an S25
  set totalpatrolhrs 0
  set opportunities 0 ; The number of minute-turns in which a U-boat (surfaced or dived) is in cone of an S25
  set escapes 0
  set ttimes []
  set s25-arrate ph-generator / 4000 * 0.013 ; the s.25 arrival rate from slider

End ; setup

To Go
;  ask agents Move
  if ticks < 2 [StartUboat]
  if random-float 1 < 0.0013 [StartUboat]
  if random-float 1 < s25-arrate [StartS25] ; gives about 4K TPH
  ask turtles [move]
  ask s25s [search] ; Search after you turn, submarines set status, check fuel
  Tick
  if ticks = 43204 [stop] ; Each run lasts 30 days
End  ;go

To StartUBoat ; This procedure creates a U-boat at one of the ports and sends it west.
  create-uboats 1 [
    set size 10
    set speed 10  ; Uboats transit from the coast at 10 kts.
    move-to one-of ports ; Randomly start at one of the ports.
    set heading 275 + random 35  ; Fan out randomly.
    set dived? FALSE  ; Surfaced transit.
    set status "egress" ; Ensures it doesn't dive during egress
    set transittime 0 ; I'm going to determine total minutes to transit
    set lastescape 0  ; Used to avoid double-counting escapes.

  ]
End ; Create Uboat

To StartS25
  create-S25s 1 [
    set size 20
    move-to Plymouth
    set heading 200 + random 50
    set fuel 100
    set label-color 10
    set patrol? FALSE    ; Used to measure TPH and limit search subroutine
    set outbound? TRUE   ; Used to transition to patrol on outbound leg
    set pathrs 0
    set contacts []
  ]
End ; StartS25

To Move ;Actual movement in the main command. This depletes fuel and battery.
  if (breed = uboats) [
    fd speed / 60
    set transittime transittime + 1
    if-else dived? [  ; Consume battery for submerged submarines
      set battery battery - .25 ; Battery life 5.2 hrs
      if battery < 20 [surface] ; Battery too low to stay down
    ] [               ; Charge battery for surfaced submarines
      if battery < 100 [set battery battery + .3] ; Recharge in 4.33 hrs
      if maxsubmergence? [
        if battery > 98 [submerge] ; battery full, dive in Max Submgnce
      ]
    ] ; if-else dived?
    checkPosition ; Transition egress to transit or transit to done
  ] ; ask uboats
; Now for the s25s
  if (breed = s25s) [
    fd airspeed / 60
    set fuel fuel - 0.12 ; Gives 10.4 hours operational flight before RTB
    if-else labels? [set label round pathrs] ; For visual debugging
    [set label ""]
    checkStatus          ; Transition to patrol, Maneuver in the box, check fuel, Land
  ]

End ; move

to CheckPosition  ;Uboats look at what its doing
  if xcor < 370 [ ; Check to see if I'm in the op area
    if status = "egress" [ ; if I just entered the op area...
      submerge             ; dive and chamge my status to transit
      set status "transit"
    ] ; a transiting, non-dived uboat
  ]
  if xcor < 100 or ycor > 520 [         ; If I've reached the North Atlantic...
    set deployed deployed + 1   ; Add me to the tally of deployed Uboats
    set ttimes lput transittime ttimes
    die                  ; And remove me from the model
  ]
end  ; CheckPosition for Uboats

to CheckStatus ;After S25 moves, check to see if they need to change something
  if outbound? [
    if xcor < 340 [
      set patrol? TRUE
      set outbound? FALSE
      set heading 235
    ]
  ]

  if patrol? [
    if xcor > 360 [ ; Eastern boundary, head West
      set heading 225 + random 90
    ]
    if xcor < 190 [ ; Western boundary, head East
      set heading 45 + random 90
    ]
    if ycor < 200 [ ; Southern boundary, head North
      set heading 295 + random 90
    ]
    if ycor > 430 [ ; Northern boundary, head South
      set heading 135 + random 90
    ]
   if fuel < 25
     [face Plymouth
      set patrol? FALSE
    ] ; RTB Out of gas
    set pathrs pathrs + 1 / 60
  ] ; end of "if on patrol block"



  if ycor > 444 ;arrived at Plymouth
    [set totalpatrolhrs totalpatrolhrs + pathrs
     die]
end  ; S25 status

to search ; Executed by every S25 every turn.
  if not patrol? [stop] ; non-patrolling aircraft should not be searching
  if count uboats < 1 [stop] ; No use searching an empty ocean.

  let target-set uboats in-cone S25-vision cone-angle ; Creates the set of all uboats in my cone
  if count target-set > 0 [   ; There's a Uboat in the cone
    let target min-one-of (uboats) [distance myself] ; Don't look for closest unless there's one in the cone.
    set nearest distance target

    if (member? target target-set) [ ; True if target is in my cone, false if nearest uboat is outside cone
;    user-message(word "Target is in the cone. Who is: " who)
      set opportunities opportunities + 1 ; Count number of turns a U-boat is in the cone of an S25
      ask target [

           if-else not dived? [
;        user-message(word "Uboat in cone of: " who "and surfaced. Battery: " round battery)
              if dived? [user-message("I am submerged!")]
              if random-float 1 < 0.1 [ ; S25s attack only 10% of what they CAN see (surfaced, in their cone) per turn.
                 ask myself [attack]
           ]
              set encounters encounters + 1  ; I count all encounters S25 to surfaced U-bot per turn, not all attacks.
          ; Note the above statment may count multiple encounters for the same interaction.
           ] ; end if target is surfaced, now else (target is dived in the cone)
           [ ; Target is selected but is dived, so...
           if (ticks - 1) > lastescape [ ; This target was NOT escaping last run. This UBoat skipped a turn in this loop.
            ; Note: this if condition means escapes are counted only once while opportunities & encounters happen every min.
             set escapes escapes + 1] ; Counts the number a submerged U-boats pass under an S25 detection cone (overall, not per min)
           set lastescape ticks ; Links this minute to the next in case I'm still in the cone.
           ]; target was dived
       ] ; stop asking target to do things
    ] ; Closest uboat in the cone selected.
  ] ; There's a uboat in the cone
  ask uboats in-cone uboatvision 360 [ ; Finds Uboats that can see me out to their vision.
    if not dived? [
;  user-message(word "Uboat crash dives. Battery: " round battery)


    submerge ; and asks them to dive if they are not dived already.
    ] ; This allows half to escape
  ]
end  ; search

to submerge
  set shape "uuboat"
  set speed 2
  set dived? TRUE
;  let attacker min-one-of (s25s) [distance myself]  ;these report distance to nearest Sunderland
;  let disttoS25 distance attacker  ;
;  user-message(word "Uboad dived, plane is nm: " disttos25)
end  ;

to snort
  set shape "uboat"
  set speed 5
  set dived? FALSE
end 

to surface
  set shape "suboat"
  set speed UT-speed
  set dived? FALSE
end 

to attack
  watch-me
;  wait 15
  set shape "attacking"
  set patrol? FALSE
  face plymouth
end  ; attack

; to-report intvalue [x]
;  set x round x
;  report x
; end