Patch Clusters Example

patches-own
[
  cluster   ;; Holds a patch which is that cluster's "leader".
  ;; it's arbitrary which patch is used to identify
  ;; the cluster -- whichever one we happen to find
  ;; first will do.  If this patch hasn't been assigned
  ;; to a cluster yet, then this holds "nobody".
]

to setup
  clear-all
  ask patches
  [ ;; use dark colors so the labels are visible
    set pcolor 3 + 10 * random 14
    ;; initially, we're in no cluster
    set cluster nobody ]
  ;; by spreading colors from patch to patch, connected areas
  ;; that are all the same color will emerge
  repeat 20
  [ ask patches
    [ set pcolor [pcolor] of one-of neighbors4 ] ]
end 

to find-clusters
  loop [
    ;; pick a random patch that isn't in a cluster yet
    let seed one-of patches with [cluster = nobody]
    ;; if we can't find one, then we're done!
    if seed = nobody
    [ show-clusters
      stop ]
    ;; otherwise, make the patch the "leader" of a new cluster
    ;; by assigning itself to its own cluster, then call
    ;; grow-cluster to find the rest of the cluster
    ask seed
    [ set cluster self
      grow-cluster ]
  ]
end 

to grow-cluster  ;; patch procedure
  ask neighbors4 with [(cluster = nobody) and
    (pcolor = [pcolor] of myself)]
  [ set cluster [cluster] of myself
    grow-cluster ]
end 

;; once all the clusters have been found, this is called
;; to put numeric labels on them so the user can see
;; that the clusters were identified correctly

to show-clusters
  let counter 0
  loop
  [ ;; pick a random patch we haven't labeled yet
    let p one-of patches with [plabel = ""]
    if p = nobody
      [ stop ]
    ;; give all patches in the chosen patch's cluster
    ;; the same label
    ask p
    [ ask patches with [cluster = [cluster] of myself]
      [ set plabel counter ] ]
    set counter counter + 1 ]
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.