Child of Simple Birth Rates

globals
[
  red-count            ; populacija rdecih
  blue-count           ; populacija modrih
]

turtles-own
[
  fertility            ; rodnost
  fertility-remainder  ; ostanek (za decimalno piko)
]

to setup
  clear-output
  setup-experiment
end 

to setup-experiment
  cp ct
  clear-all-plots
  reset-ticks
  crt steviloPrebivalstva
  [
    setxy random-xcor random-ycor         ; postavi osebe na nakljucna mesta
    ifelse who < (steviloPrebivalstva / 2)  ; zacni z enakim stevilom rdecih in modrih
      [ set color blue ]
      [ set color red ]
    set size 2                            ; boljsa preglednost
  ]
  reset-ticks
end 

to go
  reproduce
  grim-reaper
  tick
end 

;; omogoci vec ponavljanj

to go-experiment
  go
  if red-count = 0
  [
    output-print (word "Rdeči izumrejo po " ticks " generacijah.")
    setup-experiment
  ]
  if blue-count = 0
  [
    output-print (word "Modri izumrejo po " ticks " generacijah.")
    setup-experiment
  ]
end 

to wander  ;; premikanje zelv
  rt random-float 30 - random-float 30
  fd 1
end 

to reproduce
  ask turtles
  [
    ifelse color = red
    [
      set fertility floor rdeci-rodnost
      set fertility-remainder rdeci-rodnost - (floor rdeci-rodnost)
    ]
    [
      set fertility floor modri-rodnost
      set fertility-remainder modri-rodnost - (floor modri-rodnost)
    ]
    ifelse (random-float 100) < (100 * fertility-remainder)
      [ hatch fertility + 1 [ wander ]]
      [ hatch fertility     [ wander ]]
  ]
end 

;; unici visek oseb
;; rdeci in modri imajo enak odstotek smrtnosti

to grim-reaper
  let num-turtles count turtles
  if num-turtles <= steviloPrebivalstva
    [ stop ]
  let chance-to-die (num-turtles - steviloPrebivalstva) / num-turtles
  ask turtles
  [
    if random-float 1.0 < chance-to-die
      [ die ]
  ]
end 


; Copyright 1997 Uri Wilensky.
; See Info tab for full copyright and license.