Membrane Formation

No preview image

2 collaborators

Uri_dolphin3 Uri Wilensky (Author)
Default-person Bryan Head (Author)

Tags

ccl 

Tagged by Uri Wilensky over 7 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 234 times • Downloaded 15 times • Run 0 times
Download the 'Membrane Formation' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model simulates the formation of membranes in water. It shows how simple attractive and repulsive forces between different kinds of molecules can result in higher level structure. For more information about natural membranes, see http://en.wikipedia.org/wiki/Lipid_bilayer.

HOW IT WORKS

The blue circles are water molecules. A purple circle connected to an orange circle is a lipid. The purple end is hydrophilic and the orange end is hydrophobic. The purple hydrophilic molecule is attracted to water, while the orange hydrophobic molecule repels water.

At each tick, every molecule picks another random molecule within INTERACTION-DISTANCE. If these two molecules are water, one is water and the other is hydrophilic, both are hydrophilic, or both are hydrophobic, the acting molecule moves towards the other molecule by WATER-WATER-FORCE. If one molecule is hydrophobic and the other is water, the molecule moves in the direction of the other by WATER-OIL-FORCE; since this value is negative, they move away from each other.

After its first move, the acting molecule then picks a random molecule in TOO-CLOSE-DISTANCE and moves in its direction by TOO-CLOSE-FORCE. Since TOO-CLOSE-FORCE is negative, this causes molecules that are too close to repel each other.

Finally, if the molecule is connected by a link to another molecule, it moves to stay exactly LIPID-LENGTH away from its partner.

The hydrophobic isolation plot shows the average percentage of each hydrophobic molecule's neighbors that are also hydrophobic . Hence, the higher this is, the more hydrophobic molecules are isolated from water and hydrophilic molecules.

HOW TO USE IT

First choose how many water molecules and how many lipid pairs to create. Press SETUP to create molecules in random positions. Press GO to begin the simulation.

  • NUM-WATER: The number of water molecules
  • NUM-LIPIDS: The number of hydrophobic-hydrophilic pairs
  • WATER-WATER-FORCE: How much a molecule should move when it is interacting with another molecule of the same type
  • WATER-OIL-FORCE: How much a molecule should move when it is interacting with a molecule of a different type
  • TOO-CLOSE-FORCE: How much a molecule should move when it's "too close" to another molecule
  • RANDOM-FORCE: Each molecule will move in a random direction this amount each tick. Increasing this "heats up" the system.

THINGS TO NOTICE

Often, the lipids will first form circular structures where their hydrophobic ends all point in towards a collection of water molecules. This is called a "micelle". Then, these micelles will join and extend, becoming a long bilayer surface. Finally, sometimes the two ends of a surface will meet, creating a membrane that separates the water on the inside from water on the outside.

Notice how the hydrophobic isolation plot generally corresponds to the presence of these structures.

THINGS TO TRY

Try adjusting the attractive and repulsive forces between the different kinds of molecules. How much can you change the forces and still see higher level structures?

How does the concentration of lipids change what structures form? What happens when you have only lipids? Do structures still form?

How do the structures change when you set WATER-WATER-FORCE to 0? How is this reflected in the hydrophobic isolation plot? Try out various combinations of forces.

What is the neutral hydrophobic isolation? That is, what happens when both WATER-WATER-FORCE and WATER-OIL-FORCE are 0?

How does RANDOM-FORCE change the rate at which structures form? What happens when you set it really high? Can the structures hold together?

EXTENDING THE MODEL

Try adding new types of molecules to the model. Can you get any other higher level structures to form?

Try making positive forces negative and negative forces positive.

NETLOGO FEATURES

While the lipids act like they are "tied" together, the model doesn't actually use TIE. Since TIE maintains the relative orientation of the turtles, we would see the lipids spinning around in a crazy manner if it was used. Instead, at the end of each ticks, the molecules attached by links move towards or away from each other to make sure their distance stays at LIPID-LENGTH.

RELATED MODELS

This model is loosely based on dissipative particle dynamics (DPD) models. These kinds of higher level structures can be observed in DPD models as well. DPD models actually take into account conservation of momentum and the fact that molecules are constantly interacting with many other molecules.

CREDITS AND REFERENCES

This model was inspired by a DPD model created by Mark Bedau and Andrew Buchanan, in their paper "Catalysis by Self-Assembled Structures in Emergent Reaction Networks".

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

  • Head, B. and Wilensky, U. (2013). NetLogo Membrane Formation model. http://ccl.northwestern.edu/netlogo/models/MembraneFormation. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
  • Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

Copyright 2013 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

Comments and Questions

netlogo (Question)

Try adjusting the attractive and repulsive forces between the different kinds of molecules. How much can you change the forces and still see higher level structures? How does the concentration of lipids change what structures form? What happens when you have only lipids? Do structures still form? How do the structures change when you set WATER-WATER-FORCE to 0? How is this reflected in the hydrophobic isolation plot? Try out various combinations of forces. What is the neutral hydrophobic isolation? That is, what happens when both WATER-WATER-FORCE and WATER-OIL-FORCE are 0? How does RANDOM-FORCE change the rate at which structures form? What happens when you set it really high? Can the structures hold together?

Posted about 1 month ago

Click to Run Model

breed [waters water]
breed [oils oil]

globals [
  lipid-length         ;; Distance between the two particles that make up a lipid
  interaction-distance ;; Max distance at which two particles interact
  too-close-distance   ;; Distance at which particles are "too close"
]

to setup
  clear-all
  
  ;; Set globals -- these values produce good visual results
  set lipid-length 2.0
  set interaction-distance 4.0
  set too-close-distance 1.3
  
  set-default-shape turtles "circle"
  create-waters (num-water + num-lipids) [
    setxy random-xcor random-ycor
    set color blue
  ]
  
  ; To create the lipids, NUM-LIPIDS oil molecules are created. Each oil molecule then picks 
  ; one water molecule that hasn’t been linked to an oil yet. That water molecule is stored 
  ; in a variable so that the oil molecule can perform a sequence of actions on it. The oil 
  ; molecule first creates a link with its partner and then moves to position LIPID-LENGTH ;
  ; away from the water molecule.
  create-oils (num-lipids) [
    let partner one-of waters with [not any? my-links]
    
    ; Put lipid-length away from its partner in a random direction
    move-to partner
    fd lipid-length
    
    create-link-with partner
    set color orange
    ask partner [ set color violet ]
  ] 
  reset-ticks
end 

to go
  ask turtles [
    interact-with-neighbor
    repel-too-close-neighbor
    interact-with-partner
  ]
  tick
end 

;;;;;;;;;;;;;;;;;;
; Turtle commands
;;;;;;;;;;;;;;;;;;

to interact-with-neighbor
  ; Select a random neighbor and interact with it
  let near one-of other turtles in-radius interaction-distance with [not link-neighbor? myself]
  if near != nobody [
    face near
    ifelse [breed] of near = breed [ fd water-water-force ] [ fd water-oil-force ]
  ]
end 

to repel-too-close-neighbor
  ; Select a random neighbor that is too close and move away from it
  let too-near one-of other turtles in-radius too-close-distance
  if too-near != nobody [
    face too-near
    fd too-close-force
  ]
end 

to interact-with-partner
  ; If in a lipid, stay the correct distance away from partner.
  let partner one-of link-neighbors
  if partner != nobody [
    face partner
    fd ((distance partner) - lipid-length)
  ]
  lt random 360
  fd random-force
end 


; Copyright 2013 Uri Wilensky.
; See Info tab for full copyright and license.

There is only one version of this model, created over 7 years ago by Uri Wilensky.

Attached files

No files

This model does not have any ancestors.

This model does not have any descendants.