Interspecies Infection

breed [pigs pig]  
breed [people person]

turtles-own
  [ sick?        ;; if true, the turtle is infectious
    immune?      ;; if true, the turtle can't be infected
    sick-count   ;; how long the turtle has been infectious
    age ]        ;; how many weeks old the turtle is
globals
[
  %peopleinfected            ;; what % of the people are infectious
  %peopleimmune              ;; what % of the people are immune
  %peoplehealthy             ;; what % of the people are healthy
  %piginfected               ;; what % of the pigs are infectious
  %pigimmune                 ;; what % of the pigs are immune
  %pighealthy                ;; what % of the pigs are healthy
  lifespan             ;; the average lifespan of a turtle
  average-offspring    ;; the average number of offspring a turtle could have
  pig-carrying-capacity       ;; the number of pigs that can be in the world at one time
  people-carrying-capacity    ;; the number of people that can be in the world at one time
home-patches           ;; patches people inhabit
pen-patches            ;; patches pigs inhabit
border ;; border around the world, to prevent wrap infections                
]
;; The setup is divided into three subroutines

to setup
  clear-all
  setup-constants
  setup-pen
  setup-breeds
end 

to setup-pen
   
  ;; create the 'pen' for pigs
  if pigpen-size = "small"
  [set pen-patches patches with [pxcor > 5 and pycor > 5]
    ask pen-patches [set pcolor brown]]
  
  if pigpen-size = "medium"
  [set pen-patches patches with [pxcor > 1 and pycor > 1]
  ask pen-patches [ set pcolor brown ]]
  
  if pigpen-size = "large"
  [set pen-patches patches with [pxcor > 1 ]
  ask pen-patches [set pcolor brown ]]
  
   ;; create the 'homes'for people
  if pigpen-size = "small" 
  [set home-patches patches with [pycor < 5 or (pxcor < 5  and pycor >= 5)]
  ask home-patches [ set pcolor 51 ]] 
   
  if pigpen-size = "medium" 
  [set home-patches patches with [pycor < 1 or (pxcor < 1  and pycor >= 1)]
  ask home-patches [ set pcolor 51 ]]
  
  if pigpen-size = "large"
  [set home-patches patches with [pxcor < 1]
  ask home-patches [ set pcolor 51 ]]
  
  ;; create border
  set border (round max-pycor) 
  
  ask patches with [ ((abs pxcor = border) and (abs pycor <= border)) or
                   ((abs pycor = border) and (abs pxcor <= border)) ]
    [ set pcolor black ]
end 
;; We create a variable number of pigs and people and distribute them randomly. 10% of pigs are infectious.

to setup-breeds
  set-default-shape pigs "pig"
  create-pigs number-of-pigs
     [ set color pink
      move-to one-of pen-patches with [pcolor = brown]
      set age random lifespan
      set sick-count 0
      set immune? false
      set size 2  ;; easier to see
      get-healthy ]
  ask n-of (number-of-pigs / 10) pigs
     [get-sick ]
  
  set-default-shape people "person"
  create-people number-of-people
    [ set color green
      move-to one-of home-patches with [pcolor = 51]
      set age random lifespan
      set sick-count 0
      set immune? false
      set size 2  ;; easier to see
      get-healthy ]
end 

to get-sick ;; turtle procedure
  set sick? true
  set immune? false
  set color red
end 

to get-healthy ;; turtle procedure
  set sick? false
  set immune? false
  set sick-count 0
end 

to become-immune ;; turtle procedure
  set sick? false
  set sick-count 0
  set immune? true
  set color blue
end 

to setup-constants
  set lifespan 100
  set pig-carrying-capacity 200
  set people-carrying-capacity 200
  set average-offspring 2
end 

to go
  get-older
  move-pigs
  move-people
  infect-pigs
  infect-people
  recover
  reproduce
  update-global-variables
  tick
  update-plot-people
  update-plot-pigs
end 

to update-global-variables
  if count pigs > 0
  [
    set %piginfected (count pigs with [sick?]) / (count pigs) * 100
    set %pigimmune (count pigs with [immune?]) / (count pigs) * 100
    set %pighealthy (count pigs with [not sick? and not immune?]) / (count pigs) * 100
  ]
  if count people > 0
  [
    set %peopleinfected (count people with [sick?]) / (count people) * 100
    set %peopleimmune (count people with [immune?]) / (count people) * 100
    set %peoplehealthy (count people with [not sick? and not immune?]) / (count people) * 100
  ]
end 
;;Turtle counting variables are advanced.

to get-older
  ask pigs
  [
    set age age + 1
    if sick?
      [ set sick-count (sick-count + 1) ]
    ;; Turtles die of old age once their age equals the
    ;; lifespan (set at 1500 in this model).
    if age > lifespan
      [ die ]
  ]
  
  ask people
  [
    set age age + 1
    if sick?
      [ set sick-count (sick-count + 1) ]
    ;; Turtles die of old age once their age equals the
    ;; lifespan (set at 1500 in this model).
    if age > lifespan
      [ die ]
  ]
end 
;;Turtles move about at random, but within their environment (pigs in the pen, people in the "home" patches).

to move-pigs
  ask pigs
  [ifelse patch-ahead 1 = nobody
    [rt 180
      fd 1]
  [ifelse [pcolor] of patch-ahead 1 = 51
     [rt 180
     fd 2]
     [rt random 100
     lt random 100
     fd .5]]]
end 

to move-people  
  ask people
  [ifelse patch-ahead 1 = nobody
    [rt 180
      fd 2]
    [ifelse [pcolor] of patch-ahead 1 = brown
     [rt 180
     fd 3]
     [rt random 100
     lt random 100
     fd 1]]]
end 
;; If a turtle is sick, it infects other turtles on the same patch, with different rates for within and between breeds.
;; Immune turtles don't get sick.

to infect-pigs
  ask pigs with [sick?]
    [ ask other pigs-here with [ not immune? ]
        [ if (random-float 100) < within-pig-infectiousness
            [ get-sick ] ]]
  ask pigs with [sick?]  
  [ ask people-here with [ not immune? ]
    [ if (random-float 100) < between-species-infectiousness
        [get-sick]]]
end 

to infect-people
  ask people with [sick?]
    [ ask other people-here with [ not immune? ]
        [ if (random-float 100) < within-people-infectiousness
            [ get-sick ] ]
  ask pigs-here with [ not immune? ]
    [ if (random-float 100) < between-species-infectiousness
        [ get-sick ] ]]
end   
  
;; Once the turtle has been sick long enough, it
;; either recovers (and becomes immune) or it dies.

to recover
   ask pigs with [sick?]
     [ if (random sick-count) > (lifespan * (duration-pigvirus / 100))  ;; If the turtle has survived past the virus' duration, then
         [ ifelse ((random-float 100) < chance-recover-pigs)        ;; either recover or die
             [ become-immune ]
             [ die ] ] ]
   
   ask people with [sick?]  
       [ if (random sick-count) > (lifespan * (duration-peoplevirus / 100))  ;; If the turtle has survived past the virus' duration, then
         [ ifelse ((random-float 100) < chance-recover-people)        ;; either recover or die
             [ become-immune ]
             [ die ] ] ]
end 
;; If there are less turtles than the carrying-capacity
;;  then turtles can reproduce.
;; The probability of reproduction depends on average number
;;  of offspring per life.  In this model it is 2 per life (e.g.
;;  2 per 100 weeks.  The chance, therefore, for a turtle to
;;  reproduce at any given turn is 0.02 (if the population
;;  is below carrying-capacity).

to reproduce
  ask pigs with [not sick?]
    [ if (count pigs) < pig-carrying-capacity
       and (random lifespan) < average-offspring
       [ hatch-pigs 1
           [ set age 1
             rt random 360
                fd 1 ] get-healthy]]
    
  ask people with [not sick?]
    [ if (count people) < people-carrying-capacity
         and (random lifespan) < average-offspring
       [ hatch-people 1
           [ set age 1
             rt random 360
                fd 1 ] get-healthy ]]   
end 

to update-plot-people
  set-current-plot "Populations-People"
  set-current-plot-pen "sick"
  plot count people with [sick?]
  set-current-plot-pen "healthy"
  plot count people with [not sick? and not immune?]
  set-current-plot-pen "immune"
  plot count people with [immune?]
  set-current-plot-pen "total"
  plot count people
end 

to update-plot-pigs
  set-current-plot "Populations-Pigs"
  set-current-plot-pen "sick"
  plot count pigs with [sick?]
  set-current-plot-pen "healthy"
  plot count pigs with [not sick? and not immune?]
   set-current-plot-pen "immune"
  plot count pigs with [immune?]
  set-current-plot-pen "total"
  plot count pigs
end 
; *** NetLogo 4.1beta3 Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING
; IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) --
; grant numbers REC #9814682 and REC-0126227.
; Converted from StarLogoT to NetLogo, 2001.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Virus model.
; http://ccl.northwestern.edu/netlogo/models/Virus.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/Virus
; for terms of use.
;
; *** End of NetLogo 4.1beta3 Model Copyright Notice ***