Starfish_Planet_3

1 collaborator

Cosimo Leuci (Author)

WHAT IS IT?

Synthetic theory in its classical version hypothesized mutational events as strictly casual, and therefore constant mutation rate during organic evolution. Nevertheless, Barbara Mc Clintock (1984) argued that the mutation rate can increase when cells, tissues, or organisms are challenged, mainly as a consequence of transposons activity.

In the last decades, an amount of studies has shown that some new molecular mechanisms can lead in different organisms to a variation in mutation rate (see e.g. Rodrigo S. Galhardo et. al, 2007). On the other hand, John H. Holland (1975) originally suggested this it is often beneficial to change the mutation rate in a simple genetic algorithm.

The goal of the project is to show that an increase in a mutation rate can help a simple biological model to adapt to its environment. I mean as “adaptation” the process leading to a “structural coupling” of a biological system with its environment, as described by Maturana and Varela (1972) so no fitness index is used, and the adaptation, if any, should be an emergent phenomenon.

HOW IT WORKS

The environment is a liquid planet inhabited by great starfishes. The physics of this virtual environment is characterized by an oscillating flux of “cosmic energy” but just a part of that incoming energy is available for starfishes because a part of it is stored by the liquid substrate and a part is rejected by a starfishes subpopulation in the external space.

Indeed, there are two kinds of starfishes: white ones and red ones. They both need the energy to live but an excess of it can destroy them. The agents represented as white starfishes have got a better tolerance to the energy because their pigment reflects the energy (albedo positive) but they suffer when the energy supply decrease. On the other hand, the red starfishes have got a better energy storage system (albedo negative) but they show a higher sensibility to an excess of energy. In biological terms, we can say that the starfishes color “gene” has a pleiotropic effect: it influences the survival of the single starfish, and together with the action of all starfishes it can influence the energetic balance of the entire environment.

The agents born, grow, reproduce and die. The reproduction occurs after a juvenile stage lasting more time steps if the environment is overcrowded; after the maturity stage, the starfishes die. Basically, the red starfishes die also if the grade of energy in the environment is not comprised between e.g. - a and + b units; similarly, the preferred range for white starfishes could be between - b and + a. These ranges can be pushed down for red starfishes or pulled up for white starfishes as a consequence of mutations that can produce variability in this trait.

HOW TO USE IT

The setup button creates 500 red starfishes and 500 white starfishes. You can see four sliders: the first one regulates the amplitude of the incoming energy oscillations; the second one sets the energy average exposure, the third one is for the environmental mutation rate, and the fourth set the albedo power of the starfishes that is opposite for the two subpopulations.

The second source of mutations is given by a “mutator gene” that can be inserted by a switch; the gene is present in three allelic forms: the positive one increase the probability of mutations in the starfish that carry this allele, the mutations could involve itself; the negative form decreases the susceptibility of the starfish to mutations; the last allelic form is neutral and represents the wild type allele. All the three alleles have the same probability to rise in a given starfish when the environmental mutation rate is at a higher value than zero.

Another switch allows the introduction of individual shifts in the energetic tolerance range of the starfishes i.e. the resistance to energetic extremes is exposed to mutation but the tolerance range is kept the same (34 units). The tolerance-shift introduces another form of variability in any starfishes that will be visually displayed by their size. Under the effects of mutations, starfishes tolerance range can also approach the mean of the entire population: the probability of raising this case is mathematically lower but it could be favored by some environmental conditions.

THINGS TO TRY AND THINGS TO NOTICE

Set every slider to 0 and the two switches OFF and make a series of experiments in which the amplitude of energy oscillations gradually increases; the goal is to find the threshold of ecosystem impairment: this will be the stress edge.

At this point, increase the environmentalmutationrate. Can the effects of mutation help the starfishes population to face the environmental challenge? Discover how that occurs, try and run again the model slowly. If the environmentalmutationrate is lowered, does the system maintain its stability? In this configuration, are the mutations a way to reach an adaptation or are they a constitutive element of adaptation?

Previous investigations in the field of digital life (Muyoung Heo et al. 2009) have shown that “when mutation rate was a selectable trait, the population initially maintained high mutation rate until a high fitness level was reached, after which organisms with low mutation rates are gradually selected”. Introduce the “mutator” gene and check if the same outputs are reproducible on the Starfish Planet when the energy oscillation amplitude is set just above the edge of stress and at a more permissive conditions, then introduce the “tolerance-shift” gene to check if, with this new component, it is possible to reach a stable adaptation even deactivating every mutation source after the evolutive period.

Darwinian evolution is possible on Starfish Planet, as well. It is observable when, in sublethal energetic conditions, the oscillation’s axis is gradually increased or decreased acting on the energy_average slider. The effect could be lost if the variation takes place abruptly.

Finally, try the albedo effect when it is present alone or with the other environmental or “organic” factors (remember that mutation of the “tolerance-shift” or “mutator” genes, are possible only if it is present a bit of environmental_mutation, otherwise their values will stay on 0). Now, what are the best conditions to reach stable configurations? Is the process of “niche construction” always equally effective? What about diversity? The answers to the questions could be meaningful to get insights about the dynamical relationships between ecology and evolutive processes, as well as for the comprehension of some cancer disease development (see e.g. Mary Helen Barcellos-Hoff, 2013).

EXTENDING THE MODEL

It would be interesting to introduce new genes in virtual organisms: e. g. one of them could regulate the life cycle length and another one could be related to the end of the juvenile stage of starfishes.

NETLOGO FEATURES

Using HATCH to "clone" agents and DIE to close their life cycle.

RELATED MODELS

• Dewdney, A. K. (1984) Wa-Tor. https://en.wikipedia.org/wiki/Wa-Tor

• Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

• Novak, M. and Wilensky, U. (2006). NetLogo Daisyworld model. http://ccl.northwestern.edu/netlogo/models/Daisyworld. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

REFERENCES

• McClintock B. (1984) The significance of responses of the genome to challenge. Science Vol. 226, Issue 4676, pp. 792-801

• Galhardo R. S. Hastings P. J. and Rosenberg S. M. (2007) Mutation as a Stress Response and the Regulation of Evolvability. Crit Rev Biochem Mol Biol. 42(5): 399–435

• Holland, J. (1975) Adapatation in Natural and Artificial Systems. University of Michigan Press.

• Maturana H., Varela F. (1972) De Maquinas y Seres Vivos – Una Teoria Sobra La Organizacion Biologica. Editorial Universitaria

• Muyoung Heo, Louis Kang, and Eugene I. Shakhnovich (2009) Emergence of species in evolutionary "simulated annealing". PNAS 106 (6): 1869–1874

• Mary Helen Barcellos-Hoff, David Lyden & Timothy C. Wang (2013) The evolution of the cancer niche during multistage carcinogenesis. Nature Reviews Cancer Vol. 13, pp. 511–518

COPYRIGHT AND LICENSE

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/4.0/ ---

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

turtles-own [

  age                     ;; an age counter for each agent/turtle/starfish

  mutator                 ;; a gene that when activated has got three alleles; the neutral one,
                          ;; the positive one (that increase the probability of mutations) and the
                          ;; the negative one (that decrease the probability of mutations)

  tolerance_variation     ;; starfishes can survive in a range of standard energy supply
                          ;; but when the switch tolerance-shift is activated, every starfish can
                          ;; diverge from the standard, as well: the magnitude of the drift is given by
                          ;; the tolerance_variation "gene"
  ]



globals [

  incoming_cosmic_energy  ;; energy coming from external space
  surface_energy          ;; energy measured on the surface of the planet
  n.red                   ;; counter of the red starfishes
  n.white                 ;; counter of the white starfishes
  rw_difference           ;; difference between red and white starfishes
  mmut                    ;; average of mutator genes activity in total population
  mvar                    ;; average of tolerance-shift variation genes in total population
  crowd?                  ;; does the number of starfishes exceed the maximum sustained by the environment?
  ]





;;  ----------   SETUP PROCEDURES   -----------------------------------------------------------------------
;;  -------------------------------------------------------------------------------------------------------

to setup

  clear-all
  reset-ticks

  set incoming_cosmic_energy 0
  set surface_energy 0

  ask patches [set pcolor cyan]        ;; the planet has a cyan background

  crt 500
    [setxy random-xcor random-ycor     ;; the planet is populated by two kinds of starfishes,
    set color red                      ;; the red ones ...
    set shape "star"
    set size 0.7
    set age random 5
    set mutator 0
    set tolerance_variation 0
    ]

  crt 500
    [setxy random-xcor random-ycor
    set color white                    ;; and the white ones
    set shape "star"
    set size 0.7
    set age random 5
    set mutator 0
    set tolerance_variation 0
    ]

  set n.red count turtles with [color = red]
  set n.white count turtles with [color = white]
  set rw_difference n.red - n.white

  set mmut 0
  set mvar 0
  set crowd? false
end 





;;  -------------- RUNTIME PROCEDURES ---------------------------------------------------------------------
;;  -------------------------------------------------------------------------------------------------------

to go

  tick

  ;; the physics of starfish planet is given by an oscillating flux of "cosmic energy"
  set incoming_cosmic_energy (cos(ticks * 31) * energy_oscillation_amplitude) + energy_average

  ;; at the surface of the planet the energetic balance is influenced by the incoming energy,
  ;; and biological factors given by the positive or negative "albedo effect"
  ;; of two different populations of starfishes
  set surface_energy
    (surface_energy + incoming_cosmic_energy) / 2 + rw_difference * albedo_parameter

  ;; the two kinds of alien starfishes populations living on the planet follow a little bit different
  ;; challenge according to their color
  ask turtles [
    if  (color = white) [white-challenge]

    if  (color = red) [red-challenge]
    ]

  ;; if the planet is overcrowded the starfishes arrive to the reproductive age later
  ;; the reproductive process is linked to the mutation chance given by the mutation_rate
  ;; after a mutation a red newborn starfish became white
  ifelse crowd? = false
    [ask turtles [if age > 2 [reproduction]]]
    [ask turtles [if age > 3 [reproduction]]]

  ;; starfishes have all the same life cycle, lasting four cosmic ticks
  ask turtles [
    set age age + 1
    if age > 4 [die]
    ]

  ;; the number of starfishes composing the two subpopulations is counted
  set n.red count turtles with [color = red]
  set n.white count turtles with [color = white]
  set rw_difference n.red - n.white

  ;; the simulation is terminated if both subpopulations are extinguished
  if (n.red + n.white = 0) [stop]

  ;; if the number of total starfishes is excessive, the system senses its state as overcrowded
  ifelse (n.white + n.red) > 1000 [set crowd? true] [set crowd? false]

  set mmut mean [mutator] of turtles
  set mvar mean [tolerance_variation] of turtles
end 

to white-challenge
  ;; the white starfishes have got a survival range included between -17 and 19 unit of cosmic energy
  if (surface_energy >= 19 + tolerance_variation) [die]
  if (surface_energy <= -17 + tolerance_variation) [die]
end 

to red-challenge
  ;; the red starfishes have got a survival range included between -19 and 17 unit of cosmic energy
  if (surface_energy >= 17 - tolerance_variation) [die]
  if (surface_energy <= -19 - tolerance_variation) [die]
end 

to reproduction
  hatch 1 [
    set age 0
    rt random-float 360
    fd 2
    if mutator-gene [if random 100 < environmental_mutation_rate + mutator
      [set mutator mutator + (random 3 - 1)]]
    set size 0.7 + tolerance_variation / 5
    if color = red [red-mutation]
    if color = white [white-mutation]
  ]
end 

to white-mutation
  ;; when tolerance-shift is ON the range of tolerance become a genetic character of starfishes
  ;; so it can change in dependence of mutation rate and it is preferentially increased
  if tolerance-shift [
    if (random 100 < environmental_mutation_rate + mutator) [
      set tolerance_variation (tolerance_variation + random 10 - 0.1)
      if tolerance_variation <= -3 [die]
      ]
    ]
  ;; even if tolerance-shift is OFF the color of newborn starfish can mutate becoming red
    if random 100 < environmental_mutation_rate + mutator [
    set color red
    ]
end 

to red-mutation
  ;; when tolerance-shift is ON the range of tolerance become a genetic character of starfishes
  ;; so it can change in dependence of mutation rate it is preferentially increased
  if tolerance-shift [
    if random 100 < environmental_mutation_rate + mutator [
      set tolerance_variation (tolerance_variation + random 10 - 0.1)
      if tolerance_variation <= -3 [die]
      ]
    ]
  ;; even if tolerance-shift is OFF the color of newborn starfish can mutate becoming white
  ;; as consequence of this the tolerance-variation is inverted, as well
  if (random 100 < environmental_mutation_rate + mutator) [
     set color white
    ]
end

There are 18 versions of this model.

Uploaded by	When	Description	Download
Cosimo Leuci	over 6 years ago	Rev. 3.6.1	Download this version
Cosimo Leuci	almost 7 years ago	Default values slightly varied	Download this version
Cosimo Leuci	over 7 years ago	NetLogo 6.0.1 updated version	Download this version
Cosimo Leuci	over 8 years ago	A new slider (energy_average) allows you to vary the axis of energy oscillation, causing a new form of environmental stress	Download this version
Cosimo Leuci	over 8 years ago	further adjustment of mutation_rate slider to a more effective range	Download this version
Cosimo Leuci	over 8 years ago	Mutation rate slider was extended to very low levels (10E-8) as estimated in same biological systems (e.g. Escherichia coli)	Download this version
Cosimo Leuci	over 8 years ago	Documentation updated	Download this version
Cosimo Leuci	over 8 years ago	The expression of "mutator" gene was improved (the effect is retained qualitatively as before)	Download this version
Cosimo Leuci	over 8 years ago	Info updated, interface enhanced	Download this version
Cosimo Leuci	over 8 years ago	Some bugs were fixed and some theoretical choises were revisited. A "mutator" gene was added.	Download this version
Cosimo Leuci	over 8 years ago	Reverted to older version	Download this version
Cosimo Leuci	over 8 years ago	Reverted to older version	Download this version
Cosimo Leuci	over 8 years ago	Reverted to older version	Download this version
Cosimo Leuci	over 8 years ago	Reverted to older version	Download this version
Cosimo Leuci	over 8 years ago	Reverted to older version	Download this version
Cosimo Leuci	over 8 years ago	Reverted to older version	Download this version
Cosimo Leuci	over 8 years ago	Some bugs was fixed and some theoretical choises were revisited. A "mutator" gene was added.	Download this version
Cosimo Leuci	over 8 years ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
Starfish_Planet_3.png	preview	Preview for 'Starfish_Planet_3'	over 8 years ago, by Cosimo Leuci	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo