Quantum Artificial Economy

No preview image

1 collaborator

WHAT IS IT?

This is a model of a quantum artificial economy, proposed in the article: "Chaos and Nonlinear Dynamics in a Quantum Artificial Economy" arXiv:1202.6647v1 [nlin.CD] http://arxiv.org/abs/1202.6647

The model belongs to a joint Econophysics, Quantum Complex Systems Science and Risk Science research line, falling under the MSC classification:

"91B80 - Applications of statistical and quantum mechanics to economics (econophysics)"

In most businesses one deals with discrete business volumes (or in the case of companies that supply goods: discrete quantities), thus, to address economic chaotic dynamics one may, effectively, assume some quantization scheme of fundamental economic variables and economic equilibrium conditions, working with a business game process, in which the quantum averages from transaction round to transaction round follow the continuous state classical chaotic dynamics of some (coupled) nonlinear map.

The current model builds up on such a proposal, introducing a quantum artificial economy with (quantum) chaotic dynamics, by combining quantum game theory, quantum chaos theory and coherent state lattice field solutions.

The model, therefore, is an evolutionary quantum game theory-based proposal that applies the mathematical formalism of quantum chaos and quantum complex systems' science to evolutionary economics, through a quantum business game where the traded quantities are discrete, allowing for economic dynamics to be addressed for discrete economic equilibrium conditions.

HOW IT WORKS

At each transaction round, each company is characterized by a coherent state solution for the business volume (measured in quantities), which corresponds to a quantum business game equilibrium condition.

The coherent states provide probability amplitudes (interpreted as Arrow-Debreu price amplitudes for business risk exposure, see Refs [1] and [2]), such that each alternative number state corresponds to a company's equilibrium solution, given by the quantum operator:

| Q(i) = N(i) + theta

where N(i) is the i-th company's bosonic number operator and theta corresponds to the lowest quantities that can be sold.

The quantitis eigenspectrum is discrete, which captures the nature of supply for most businesses.

The coherent state, for each round, alpha_t(i) (where t labels the round and i the company) is defined as the squared root of Qe_t(i) - theta, where Qe_t(i) are the (quantum) expected quantities to be sold by company i at the end of the round t.

The dynamical variable Qe_t is equal to Q-bar + niu * x_t(i), where x_t(i) is a company's fitness variable and it is driven by a continuous state coupled quadratic map (see Eqs.(30) to (32) in Ref. [2], page 7).

The nonlinear map introduces an adaptive walk on a hypercubic lattice, implementing a business economics version of Kaneko's self-organizing genetic algorithms. In this way, each company's binary string code corresponds to a core business strategic profile, where each bit of the binary string is a core business dimension (among core business dimensions one can include the mission statement and business concept).

The coupled quadratic map implements four types of evolutionary dynamics:

(A) - Local competition dynamics between companies that are close to each other in their core business strategic dimensions (local hypercubic lattice one-bit mutant neighors coupling as per Kaneko, Refs. [3] and [4]) - controlled by the slider epsilon_1;

(B) - Global competitiveness' industry-wide evolutionary race - controlled by the slider epsilon_2;

(C) - Market share feedback effects upon a business fitness (this leads to a coupling between the quadratic map and the previous transaction round's company's market share, such that the previous round's quantum fluctuations affect the company's fitness dynamics) - controlled by the slider delta.

(D) - Local fitness dynamics given by the quadratic map with nonlinearity parameter b.

HOW TO USE IT

The upper eight sliders set the economy's profile. The sliders b, theta, epsilon_1, epsilon_2, delta, Q-bar and niu are the parameters' for the model's main equations, reviewed above.

The slider k sets the length of the core business strategic profile and, therefore, the number of companies in the economy is set to N = 2^k.

The lower six sliders correspond to plotting and visualization parameters, these are:

-> plotting-sampling: the user can set the plotting sampling range "p" so that only the rounds satisfying t mod p = 0 are plotted;

-> min-plot-x, max-plot-x, min-plot-y, max-plot-y: the user can set the range for the "Mean Economic Output" as well as the "Delay-Plot Mean Economic Output";

-> max-height: each company (turtle agent) is set as a line segment and the size of the turtle is set to the product of max-height multiplied by the market share, in this way, one can see the quantum fluctuations in the lattice sites such that lines with the greater company height have larger market shares which, for each company, result from the sum of the quantities sold by the company divided by the total of quantities sold.

THINGS TO NOTICE

In this model one may notice the fluctuations in the company heights and try to find patterns, getting a feel for the quantum business game dynamics.

One may also look at each of the three plots:

- "Mean x" - this is the plot for the companies' fitness mean field;

- "Mean Economic Output" - this is the plot for the mean quantities sold in the economy at each round of the game;

- "Delay-Plot Mean Economic Output" - this is the delay plot for the mean quantities sold in the economy for two consecutive rounds;

One may look at the company fitness variable x and see how its dynamics leaves a signature in the quantum business game dynamics ("Mean x" plot vs "Mean Economic Output").

One may look at patterns in the delay plot that may relate to the chaotic dynamics.

THINGS TO TRY

The model works as a sort of economic lab, such that different parameters lead to different economic profiles, some of the most relevant are obtained for:

epsilon_1 = delta = 0: in this case, there is no market share coupling in the fitness dynamics and neither is there any local coupling, the global coupling slider epsilon_2 will then set the strength of a perfect competition scenario. The higher the value of epsilon_2 is the more does the economy profile approach the perfect competition regime, with one difference, that due to the quantum fluctuations, each company's economic equilibrium changes from round to round, however, the quantum averages of the several companies synchronize so that one obtains a statistical economic equilibrium notion, just as it takes place in other artificial economies models with discrete local equilibrium trading like, for instance, sugarscape.

epsilon_1 = 0: in this case, one may address both global competition and local market share coupling, such that on average companies which got a higher market share in one round tend to increase their market share in the following round.

In the more general case, where all the three parameters can be changed (epsilon_1, epsilon_2 and delta) there is business concept differentiation, global competition and market share coupling.

The user may adjust the profile and see how different economic profiles lead to different dynamics.

EXTENDING THE MODEL

The model may be changed to include value chain effects, labor market, and other features of actual economies.

RELATED MODELS

Other related models with the same MSC classification are:

- Herding

http://ccl.northwestern.edu/netlogo/models/community/Herding

- Artificial Financial Market

http://ccl.northwestern.edu/netlogo/models/community/Artificial%20Financial%20Market

- Artificial Financial Market II - Tail Risk

http://ccl.northwestern.edu/netlogo/models/community/Artificial%20Financial%20Market%20II%20-%20Tail%20Risk

- Quantum Financial Market

http://ccl.northwestern.edu/netlogo/models/community/Quantum_Financial_Market

Also related to Quantum Complex Systems Science is the model:

- Quantum Life I

http://ccl.northwestern.edu/netlogo/models/community/Quantum%20Life%20I

CREDITS AND REFERENCES

[1] Gon_ves, 2012, "Quantum Financial Economics of Games of Strategy and Financial Decisions", arXiv:1202.2080v1 [q-fin.GN] http://arxiv.org/abs/1202.2080

[2] Gon_ves, 2012, "Chaos and Nonlinear Dynamics in a Quantum Artificial Economy" arXiv:1202.6647v1 [nlin.CD] http://arxiv.org/abs/1202.6647

[3] Kaneko, K., "Chaos as a Source of Compexity and Diversity in Evolution", Arti?cial Life I, 1994, 163-177

[4] Kaneko, K. and I. Tsuda, Complex Systems: Chaos and Beyond, A Constructive Approach with Applications in Life Sciences, Springer, Germany, 2001.

The present work is part of an ongoing research by the author in risk science, risk mathematics, quantum game theory and the application of the mathematical formalisms from quantum theory and chaos theory to mathematical economics.

AUTHOR INFORMATION:

-------------------

Carlos Pedro Gon_ves (PhD)

Instituto Superior de Ci_ias Sociais e Pol_cas - Technical University of Lisbon

E-mail: cgoncalves@iscsp.utl.pt

Website: https://sites.google.com/site/carlospedrogoncalves/

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [ N Mean-Economic-Output_t-1 Mean-Economic-Output_t ]

turtles-own 
[
  core-business-ID 
  
  ; Quantum business dynamics variables:
  x_t-1
  x_t
  F
  number-state
  Qe
  
  
  ; Quantities supplied:
  Q_t-1
  Q_t
  
  ; Market share:
  
  M_t-1
  M_t
  
  
  ]

to setup-types
  ca
  no-display
  ask patches [ set pcolor white ]
  set-types
  create-hypercubic-lattice
  ask turtles [ set x_t 1 - 2 * random-float 1.000 ]
  display 
end 

to go
  tick
  update-core-business-fitness
  quantum-game
  determine-economic-output
  do-plot
end 

to update-core-business-fitness
  
  ask turtles 
  
  [ set x_t-1 x_t
    set M_t-1 M_t ]
  
  ask turtles [ set F (1 - delta) * (1 - b * x_t-1 ^ 2) + delta * M_t-1 ]
  
  ask turtles [ set x_t (1 - epsilon_1 - epsilon_2) * F + epsilon_1 * mean [F] of link-neighbors + epsilon_2 * mean [F] of turtles ]
  
  ask turtles [ set Qe Q-bar + niu * x_t ]
end 

to quantum-game
  ask turtles [ set number-state random-poisson (Qe - theta) ]
  ask turtles [ set Q_t number-state + theta ]
  ask turtles [ set M_t Q_t / (sum [Q_t] of turtles) ]
  ask turtles [ set size max-height * M_t ]
end 

to determine-economic-output
  set Mean-Economic-Output_t-1 Mean-Economic-Output_t
  set Mean-Economic-Output_t mean [Q_t] of turtles
end 

to do-plot
  set-current-plot "Delay-Plot Mean Economic Output"
  set-plot-x-range min-plot-x max-plot-x
  set-plot-y-range min-plot-y max-plot-y
  if (ticks mod plotting-sampling = 0) [ plotxy Mean-Economic-Output_t-1 Mean-Economic-Output_t ]
  
  set-current-plot "Mean Economic Output"
  set-plot-y-range min-plot-y max-plot-y
  plot Mean-Economic-Output_t
  
  set-current-plot "Mean x"
  plot mean [x_t] of turtles
end 










;;;;;;;;;;;;;;;;;;;;;;
;; SETUP PROCEDURES ;;
;;;;;;;;;;;;;;;;;;;;;;

to set-types

  set N 2 ^ k
  cro N [ fd 10 rt 180 ]
  ask turtles [ set core-business-ID who ]
end 

to create-hypercubic-lattice
  
  let prev-max-who -1
  if (any? turtles)
    [ set prev-max-who  (max [core-business-ID] of turtles) ]
    
 ask turtles 
 
 
  [
    
    let i 0
    repeat N
    [
      if ((floor ((core-business-ID - prev-max-who - 1) / (2 ^ i))) mod 2 = 0)
        [ create-link-with turtle (core-business-ID + (2 ^ i)) ]
      set i (i + 1)
    ]
  ]
  
  ask links [ set color black ]
  
  set-default-shape turtles "line"
end

There is only one version of this model, created almost 13 years ago by Carlos Pedro S. Gonçalves.

Attached files

No files

This model does not have any ancestors.

This model does not have any descendants.

NetLogo