Schistosomiasis

1 collaborator

WHAT IS IT?

Shistosomiasis is a disease caused by parasitic worms Schistosoma mansoni and others.

HOW IT WORKS

The disease is caused by parasitic worms that go through life stages. When worm eggs are hatched in water (rivers etc.) they release miracidium which will find snails (Biomphalaria glabrata, and others) as intermediary hosts. Once the intermediary hosts are infected, miracidium will form sporocysts. After a few generations of sporocysts, snails produce cercariae, which are released into water and might contaminate human beings when in contact by penetrating humans' skin. The life stages will follow to develop into an adult worm that reside most commonly in human intestines. For our purposes here, we consider the lifestages: eggs, miracidium, cercariae, and worm.

Number of Humans is N1 (fixed at N1=50). Number of snails is set fixed at N2=50.

Worm -- The worm survive at each time interval with probability pWorm. They are created when a human gets in touch with cercariae and cercariae penetrate human skin with rate Beta₁ (assumed almost perfect).

Miracidium -- Miracidium are created at rate lambda1Eggs and survice with probability pMiracidium.

Cercariae -- They are created at rate lambda1LibCercariae and survive with probability pCercariae.

Snail -- Snails are assumed at a fixed level. A fraction of them is infected initially which starts the process. It is assumed that the mortality rate is equal to the birth rate. For simplicity, then, whenever a snail dies another one is given birth. In practical terms, the result is the replacement of a possibly infected one by an uninfected snail. The probability of turning a snail into an uninfected state is pSnail.

lambda1Eggs -- rate of eggs produced per female worm lambda1LibCercariae -- rate of cercariae releasing per infected snail

f -- fraction of snails that survive to produce cercariae.

The model in Anderson and May also includes parameters (Beta₁ and Beta₂) which are considered almost perfect here (their values set fixed at 0.99).

HOW TO USE IT

To use the model, set the variables described above, press SETUP, and then GO.

The plot shows the number of infected humans, total number of miracidiums, total number of cercariae, and the number of infected snails.

THINGS TO NOTICE

The green part of the world represents non-aquatic areas, whereas the blue part of the world represents aquatic area (rivers, for instance).
An infection to a human can happen only in water.

THINGS TO TRY

By changing values for the parameters, it is possible to create scenarios in which schistosomiasis disappears, whereas it is also possible to see situations in which humans (and also snails) keep infected for long periods of time. The result indeed depends on the basic reprodution number R₀ as described in Anderson and May (1992).

RELATED MODELS

This model uses the same setup of the El Farol model by Uri Wilensky. There are patches for the bar. In this model, these patches represent the river. The rest of the area is area where humans circulate and eventually go to the river.

CREDITS AND REFERENCES

Model created by:

Daniel A.M. Villela PROCC - FIOCRUZ Av. Brasil, 4365 Rio de Janeiro, RJ, Brazil

E-mail: dvillela AT fiocruz . br

This model is inspired by the modeling of schistosomiasis described in the book by Roy Anderson and Robert May.

Anderson, Roy M., Robert M. May, and B. Anderson. Infectious diseases of humans: dynamics and control. Vol. 28. Oxford: Oxford university press, 1992.

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

Villela, Daniel (2013). NetLogo Schistosomiasis model. NetLogo Modeling Commons. Program for Scientific Computing, Oswaldo Cruz Foundation, Rio de Janeiro, Brazil.
Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [ miracidiums miracidium ]
breed [ humans human ]
breed [ cercariaes cercariae ]
breed [ snails snail ]
breed [ schistosomas schistosoma ]


globals [
  home-patches      
  water-patches       
  N1
  N2
  N2inf
  ;; probability of moving into snails area
  pmove
  lambda1
  lambda2
  beta1
  beta2
]


turtles-own [
  mu          ;; mortality rate  
  infected?
  
]

to setup
  clear-all
  set-default-shape humans "person"
  set-default-shape snails "dot"
  set-default-shape cercariaes "triangle"
  set-default-shape miracidiums "triangle"
  
  set beta1 0.99
  set beta2 0.99
  set pmove 0.5
  
  set home-patches patches with [pycor < 0 or (pxcor <  0 and pycor >= 0)]
  ask home-patches [ set pcolor green ]
  
  set water-patches patches with [pxcor > 0 and pycor > 0]
  ask water-patches [ set pcolor blue ]

set N1 50
  ;; create humans
  create-humans N1 [
    set color white
    set infected? false
    move-to-empty-one-of home-patches
  ]
  
  ;; create snails
  set N2 50
  set N2inf 20
  
  ;; infected ones
  create-snails N2inf [
    set color white
    set infected? true
    move-to-empty-one-of water-patches   
  ]
  
  create-snails N2 - N2inf [
    set color white
    set infected? false
    move-to-empty-one-of water-patches   
  ]
  
  ;; start the clock
  reset-ticks
end 

to go

  ask humans [
 
    ;; movement of humans
    ifelse random-float  1 < pmove [
      move-to-empty-one-of home-patches
    ]
    [
      move-to one-of water-patches   
      if any? cercariaes-here with [ infected? = true ] and random-float 1 < beta1 [
        set infected? true
      ]
      if infected? [ mymake-miracidiums ]
    ]
  
    if infected? and random-float 1 < ( 1 - pworm ) [
      set infected? false
    ]
  
  ]

  ask snails [  
    ;; model assumes that as some of them die new snails appear
    ;; so the number stays at a constant level
    ifelse random-float 1 < (1 - pSnail) [
      set infected? false
    ]
    [
      move-to one-of water-patches  
      if any? miracidiums-here with [ infected? = true ] and random-float 1 < beta2 [
        set infected? true
      ]  
      ;; model has f as fraction of snails that survive to release cercariae       
      if infected? and random-float 1 < f [ mymake-cercariae ]   
    ]
  ]

  ask miracidiums [
    ifelse random-float 1 < ( 1 - pMiracidium ) [
      die
    ] 
    [
      move-to one-of water-patches
    ]
  ]

  ask cercariaes [
    ifelse random-float 1 < ( 1 - pCercariae ) [
      die
    ]
    [
      move-to one-of water-patches
    ]   
  ]

  tick
end 

to mymake-cercariae 
  hatch-cercariaes random ( 2 * lambda2LibCercariae) [
    set infected? true
    set color red
    move-to one-of water-patches
  ] 
end 

to mymake-miracidiums 
  hatch-miracidiums random ( 2 * lambda1Eggs) [
    set infected? true
    ;; set color red
    move-to one-of water-patches
  ] 
end 

;; same procedure in the El Farol model by Uri Wilenski

to move-to-empty-one-of [locations]  ;; turtle procedure
  move-to one-of locations
  while [any? other turtles-here] [
    move-to one-of locations
  ]
end 


; Copyright 2013 Daniel Villela.
; See Info tab for full copyright and license.

There are 2 versions of this model.

		Uploaded by	When	Description	Download
		Daniel Villela	over 10 years ago	just a fix in the reference	Download this version
		Daniel Villela	over 10 years ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
Schistosomiasis.png	preview	Preview for 'Schistosomiasis'	over 10 years ago, by Daniel Villela	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo