Fermi Rumour

turtles-own [
  spread ;;is a spreader or not
  ignorant ;; is an ignorant or not
  encounter ;; to keep how many times encountered with a non-ignorant
]

globals [
  number-spreaders
  number-ignorants
  number-stifflers
  rate
  rate-ignorants
  rate-stifflers
  rate-spreaders
]

to setup
  clear-all
  ask patches [ set pcolor black ]
  set number-ignorants (number)
  set rate-stifflers 0
  set rate-ignorants 1
  create-turtles number [
    setxy random-xcor random-ycor
    set color blue
    set spread 0
    set ignorant 1
  ]
  ask n-of 1 turtles [
    set color yellow
    set spread 1
  ]
  reset-ticks
end 

to go
  ask links [die]

  ask turtles with [spread = 1] [
    set encounter encounter + 1
    act-spread
  ]
  update-globals
  if not any? turtles with [spread = 1] [
    ;; For logging activate the following three lines
    ;;file-open "C:\\FERMI.txt"
    ;;file-print (word conversion-probability";"stop-criteria";"rate"\r\n")
    ;;file-close
    stop
  ]
  tick
end 

to act-spread
  ask one-of other turtles [
    ;;choose random one
    ;;show (word myself "->" self)
    ifelse ignorant = 1 ;; if choosen one is an ignorant
    [
      create-link-from myself [set color yellow] ;; create a yellow link
      if conversion-probability > random 100 [
        set spread 1 ;; make it a spreader
        set ignorant 0 ;; make it non-ignorant
        set color yellow ;; make it yellow
      ]

    ] ;;else
    [

      if withdraw? [ ;; is it a stiffler?
        ;;show "açıkı"
        set encounter encounter + 1
        if encounter >= stop-criteria [
          set spread 0
          set color gray
        ]
      ]
      ask myself [
        if encounter >= stop-criteria [
          set spread 0
          set color gray
        ]
      ]
    ]
  ]
end 

to reset
  set number 1000
  set withdraw? true
  set stop-criteria 1
  set conversion-probability 100
end 

to update-globals
  set number-spreaders (count turtles with [spread = 1])
  set number-ignorants (count turtles with [ignorant = 1])
  set number-stifflers (count turtles with [(spread = 0) and (ignorant = 0)])
  set rate number-ignorants / number
  set rate-ignorants number-ignorants / number
  set rate-stifflers number-stifflers / number
  set rate-spreaders number-spreaders / number
end