Honey Bee Colony Collapse Disorder Model

Honey Bee Colony Collapse Disorder Model preview image

1 collaborator

Default-person Stan Huang (Author)

Tags

(This model has yet to be categorized with any tags)
Model group MAM-2015 | Visible to everyone | Changeable by the author
Model was written in NetLogo 5.2.0 • Viewed 1396 times • Downloaded 173 times • Run 0 times
Download the 'Honey Bee Colony Collapse Disorder Model' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

The Honey Bee CCD Model is a tool that is used to simulate honey bee Colony Collapse Disorder bt four different factors, pesticides, the Varroa Mite, High Fructose Corn Syrup, and deforestation.

The model maps out a population of honey bees, wild flowers, and hives, that are affected by different settings as indicated by the user.

The goal of this model is to find out how these different factors work together to cause CCD, a major issue currently affecting bee colonies all over the United States.

HOW IT WORKS?

The agents of the Honey Bee CCD model consist of different breeds of turtles and the patches. These different breeds of turtles include bees, flowers, and hives.

Bees:

The bees are concerned with only two things, collecting pollen for the hive and staying alive. To do this they will seek out flowers and collect pollen from them. Rules:

  1. I am born in the hive with random energy and age
  2. I move around randomly at a speed of .25 per tick
  3. If I see a flower in my cone of vision, I will turn towards it and fly at a speed of .5 per tick
  4. If I touch a flower and it has pollen, I will collect one pollen from it and look for another flower
  5. If I have five or more pollen, I will turn towards my hive and fly there at .5 per tick
  6. Once I reach my hive I will deposit five pollen
  7. If my energy gets too low, I will consume a pollen
  8. If I fly over pesticide sprayed lands (pink, light pink, light green) lose energy of value pesticide-potency
  9. If Mites are on, lose energy every 5 ticks or so
  10. If High Fructose Corn Syrup is on, add energy every 10 ticks or so but take twice the damage from pesticides and mites
  11. Each tick I lose energy and I age
  12. If my energy or age reaches zero, I die

Flowers:

The flowers are concerned with producing pollen and planting the seeds for new flowers to grow. In order to do this, they need the assistance of bees to cross pollinate. Rules:

  1. I am born with a random age on top of grass or pesticide sprayed grass
  2. Every tick I have a chance of increasing my pollen count by one
  3. If a bee lands on me and I have pollen, I lose one pollen
  4. If a bee lands on me and it is carrying pollen, I become pollinated
  5. If pollinated, I have a chance every ten ticks to release to spawn a new flower up to fifteen patches away from me.
  6. If my offspring is to spawn on roads, don’t let it spawn
  7. Every tick my age goes down by one
  8. If my age reaches zero, I die

Hive(s):

The main hive is a yellow rectangle which acts as the spawn point of every bee. Its purpose is to store nectar created from every five pollen that is returned by bees, and to grow in size. Rules:

  1. I am spawned randomly in the world
  2. Every time a bee deposits 5 pollen into me, I increase in nectar by one
  3. For every hundred nectar I receive, add on another yellow rectangle adjacent to me

Patches:

The patches represent the ground of the system. In most cases its grass but in certain cases it can be pesticide treated land or roads Rules:

  1. I spawn green 55.5
  2. If sprayed pesticides, turn pink
  3. If pink for 1000 ticks, turn light pink
  4. If light pink for 1000 ticks, turn light green
  5. If light green for 1000 ticks, turn green
  6. If set to road, turn dark gray

HOW TO USE IT

There are many different settings that can be sdjusted to fit the needs of the user, and ways to interact with the model.

Running the Model:

Setup: Click this button to set up the model. It spawns the inital flowers and hive randomly on the display. The initial bees are spawned wherever the hive is.

Go: Click this button to run the model and start the ticks. The agents will start to move and interact with one another.

Sliders/Variables

As seen on the UI, various sliders and variables can be set to change the initial conditions of the model.

Bees

initial-number-bees: This sets the initial number of bees spawned upon setup. Deafault 10.

bees-gain-from-food: This is how much energy a bee gains from eating pollen. Default 20.

bee-reproduce: This is the rate at which new bees will spawn from the hive every ten ticks. Default 6%

Flowers

initial-number-flowers: This is the initial number of flowers spawned upon setup. Default 40.

flower-pollen-rate: This is the rate at which flowrs gain pollen every tick. Default 10%

flower-reproduce: This is the rate at which flowers reproduce when pollinated every ten ticks. Default 5%.

Hives

initial-number-hives: This is the initial number of hives spawned upon setup. Default 1.

CCD Factors

pesticide-strength: How much energy per tick a bee loses flying over pesticides. Default 2.

mite-infection-rate: The rate at which new bees are infected with mites. Default 60%.

corn-syrup-value: How much energy a bee gains per ten ticks from being fed High Fructose Corn Syrup. Default 3.

mite-damage: How much energy per five ticks a bee loses from a mite infection. Default 3.

CCD Factors

mouse-interation: A chooser that sets what clicking on patches does. Options are either spray pesticides, buid roads, or plant grass.

corn-syrup?: Sets bees being fed High Fructose Corn Syrup on or off.

mites?: Sets bees being affected by Varroa Mites on or off.

test-pesticides?: Testing tool, sets flowers automatically having pesticides applied to them on or off.

Monitors and Plots

Population Plot: Plots the population of bees and flowers over time.

Total Flower Pollen: Plots the total amount of pollen shared among flowers over time.

Hive Size: Plots the number of hives (yellow hexagons) in the main hive (hive 0) over time.

Total Flower Pollen Monitor: count of total pollen among flowers

'#Bees': Count of bees

'#Flowers': Count of flowers

Hive Size Monitor: Count of hives in main hive (count of yellow hexagons).

THINGS TO NOTICE

The Population of Bees and Flowers

Bees and flowers depend on each other in order to survive. Pay attention to how they interact and how they populations shift with each other, especially once CCD factors are applied.

The Effects of CCD Factors

Pay attention to just how the CCD factors affect the model. What do they do to the bees? The flowers? Does the populaiton drop suddenly or is it gradual?

Clustering of Bees and Flowers

When different CCD Factors are applied, especially roads, how does the behavor of bees and flowers change? Do they cluster to one place or does it spread around the display? What happens when pesticides are aplied then?

Colony Collapse

Try to pinpoint the moment that CCD becomes imminent. What factors did you use? What settings were set? Are they realistic?

THINGS TO TRY

CCD Fators and Mixing

Try all of the four CCD factors and play around with mixing them together. What kind of effects does this have on the population? Do any of these combinations cause CCD, and if so, how quicklhy and efficiently are bees dying off?

Mouse Interaction

Using the chooser, select pesticides or roads to interact with the model. Just click a patch or drag it around in order to spray pesticides or create roads. This should change the behavior of both the bees and flowers over time, and different kinds of patterns can be set.

Different mite-damage and pesticide-strength

Play around with these settings. Just how dangerous do pesticides and mites have to bee to take out a bee colony on their own?

Flipping on Switches

Let a population take its course for a while before flipping on corn-syrup? or mites?. What kind of differences do you see when the switiches are turned on halfway?

EXTENDING THE MODEL

Bee Communication

While this model has each bee acting separately, I would love to be able to use links to simulate communication which would lead bees to share information about were certain flowers were. This might have even lead to a different result in my deforestation analysis if it was implemented.

Cross Breeding Colors

Another additional feature that would have been good to have would be more accurate cross breeding between flowers. A newly born flower should share and combine traits from both its parents, not just one. In the current model a new flower will have a variant color depending on the flower that hatched it, but I would like to also have its color affected by the color of the flower that had its pollen used to pollinate the parent flower. It would have at least made for a more colorful board.

More Complicated Mite Features

In reality, the effects of Varro Mites on bees is far more complex than what is programmed already. There is a risk for infections and various different viruses and diseases a bee can receive just from having been infected by a mite. Unfortunately the implementation of it here can be considered primitive.

NETLOGO FEATURES

Mouse Interaction

This model makes use of the mouse interaction features of NetLogo to make the display interactive and allow for all different kinds of scenarios in this bee flower population.

Cone of Vision

This model uses NetLogo's cone of vision tactic in order to help bees locate flowers in their range of vision.

RELATED MODELS

Many of the features used in this model took inspiration from other NetLogo models easily found through the included library.

Wolf-Sheep Model

This model was the inspiraiton to create some sort of population model consisting of random movements, but sustained populations between animals.

Flocking-Vee Model

This model was the inspiration for the bees' feature of finding and following flowers, as well as flying straight towards their hive once enough pollen has bee collected. They emulate how the birds i the Flocking-Vee Model follow each other when in their cone of vision.

CREDITS AND REFERENCES

My model can be found on ModelingCommons here: http://modelingcommons.org/browse/one_model/4399#model_tabs_browse_info

Credits

Honey Bee Colony Collapse Disorder Model created by Stan Huang.

Thanks to my Professor Uri Wilensky and his wonderful TAs Bryan Head, Arthur Hjorth, and David Weintrop for teaching me about this nifty tool!

Citations

1) Boland, Maria. "The Importance of Honeybees." MNN. Mother Nature Network, 3 May 2010. Web. 06 June 2015. http://www.mnn.com/earth-matters/animals/stories/the-importance-of-honeybees.

2) Gore, Bob. "Colony Collapse Disorder Is Responsible for 42 % Increase in Bee Mortality Rate in the US According to Research." Empire State Tribune. Empire State Tribune, 19 May 2015. Web. 06 June 2015. http://www.esbtrib.com/2015/05/19/12611/colony-collapse-disorder-is-higher-by-11-percent-this-year-in-colorado-compared-to-last-year/.

3) Henry, Mikael. "A Common Pesticide Decreases Foraging Success and Survival in Honey Bees." A Common Pesticide Decreases Foraging Success and Survival in Honey Bees. Science Magazine, 29 Mar. 2012. Web. 06 June 2015. http://www.sciencemag.org/content/336/6079/348.

4) "Pesticide Combination Affects Bees' Ability to Learn." 27 March 2012. Bioscience for the Future, 27 Mar. 2013. Web. 06 June 2015. http://www.bbsrc.com/news/food-security/2013/130327-pr-pesticide-combination-affects-bees.aspx.

5) Shelomi, Matan. "What's the Deal with the Bees?" Quora.com. N.p., 20 May 2014. Web. .

6) Yirka, Bob. "Researchers Find High-fructose Corn Syrup May Be Tied to Worldwide Collapse of Bee Colonies." Researchers Find High-fructose Corn Syrup May Be Tied to Worldwide Collapse of Bee Colonies. Phys.org, 30 Apr. 2013. Web. 07 June 2015. http://phys.org/news/2013-04-high-fructose-corn-syrup-tied-worldwide.html.

Comments and Questions

Why at 1 pm eastern standard time is there such an overload? (Question)

My class has been trying to use this around 1 pm and we get a message that there are too many users and will not let us run the program. Any suggestions?

Posted 7 months ago

Click to Run Model

breed [bees bee]  
breed [hives hive]
breed [flowers flower]
turtles-own [
  energy
  age
  visible-neighbors
  closest-neighbor
  ]       
bees-own [
  pollen 
  infected
  ]
hives-own [
  nectar
  growth-num
  ]
flowers-own [
  pollen-count
  pollinated?
  ]
patches-own [
  countdown
  ]

to setup
  clear-all
  ask patches [ set pcolor 55.5 ]
  
   set-default-shape hives "hex"
  create-hives initial-number-hives  ;; create the hives, then initialize their variables
  [
    set color yellow
    set size 1  ;; easier to see
    set energy 200
    set age random 1000
    setxy random-xcor random-ycor
  ]
  
  set-default-shape bees "bee"
  create-bees initial-number-bees  ;; create the bees, then initialize their variables
  [
    
    set size 0.5 
    set energy random (2 * bees-gain-from-food)
    set age random 1000
    setxy 
     [xcor] of hive 0 [ycor] of hive 0
    if random-float 100 < mite-infection-rate [ 
      set infected 1
    ]
  ]

  set-default-shape flowers "flower"
  create-flowers initial-number-flowers ;; create the flowers, then initialize their variables
  [
    set pollen-count random 20
    set age (random 1000 - count flowers) ;; Set random age, the more flowers there are the smaller lifespan new flowers have
    set size 3  ;; easier to see
    setxy random-xcor random-ycor
  ]
  reset-ticks
end 

to go
  if not any? turtles [ stop ]
  if mouse-interaction = "pesticide" [ ;; If the mouse-interaction is set to pesticide, mouse clicking will spray pesticides
    pesticides
  ]
  if mouse-interaction = "roads" [ ;; If the mouse-interaction is set to roads, mouse clicking will build roads
    deforestation
  ]
  if mouse-interaction = "grass" [ ;; If the mouse-interaction is set to grass, mouse clicking will make grass
    grass
  ]
  ask patches [
    pesticide-countdown ;; count down pesticide fading
  ]
  ask bees [
    ifelse pollen > 5[                        ;; If bees have more than 5 pollen, return to hive and deposit
      deposit-to-hive                         ;; Call deposit-to-hive procedure
    ]
    [
      set visible-neighbors (other flowers in-cone 10 120)  ;; Else, go find flowers in cone of vision
      ifelse any? visible-neighbors [
        set closest-neighbor min-one-of visible-neighbors [distance myself]   ;; If flower found, go towards it
        face closest-neighbor
        fd 0.5
        collect-pollen                                ;; Call collect-pollen procedure
      ]
      [
        move                                          ;; If flwoer not found, move randomly
      ]
    ]
    if energy < bees-gain-from-food [                 ;; If energy is lover than bees-gain-from-food, eat pollen if any and gain energy
      if pollen > 0 [
        set pollen (pollen - 1)
        set energy (energy + bees-gain-from-food)
      ]
    ]
    corn-syrup                                        ;; Call corn-syrup procedure
    if (ticks + random 5) mod 10 = 0 [                ;; Every 10 ticks or so, reproduce bees from hive
      reproduce-bees
    ]
    set energy (energy - 1)                           ;; Bees lose energy every tick
    if member? ([pcolor] of patch-here) (list 17 19 59) [
      set energy (energy - pesticide-strength)        ;; If flying on pesticides, lose energy based on pesticide-strength
      if corn-syrup? [
        set energy (energy - pesticide-strength)      ;; If corn syrup is on, lose twice as much energy
      ]
    ]
    if mites? [                                       ;; If mites are on,lose energy based on mite-damage every 5 ticks or so
      mite-effects                                    ;; Call mite-effects procedure
    ]
    set age (age - 1)                                ;; Age bees every tick
    death                                            ;; Die if no energy or too old
  ]

  ask hives [
    if count bees = 0 [                              ;; If no more bees, start hive collapse
        set energy energy - 1                        ;; hives lose energy per tick in collapse
    ]
    if hive 0 != nobody [
      reproduce-hives                                ;; Make adjacent hives when growing
    ]
    death                                            ;; Die in collapse
  ]
  ask flowers [
    if [pcolor] of patch-here = 2 or [pcolor] of neighbors = 2 [ ;; Die on roads/Never spawn
      die
    ]
    if any? hives-here or any? hives-on neighbors[               ;; Can't spawn on hives
      die
    ]                     
    if random-float 100 < flower-pollen-rate [                   ;; Produce pollen per tick based on flower-pollen-rate
      set pollen-count (pollen-count + 1)
    ]
    if age < 600 [
      if (ticks + random 5) mod 10 = 0[                          ;; Every 10 ticks or so when a flower has under 600 ticks of age left, a flower has the chance of reproducing if pollinated already
        if pollinated? = 1 [
          reproduce-flowers
        ]
      ]
    ]
    if test-pesticides? [
      ask patch-here [                                             ;; For testing purposes only, spray all flowers
        set pcolor 17
      ]
    ]
    set age (age - 1)
    death                                                        ;; Age and die if too old
  ]
  tick
end 

to move  ;; turtle procedure, moves turtle randomly
  rt random 50
  lt random 50
  fd 0.25
end 

;; REPRODUCTION

to reproduce-bees  ;; bees procedure, reproduces the bees
  if random-float 100 < bees-reproduce [  ;; throw "dice" to see if you will reproduce
    ask hive 0 [
      hatch-bees 1 [ 
        set size 0.5  
        set age random 1000
        set energy random (2 * bees-gain-from-food)
        rt random-float 360 fd 0.5
        if random-float 100 < mite-infection-rate [  ;; Set infection by mite (no effect unless mite? switch turned on)
          set infected 1
        ]
      ] 
    ]
  ]
end 

to reproduce-hives  ;; hive procedure to reproduce hives
  if [growth-num] of hive 0 > 100 [  ;; If growth number reaches 100 (100 nectar put into hive), reproduce another yellow rectangle onto it
    hatch 1 [ 
      set energy random 100          ;; Energy within 100
      rt random-float 360 fd 0.5
      ]  ;; hatch an offspring and move it forward 0.5 step next to first hive
    ask hive 0 [
      set growth-num 0               ;; Reset growth number     
    ]
  ]
end 

to reproduce-flowers  ;; Flower procedure, reproduces flowers
  if random-float 100 < flower-reproduce [                          ;; throw "dice" to see if you will reproduce
    hatch 1 [ 
      set pollen-count 0
      set color (color + (random 2) - (random 2))                   ;; Spawn color is a variant of parent color
      set age (random 1000 - count flowers)
      set size 3  ;; easier to see
      rt random-float 360 fd random 15                              ;; Set spawn placement at most 15 patches away
      while [any? other flowers-here or any? flowers-on neighbors][ ;; If flower already here, randomly move 2 to find different patch
        rt random-float 360 fd 2
      ]
      if any? hives-here or any? hives-on neighbors[                ;; Can't spawn on hives
        die
      ]
      set pollinated? 0
      if [pcolor] of patch-here = 2 or [pcolor] of neighbors = 2 [ ;; Can't spawn on roads
        die
      ]
    ]
    set pollinated? 0                                               ;; Flower not pollinated anymore
  ]
end 

;; POLLEN PROCEDURES

to collect-pollen  ;; bee procedure to collect pollen from flowers
  let buddy one-of flowers-here                    ;; grab flower present
  if buddy != nobody[
    if [pollen-count] of buddy > 0                 ;; did we get one?  if so,
    [ 
      ask buddy [                                  ;; collect pollen from flower, and pollinate it
        set pollen-count (pollen-count - 1)
        set pollinated? 1
 
      ]
      set pollen (pollen + 1)

    ] 
  ]
end 

to deposit-to-hive                        ;; Procedure to deposit pollen into hive which is converted to nectar
  face hive 0
  fd 0.5
  let home-hive one-of hives-here         
  if home-hive = hive 0 [
    set pollen (pollen - 5)               ;; Deposit pollen
    ask hive 0 [
      set nectar (nectar + 1)
      set growth-num (growth-num + 1)     ;; increase nectar and growth number
    ]
  ]
end 

;; PESTICIDES 

to pesticides ;; CCD Factor procedure, mouse click to set pesticides
  if mouse-down?[ 
    ask patch mouse-xcor mouse-ycor [ 
      if pcolor = 55.5 [
        set pcolor 17
        set countdown 1000
      ]
        ask neighbors [                         ;; Also set it on neighbors
          if pcolor = 55.5 [
            set pcolor 17
            set countdown 1000
          ]
        ]
    ] 
   ]
end 

to pesticide-countdown          ;; Patch procedure to cause pesticide fading
  if pcolor = 17 [              ;; This block of code will make pesticide sprayed grass turn light pink after 100 ticks, then light green, then back to green (grass).
    if countdown = 0 [          ;; When the grass is green again, the pesticides have faded away. This entire procedure is done through the use of a countdown variable.
      set pcolor 19
      set countdown 1000
    ]
  ]
  if pcolor = 19 [
    if countdown = 0 [
      set pcolor 59
      set countdown 1000
    ]
  ]
  if pcolor = 59 [
    if countdown = 0 [
      set pcolor 55.5           
    ]
  ]
  if countdown > 0 [
    set countdown (countdown - 1) ;; End block of fading pesticides
  ]
end 

;; VARROA MITES

to mite-effects
  if infected = 1 [
    if (ticks + random 5) mod 5 = 0 [
      set energy (energy - mite-damage)
      if corn-syrup? [                            ;; If corn syrup is on, lose twice as much energy
        set energy (energy - mite-damage)
      ]
    ]
  ]
end 

;; HIGH FRUCTOSE CORN SYRUP

to corn-syrup                              ;; Turn on corn syrup and feed bees every 10 ticks or so
  if (ticks + random 5) mod 10 = 0 [
    set energy (energy + corn-syrup-value)
  ]
end 

;; DEFORESTATION

to deforestation ;; CCD Factor procedure, mouse click to set roads
  if mouse-down?[ 
    ask patch mouse-xcor mouse-ycor [ 
      set pcolor 2
      ask neighbors [                      ;; Also set on neighbors
        set pcolor 2
        ]
      ] 
    ]
end 

;; SET GRASS

to grass ;; Patch procedure, change patches back to grass
  if mouse-down?[ 
    ask patch mouse-xcor mouse-ycor [ 
      set pcolor 55.5
      ask neighbors [                      ;; Also set on neighbors
        set pcolor 55.5
        ]
      ] 
    ]
end 

to death  ;; turtle procedure, cause death
  ;; when energy or age dips below zero, die
  if energy < 0 [ die ]
  if age < 1 [die]
end 


 

There are 6 versions of this model.

Uploaded by When Description Download
Stan Huang over 10 years ago Fixed small issue Download this version
Stan Huang over 10 years ago Added some comments Download this version
Stan Huang over 10 years ago Completed model and Info tab Download this version
Stan Huang over 10 years ago Added last two CCD factorrs Download this version
Stan Huang over 10 years ago Updated lots of things, first two detrimental factors working Download this version
Stan Huang over 10 years ago Initial upload Download this version

Attached files

File Type Description Last updated
372 Poster.pdf pdf Poster for Poster Fair over 10 years ago, by Stan Huang Download
Honey Bee Colony Collapse Disorder Model.png preview Preview Image over 10 years ago, by Stan Huang Download
Honey Bee Colony Collapse Disorder Model.png preview Preview Image Fixed over 10 years ago, by Stan Huang Download
Huang_Stan_Slam.pdf pdf Poster Slam Slides over 10 years ago, by Stan Huang Download
Project Proposal.docx word Old Project Proposal (Original Idea) over 10 years ago, by Stan Huang Download
Project_Proposal.pdf pdf Project Proposal for this Model over 10 years ago, by Stan Huang Download
Stan_HuangFinalReport.pdf pdf Final Report of Model over 10 years ago, by Stan Huang Download
StanHuang_June1.pdf pdf 3rd Progress Report over 10 years ago, by Stan Huang Download
StanHuang_May18.pdf pdf First Progress Report (project revamped later so disregard content) over 10 years ago, by Stan Huang Download
StanHuang_May25.pdf pdf 2nd Progress report over 10 years ago, by Stan Huang Download

This model does not have any ancestors.

This model does not have any descendants.