MIHS - CoronaVirus2.0

1 collaborator

WHAT IS IT?

This model simulates the transmission and perpetuation of a virus (such as CoronaVirus) in a human population.

Ecological biologists (also called epidemiologists) have suggested a number of factors which may influence the survival of a directly transmitted virus within a population. (Yorke, et al. "Seasonality and the requirements for perpetuation and eradication of viruses in populations." Journal of Epidemiology, volume 109, pages 103-123)

For additional information on CoronaVirus, go to the Centers for Disease Control's website: https://www.cdc.gov/coronavirus/2019-ncov/about/index.html

HOW IT WORKS

The model is initialized with 200 people, of which 10 are infected. People move randomly about the world in one of three states: healthy but susceptible to infection (grey), sick and infectious (red), and healthy and immune (green). People may die of infection or recover. The spread of the infection and the number of deaths depend on a number of factors:

Some of these factors are summarized below with an explanation of how each one is treated in this model.

The density of the population

Population density affects how often infected, immune and susceptible individuals come into contact with each other. You can change the size of the initial population through the NUMBER-PEOPLE slider.

Mortality (deaths due to the virus)

Older people, those with lung diseases, or those with compromised immune systems are more likely die from the virus. The overall chance of dying is determined by the slider CHANCE-RECOVER, but the program is written such that younger individuals are far less likely to die than older people.

Degree of immunity

If a person has been infected and recovered, how immune are they to the virus? We often assume that immunity lasts a lifetime and is assured, but in some cases immunity wears off in time and immunity might not be absolutely secure. In this model, immunity is secure, but it only lasts for a year. If the immunity were not absolute or if it lasted for a much shorter time, this could reflect the tendency of viruses to mutate rapidly while infecting a host. Those who have been infected previously and recovered may not be immune to the new strains of the virus that are continuously evolving in the population.

Infectiousness (or transmissibility)

How easily does the virus spread? Some viruses with which we are familiar spread very easily. Some viruses spread from the smallest contact every time. Others (the HIV virus, which is responsible for AIDS, for example) require significant contact, perhaps many times, before the virus is transmitted. In this model, infectiousness is determined by the INFECTIOUSNESS slider. CoronaVirus does not require direct contact with an infected person to spread. When an infected person sneezes or coughs, they may leave tiny droplets containing the virus on nearby surfaces. When uninfected people touch those surfaces, they risk becoming infected, too.

Duration of infectiousness

How long is a person infected before they either recover or die? This length of time is essentially the virus's window of opportunity for transmission to new hosts. In this model, duration of infectiousness is determined by the DURATION slider.

People's behavior (both while sick and while healthy)

In the simulation, both sick and healthy people move about randomly. There are many behaviors sick people could adopt that would dramatically change the risk of transmitting the virus to others (such as quarantining themselves). Healthy people could also reduce their risk of becoming infected (perhaps by avoiding contact with other people, "washing hands," wearing a "mask", etc.).

Hard-coded parameters

Two important parameters of this model are set as constants in the code (See setup-constants procedure). They can be exposed as sliders if desired. The turtles’ lifespan is set to 80 years and the duration of immunity is set to 52 weeks.

HOW TO USE IT

Each "tick" represents part of a day; in the time scale of this model there are 10 ticks in a day, 70 ticks in one week.

The INFECTIOUSNESS slider determines how great the chance is that virus transmission will occur when an infected person and susceptible person occupy the same patch. For instance, when the slider is set to 50, the virus will spread roughly once every two chance encounters.

The DURATION slider determines the number of days before an infected person either dies or recovers.

The CHANCE-RECOVER slider controls the average likelihood that an infection will end in recovery/immunity. When this slider is set at zero, for instance, the infection is always deadly. Older people are less likely to recover and, therefore, more likely to die.

The SETUP button resets the graphics and plots and randomly distributes NUMBER-PEOPLE in the view. All but 10 of the people are set to be grey susceptible people and 10 red infected people (of randomly distributed ages). The GO button starts the simulation and the plotting function.

The TURTLE-SHAPE chooser controls whether the people are visualized as person shapes or as circles.

Three output monitors show the percent of the population that is infected, the percent that is immune, the cumulative number of deaths due to the virus, and the number of weeks that have passed. The plot shows (in their respective colors) the number of infected and immune people. It also shows the number of individuals who have died in black.

THINGS TO NOTICE

The factors controlled by the various sliders interact to influence how likely the virus is to spread in this population, as well as how many people are likely to die. Notice that in all cases, these factors must create a balance in which an adequate number of potential hosts remain available to the virus and in which the virus can adequately access those hosts.

Often there will initially be an explosion of infection since no one in the population is immune. This approximates the initial "outbreak" of a viral infection in a population, one that often has devastating consequences for the humans concerned. Soon, however, the virus becomes less common as the population dynamics change. What ultimately happens to the virus is determined by the factors controlled by the sliders.

Notice that viruses that are too successful at first (infecting almost everyone) may not survive in the long term. Since everyone infected generally dies or becomes immune as a result, the potential number of hosts is often limited. The exception to the above is when the DURATION slider is set so high that people begin to lose their immunity, thus providing new hosts.

THINGS TO TRY

Think about how different slider values might approximate the dynamics of real-life viruses. The famous Ebola virus in central Africa has a very short duration, a very high infectiousness value, and an extremely low recovery rate. For all the fear this virus has raised, how successful is it? Set the sliders appropriately and watch what happens.

The HIV virus, which causes AIDS, has an extremely long duration, an extremely low recovery rate, but an extremely low infectiousness value. How does a virus with these slider values fare in this model?

Look up these parameters for CoronaVirus. Some of them may still be unknown (or uncertain) at the present time.

EXTENDING THE MODEL

Build a similar model simulating viral infection of a non-human host with very different reproductive rates, lifespans, and population densities.

Add a slider controlling how long immunity lasts. You could also make immunity imperfect, so that immune turtles still have a small chance of getting infected. This chance could get higher over time.

Try altering people's behavior - sick people may not behave the same way that healthy people do. Everyone could change their behavior in an attempt to restrict the spread of the virus - could you rewrite this model to allow you to test the efficacy of different behaviors (wearing masks, quarantine, hand-washing, etc.)?

VISUALIZATION

The circle visualization of the model comes from guidelines presented in Kornhauser, D., Wilensky, U., & Rand, W. (2009). http://ccl.northwestern.edu/papers/2009/Kornhauser,Wilensky&Rand_DesignGuidelinesABMViz.pdf.

At the lowest level, perceptual impediments arise when we exceed the limitations of our low-level visual system. Visual features that are difficult to distinguish can disable our pre-attentive processing capabilities. Pre-attentive processing can be hindered by other cognitive phenomena such as interference between visual features (Healey 2006).

The circle visualization in this model is supposed to make it easier to see when agents interact because overlap is easier to see between circles than between the "people" shapes. In the circle visualization, the circles merge to create new compound shapes. Thus, it is easier to perceive new compound shapes in the circle visualization. Does the circle visualization make it easier for you to see what is happening?

RELATED MODELS

AIDS
Virus on a Network

CREDITS AND REFERENCES

This model can show an alternate visualization of the Virus model using circles to represent the people. It uses visualization techniques as recommended in the paper:

Kornhauser, D., Wilensky, U., & Rand, W. (2009). Design guidelines for agent based model visualization. Journal of Artificial Societies and Social Simulation, JASSS, 12(2), 1.

HOW TO CITE

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

Wilensky, U. (1998). NetLogo Virus model. http://ccl.northwestern.edu/netlogo/models/Virus. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Please cite the NetLogo software as:

Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

turtles-own
  [ sick?                ;; if true, the turtle is infectious
    remaining-immunity   ;; how many weeks of immunity the turtle has left
    sick-time            ;; how long, in weeks, the turtle has been infectious
    age ]                ;; how many weeks old the turtle is

globals
  [ %infected            ;; what % of the population is infectious
    %immune              ;; what % of the population is immune
    days                 ;; cumulative number of days in simulation
    deaths               ;; cumulative number of deaths due to virus
    lifespan             ;; the lifespan of a turtle - the chance of dying when infected is higher for older turtles
    immunity-duration    ;; how many weeks immunity lasts
    cumulative-age       ;; used to calculate average age of population
    ticks-per-week ]     ;; # of ticks to simulate 1 week of time


;; The setup is divided into four procedures

to setup
  clear-all
  setup-constants
  setup-turtles
  update-global-variables
  update-display
  reset-ticks
end 

;; We create a variable number of turtles of which 10 are infectious,
;; and distribute them randomly

to setup-turtles
  create-turtles number-people
    [ setxy random-xcor random-ycor
      set age ( random average-age + random lifespan * .75 )  ;; age is randomly distributed around the average value
      if age > lifespan + 30 [ set age lifespan + random 30 ]
      set cumulative-age cumulative-age + age
      set sick-time 0
      set remaining-immunity 0
      set size 1.5  ;; easier to see
      ;; set label age
      get-healthy ]
  ;; calculate average age
  set cumulative-age cumulative-age / number-people
  ask n-of 10 turtles
    [ get-sick ]
end 

to get-sick ;; turtle procedure
  set sick? true
  set remaining-immunity 0
end 

to get-healthy ;; turtle procedure
  set sick? false
  set remaining-immunity 0
  set sick-time 0
end 

to become-immune ;; turtle procedure
  set sick? false
  set sick-time 0
  set remaining-immunity immunity-duration
end 

;; This sets up basic constants of the model.

to setup-constants
  set lifespan 80     ;; average lifespan is assumed to be 80 years - the chance of dying when infected is higher for older turtles
  set immunity-duration 52
  set ticks-per-week 70
end 

to go
  ask turtles [
    update-sick-immune
    move
    if sick? [ recover-or-die ]
    if sick? [ infect ]
  ]
  update-global-variables
  update-display
  tick
end 

to update-global-variables
  if count turtles > 0
    [ set %infected (count turtles with [ sick? ] / count turtles) * 100
      set %immune (count turtles with [ immune? ] / count turtles) * 100 ]
end 

to update-display
  ask turtles
    [ if shape != turtle-shape [ set shape turtle-shape ]
      set color ifelse-value sick? [ red ] [ ifelse-value immune? [ green ] [ grey ] ] ]
end 

;; turtle counting variables are advanced either daily or once per week (i.e. only after ticks-per-week ticks have passed)

to update-sick-immune ;; turtle procedure
  ;; check that 1 day has passed and update sick-time
  if ticks mod ( ticks-per-week / 7 ) = 0 [
    if sick? [ set sick-time sick-time + 1 ]
  ]
  ;; check that 1 week has passed and update remaining-immunity
  if ticks mod ticks-per-week = 0 [
    if immune? [ set remaining-immunity remaining-immunity - 1 ]
  ]
end 

;; turtles move about at random.

to move ;; turtle procedure
  right random 100
  left random 100
  forward 1
end 

;; If a turtle is sick, it infects other turtles on the same patch.
;; Immune turtles don't get sick.

to infect ;; turtle procedure
  ask other turtles-here with [ not sick? and not immune? ]
    [ if random-float 100 < infectiousness
      [ get-sick ] ]
end 

;; Once the turtle has been sick long enough, it
;; either recovers (and becomes immune) or it dies.

to recover-or-die ;; turtle procedure
  if sick-time > duration                        ;; If the turtle has survived past the virus' duration, then
    [ ifelse ( random-float 150 * age / lifespan ) < chance-recover   ;; either recover or die - older turtles have a lower chance of recovery
      [ become-immune ]
      [ set deaths deaths + 1  die ]
    ]
end 

to-report immune?
  report remaining-immunity > 0
end 

to startup
  setup-constants ;;
end 


; Copyright 1998 Uri Wilensky.
; See Info tab for full copyright and license.

There is only one version of this model, created over 5 years ago by Larry Bencivengo.

Attached files

File	Type	Description	Last updated
MIHS - CoronaVirus2.0.png	preview	Preview for 'MIHS - CoronaVirus2.0'	over 5 years ago, by Larry Bencivengo	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo