Bug Hunters Camouflage

globals
[
  leader            ;; a string expressing the player who has caught the most bugs (or a tie if appropriate)
  leader-caught     ;; the number of bugs the leader has caught
  total-caught      ;; running total of the total number of bugs caught by everyone
  adult-age         ;; the number of ticks before bugs are full grown
]

;; each client controls one player turtle
;; players are always hidden in the view
breed [players player]

players-own
[
  user-name    ;; the unique name users enter on their clients
  caught       ;; the number of bugs this user as caught
  attempts     ;; times the user has clicked in the view trying to catch a bug
  percent      ;; percent of catches relative to the leader
]

breed [bugs bug]

;; gene-frequencies determine the color
;; of each bug and mutate as bugs reproduce
bugs-own
[
  red-gene    ;; gene for strength of expressing red pigment (0-255)
  blue-gene   ;; gene for strength of expressing blue pigment (0-255)
  green-gene  ;; gene for strength of expressing green pigment (0-255)
]

;;;;;;;;;;;;;;;;;;;
;; Setup Procedures
;;;;;;;;;;;;;;;;;;;

to startup
  hubnet-reset
  setup-clear
end 

;; this kills off all the turtles (including the players)
;; so we don't necessarily want to do this each time we setup

to setup-clear
  ca
  set-default-shape bugs "moth"
  set adult-age 50
  setup
end 

;; setup the model for another round of bug catching
;; with the same group of users logged in

to setup
  cp
  clear-all-plots
  reset-ticks
  ask bugs [ die ]

  set total-caught 0
  set leader ""
  set leader-caught 0

  change-environment
  make-initial-bugs
  ;; make sure to return players to initial conditions
  ask players [ initialize-player ]
end 

to make-initial-bugs
  create-bugs carrying-capacity
  [
    set size bug-size
    ;; assign gene frequencies from 0 to 255, where 0 represents 0% expression of the gene
    ;; and 255 represent 100% expression of the gene for that pigment
    set red-gene random 255
    set blue-gene random 255
    set green-gene random 255
    setxy random-xcor random-ycor
    set-phenotype-color
    assign-genotype-labels
  ]
end 

;;;;;;;;;;;;;;;;;;;;;
;; Runtime Procedures
;;;;;;;;;;;;;;;;;;;;;

to go
  grow-bugs
  reproduce-bugs
  listen-clients
  every 0.01
  [ tick ]
  do-plots
end 

to grow-bugs
  ask bugs
  [
    ;; show genotypes if appropriate, hide otherwise
    assign-genotype-labels
    ;; if the bug is smaller than bug-size then it's not full
    ;; grown and it should get a little bigger
    ;; so that bugs don't just appear full grown in the view
    ;; but instead slowly come into existence. as it's easier
    ;; to see the new bugs when they simply appear
    ifelse size < bug-size
    [ set size size + (bug-size / adult-age) ]
    [ set size bug-size ]
  ]
end 

;; keep a stable population of bugs as predation rates go up or down

to reproduce-bugs
  ;; if all the bugs are removed by predators at once
  ;; make a new batch of random bugs
  if count bugs = 0
  [ make-initial-bugs ]

  ;; otherwise reproduce random other bugs  until
  ;; you've reached the carrying capacity
  if count bugs < carrying-capacity
  [ ask one-of bugs [ make-one-offspring ] ]
end 

to make-one-offspring ;; turtle procedure
  ;; three possible random mutations can occur, one in each frequency of gene expression
  ;; the max-mutation-step determines the maximum amount the gene frequency can drift up
  ;; or down in this offspring
  let red-mutation   random (max-mutation-step + 1) - random (max-mutation-step + 1)
  let green-mutation random (max-mutation-step + 1) - random (max-mutation-step + 1)
  let blue-mutation  random (max-mutation-step + 1) - random (max-mutation-step + 1)
  hatch 1
  [
     set size 0
     set red-gene   limit-gene (red-gene   + red-mutation)
     set green-gene limit-gene (green-gene + green-mutation)
     set blue-gene  limit-gene (blue-gene  + blue-mutation)
     set-phenotype-color
     ;; move away from the parent slightly
     wander
   ]
end 

;;  ask all bugs to reproduce, ignoring carrying-capacity limits

to make-generation
  ask bugs [ make-one-offspring ]
end 

;; used to move bugs slightly away from their parent

to wander ;; turtle procedure
   rt random 360
   fd random-float offspring-distance + 1
end 

;; loads an image as a background among the images listed in the environment chooser

to change-environment
    import-drawing environment
end 

;; a visualization technique to find bugs if you are convinced they are not there anymore
;; it allows flashing without actually changing and recalculating the color attribute of the bugs

to flash-bugs
  repeat 3
  [
    ask bugs [ set color black ]
    wait 0.1
    display
    ask bugs [ set color white ]
    wait 0.1
    display
  ]
  ask bugs [ set-phenotype-color ]
end 

to assign-genotype-labels  ;; turtle procedure
  ifelse show-genotype?
  ;; we display the genotype without decimal digits, to make
  ;; the data display of this information less cluttered
  [ set label color ]
  [ set label "" ]
end 

;; convert the genetic representation of gene frequency
;; into a phenotype (i.e., a color, using the rgb primitive)
;; we are using rgb color rather than NetLogo colors, thus, we just
;; make a list of the red green and blue genes.

to set-phenotype-color  ;; turtle procedure
  set color rgb red-gene green-gene blue-gene
end 

;; imposes a threshold limit on gene-frequency.
;; without this genes could drift into negative values
;; or very large values 

to-report limit-gene [gene]
  if gene < 0   [ report 0   ]
  if gene > 255 [ report 255 ]
  report gene
end 

;;;;;;;;;;;;;;;;;;;;;;
;; HubNet Procedures
;;;;;;;;;;;;;;;;;;;;;;

to listen-clients
  while [hubnet-message-waiting?]
  [
    hubnet-fetch-message
    ifelse hubnet-enter-message?
    [ add-player ]
    [
      ifelse hubnet-exit-message?
     [ remove-player ]
     [
        if hubnet-message-tag = "View"
        [
          ask players with [ user-name = hubnet-message-source ]
            [ eat-bugs ]
        ]
      ]
    ]
  ]
end 

;; when a client logs in make a new player
;; and give it the default attributes

to add-player
  create-players 1
  [
    set user-name hubnet-message-source
    initialize-player
  ]
end 

to initialize-player ;; player procedure
  hide-turtle
  set attempts 0
  set caught 0
  set-percent
  send-student-info
end 

;; when clients log out simply
;; get rid of the player turtle

to remove-player
  ask players with [ user-name = hubnet-message-source ]
    [ die ]
end 

to eat-bugs
  ;; extract the coords from the hubnet message
  let clicked-xcor  (item 0 hubnet-message)
  let clicked-ycor  (item 1 hubnet-message)

  ask players with [ user-name = hubnet-message-source ]
  [
    set xcor clicked-xcor      ;; go to the location of the click
    set ycor clicked-ycor
    set attempts attempts + 1  ;; each mouse click is recorded as an attempt
                               ;; for that player

    ;;  if the players clicks close enough to a bug's location, they catch it
    ;;  the in-radius (bug-size / 2) calculation helps make sure the user catches the bug
    ;;  if they click within one shape radius (approximately since the shape of the bug isn't
    ;;  a perfect circle, even if the size of the bug is other than 1)
    let candidates bugs in-radius (bug-size / 2)
    ifelse any? candidates
    [
      let doomed-bug one-of candidates
      set caught caught + 1
      set total-caught total-caught + 1
      ask doomed-bug
        [ die ]

      ;; if a bug is caught update the leader
      ;; as it may have changed
      update-leader-stats
      ;; all the players have monitors
      ;; displaying information about the leader
      ;; so we need to make sure that gets updated
      ;; when the leader changed
      ask players
      [
        set-percent
        send-student-info
      ]
    ]
    ;; even if we didn't catch a bug we need to update the attempts monitor
    [ send-student-info ]
  ]
end 

;; calculate the percentage that this player caught to the leader

to set-percent ;; player procedure
  ;; make sure we don't get a divide by 0 error
  ifelse leader-caught > 0
  [ set percent (caught / leader-caught) * 100]
  [ set percent 0 ]
end 

;; update the monitors on the client

to send-student-info ;; player procedure
  hubnet-send user-name  "Your name" user-name
  hubnet-send user-name "You have caught" caught
  hubnet-send user-name "# Attempts"  attempts
  hubnet-send user-name "Relative %"  (precision percent 2) ;; just show 2 decimal places
  hubnet-send user-name "Top hunter" leader
  hubnet-send user-name "Top hunter's catches" leader-caught
end 

;; do the bookkeeping to display the proper leader and score

to update-leader-stats
  if any? players
  [
    let leaders players with-max [ caught ]
    let number-leaders count leaders

    ;; if there is more than one leader just report
    ;; a tie otherwise report the name
    ifelse number-leaders > 1
    [ set leader word number-leaders "-way tie" ]
    [ ask one-of leaders [ set leader user-name ] ]
    set leader-caught [caught] of one-of leaders
  ]
end 

;;;;;;;;;;;;;;;;;;;;;
;; Plotting Procedure
;;;;;;;;;;;;;;;;;;;;;

to do-plots
  set-current-plot "Bugs Caught by All Hunters vs. Time"
  plot total-caught
end 


; Copyright 2006 Uri Wilensky.
; See Info tab for full copyright and license.