Radical Polymerization

Radical Polymerization preview image

1 collaborator

Uri_dolphin3 Uri Wilensky (Author)

Tags

chemical reactions 

Tagged by Reuven M. Lerner over 4 years ago

chemistry and physics 

Tagged by Reuven M. Lerner over 4 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 163 times • Downloaded 6 times • Run 0 times
Download the 'Radical Polymerization' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model explains kinetics of radical polymerization. Radical polymerization can be thought of as the process of agglomeration of small molecules (monomers) into chains (polymer chains) initiated by active particles (radicals).

An example of radical polymerization would be industrial polymerization of ethylene into polyethylene (PET):

n C H  --------> ~C  H~
  2 4           2n 4n

A gaseous mixture of ethylene and oxygen (used as a catalyst), is pumped through a mile-long heated pipe. As the mixture moves along the pipe, the molecules of ethylene polymerize into chains. At the end of the pipe, the polymer is collected and co-products with low molecular mass are recycled.

Molecules of oxygen turn into bi-radicals under the influence of high temperature:

O --------> *O-O*
 2

here the asterisk denotes a free electron. These bi-radicals react with pi-bonds in ethylene and start the process of chain growth according to the scheme:

 *O-O* + C H --------> *O-O-CH-CH*
          2 4                 2  2

 *O-O-CH-CH* + CH-CH --------> *O-O-CH-CH-CH-CH*
        2  2     2  2                 2  2  2  2

We can thus think of radical polymerization as interaction between (bi-) radicals and monomers.

Notice that if two radicals react with each other, they will form an inert compound and end the process of forming loner chains.

Let us assume that we run polymerization using AIBN as an initiator which we denote by I. We thus have the following kinetically distinct particles in the system:

(i) Initiator molecules;
(ii) Radicals;
(iii) Monomers;
(iv) "Dead" chains;

A radical can react with a monomer, in which case it absorbs the monomer and increases its chain-length by 1. Alternatively, a radical can react with another radical forming a "dead" molecule which does not react with other particles. Let us denote by R(n) radicals which have reacted n times with monomers. Let M stand for monomers and C(k) for "dead" chains of length k. Then schematically we can describe the reactions by the following system of equations:

        I --------> 2 R(1)              (initiation)

        R(n) + M --------> R(n+1)       (growth)

     R(n) + R(m) --------> C(n+m)       (termination)

In this model, there are four breeds of turtles:

  • initiators (yellow turtles);
  • monomers (green turtles);
  • radicals (red turtles);
  • polymers (blue turtles).

Each turtle carries a variable, chain-length. Initially there are 200 turtles of monomer breed with chain-length set to 1. There is also a user-defined number (Io) of initiator breed with chain-length set to 0.

The rules are quite simple:

(i) All turtles move around randomly.
(ii) Yellow turtles (initiators) spontaneously break up into two red turtles (radicals) with probability Ki;
(iii) Green turtles (monomers) react with red turtles (radicals) with probability Km. If there is at least one radical on the same patch as the given monomer, the monomer dies and the chain-length of the radical which "killed" it is incremented by 1;
(iv) Red turtles (radicals) react with each other pairwise. If there is a pair of radicals on the same patch, they annihilate each other with probability Kr forming a polymer chain (a blue turtle);

HOW TO USE IT

With sliders one can control the initial number of initiators (Io) and reaction probabilities

  • Ki (initiator): probability of an initiator (yellow) creating two radicals (red);
  • Km (monomer): probability of reaction between monomers (green) and radicals (red), forming a radical with a longer chain length;
  • Kr (radical): probability of two radicals (red) reacting to form a polymer chain (blue).

Select the initial number of initiators Io and press the "setup" button. To start the simulation press the GO button. You can set the probabilities Ki, Km and Kr before or after you do setup. You can also modify this constants on the fly during the execution of the GO procedure.

One plot shows the number of initiators, monomers, radicals, and polymers. The distribution of chain-lengths of polymers (blue) is shown in the second plot in the form of a histogram. Each chain is labeled with its length.

THINGS TO NOTICE

Distribution of chain-length drastically depends on the mode of initiation. If you select low values of Io and Ki, then the life expectancy of radicals will rise leading to longer chains. However in this case the simulation will have to run too long in order to produce a sizable amount of long-length chains. If you start the simulation with a lot of initiator which decomposes rapidly, radicals will tend to react with themselves and form low molecular oligomers.

THINGS TO TRY

Try to find the optimum values for which the distribution is tight and the simulation runs at a reasonable pace.

EXTENDING THE MODEL

Try to implement the model of industrial production of polyethylene (PET) described above. Are you going to have "dead" chains in this model?

Can you modify the model so that visible "chains" of turtles actually form, like in the Follower model?

ADDITIONAL INFORMATION

Note that in real polymerization reactions, the outcomes are affected by the position and shapes of the chains in three-dimensional space. This aspect of the reactions is not presented in this model.

Although oxygen is widely used in industry as initiator of radical polymerization, scientists prefer to use other initiators in the lab, especially when the reaction has to be performed under conditions of atmospheric pressure and room temperature. Two of the most frequently used lab initiators are benzoyl peroxide and 2-2'-azo-bis-isobutyrylnitrile (AIBN):

    C H-C(O)O-O(O)C-H C
 6 5             5 6

            CH     CH
        | 3    | 3
        CH -C--N=N-C- CH
      3 |      |    3
        CN     CN

Peroxydes and azo-compounds are extremely unstable and tend to break up into radicals very easily if exposed to moderate heat or light. Here is the reaction of decomposition of AIBN:

            CH     CH                     CH
        | 3    | 3                    | 3     ^
        CH -C--N=N-C- CH  --------> 2 CH -C* + N  |
      3 |      |    3               3 |     2
        CN     CN                     CN

This reaction is irreversible because of the escape of nitrogen.

RELATED MODELS

Simple Kinetics series, Polymer Dynamics

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

COPYRIGHT AND LICENSE

Copyright 1998 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [ initiators initiator ]  ;; yellow
breed [ monomers monomer ]    ;; green
breed [ polymers polymer ]    ;; blue
breed [ radicals radical ]    ;; red


turtles-own [
  chain-length
]

to setup
  clear-all
  set-default-shape turtles "circle"
  ;; make molecules
  create-monomers 200
   [ set color green
     set chain-length 1 ]
  create-initiators Io
   [ set color yellow
     set chain-length 0 ]
  ;; scatter them around the world
  ask turtles
   [ setxy random-xcor random-ycor ]
  ;; start plots
  reset-ticks
end 

to go
  ask monomers [ grow-chain ]
  ask initiators [ initiate ]
  ask turtles [ move ]
  ask radicals [ terminate ]
  ask radicals [ set label chain-length ]
  ask polymers [ set label chain-length ]
  tick
end 

to move
  rt random 50 - random 50
  fd 1
end 

;; monomer procedure -- monomer turtle finds a radical on the same patch,
;; increases the chain-length of the radical by 1, then dies

to grow-chain
  let partner one-of radicals-here
  if (partner != nobody) and (random-float 1000 < Km)
    [ ask partner [ set chain-length chain-length + 1 ]
      die ]
end 

;; initiator procedure -- unimolecular initiation: yellow turtles
;; spontaneously break up into two red radicals

to initiate
  if (random-float 1000 < Ki)
    [ set color red
      set breed radicals
      hatch 1 [ move ] ]
end 

;; radical procedure -- radicals react pairwise

to terminate
  let partner one-of other radicals-here
  if (partner != nobody) and (random-float 500 < Km)
    [ if self < partner
        [ ask partner
            [ set color blue
              set breed polymers
              set chain-length chain-length + [chain-length] of myself ] ]
          die ]
end 

;; plotting procedures

to do-histogram
  let histogram-max max fput 10 [chain-length] of polymers
  set-plot-x-range 0 histogram-max
  set-histogram-num-bars (histogram-max + 1)
  histogram [chain-length] of polymers
end 


; Copyright 1998 Uri Wilensky.
; See Info tab for full copyright and license.

There are 10 versions of this model.

Uploaded by When Description Download
Uri Wilensky over 4 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky almost 5 years ago Updated version tag Download this version
Uri Wilensky almost 5 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky almost 6 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky over 7 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 7 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 7 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 7 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 7 years ago Model from NetLogo distribution Download this version
Uri Wilensky over 7 years ago Radical Polymerization Download this version

Attached files

File Type Description Last updated
Radical Polymerization.png preview Preview for 'Radical Polymerization' over 4 years ago, by Uri Wilensky Download

This model does not have any ancestors.

This model does not have any descendants.